Hallo Zusammen,
könnt Ihr mir helfen folgende Formeln kürzer zu machen:
=WENNFEHLER(WENN(UND(ODER(B6<=4;B6="-");B6>0;ODER(C6<=4;C6="-");C6>0;ODER(D6<=4;D6="-");D6>0); MITTELWERT(B6:D6);WENN(UND(;B6=0;C6=0;D6=0);"";"!"));"-")
und
=WENN($E6<=2;"A";WENN(UND($E6>2;$E6<=3);"B";WENN(UND($E6>3;$E6<=4);"C";WENN(E6="!";"<<<";""))))
Vielen Dank im Voraus
Hola,
verlinkst du bitte deine Fragen in den verschiedenen Foren untereinander?
Danke.
Gruß,
steve1da
Hallo,
da würde ich einfach mal so kürzen:
Code:
=WENN((MAX(B6:D6)<=4)*(MIN(B6:D6)>0);MITTELWERT(B6:D6);WENN((B6=0)*(C6=0)*(D6=0);"";"!"))
=WENN(E6="!";"<<<";VERWEIS(E6-1%;{0;2;3};{"A";"B";"C"}))
=WENN((MAX(B6:D6)<=4)*(MIN(B6:D6)>0);MITTELWERT(B6:D6);WENN((B6=0)*(C6=0)*(D6=0);"";"!"))
=WENN(E6="!";"<<<";VERWEIS(E6-1%;{0;2;3};{"A";"B";"C"}))
ginge auch so (nicht unbedingt besser, nur alternativ):
=WENN((MAX(B6:D6)<=4)*(MIN(B6:D6)>0);MITTELWERT(B6:D6);WENN(PRODUKT(B6:D6);"!";""))
=WENN(E6="!";"<<<";ZEICHEN(VERGLEICH(E6-1%;{0;2;3})+64))
PHP-Code:
=iferror(char(E6+65);"<<<")
Hi snb,
NEIN!
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | B | C | D | E | F | G | H | I | J | K | L |
| 91 | - | 4 | 1 | 2,5 | B | 2,5 | B | 2,5 | B | 2,5 | B |
| 92 | - | 4 | 2 | 3 | B | 3 | B | 3 | B | 3 | C |
| 93 | - | 4 | 3 | 3,5 | C | 3,5 | C | 3,5 | C | 3,5 | C |
| 94 | - | 4 | 4 | 4 | C | 4 | C | 4 | C | 4 | D |
| Zelle | Formel |
| E91 | =WENN((MAX(B91:D91)<=4)*(MIN(B91:D91)>0);MITTELWERT(B91:D91);WENN((B91=0)*(C91=0)*(D91=0);"";"!")) |
| F91 | =WENN(E91="!";"<<<";VERWEIS(E91-1%;{0;2;3};{"A";"B";"C"})) |
| G91 | =WENN((MAX(B91:D91)<=4)*(MIN(B91:D91)>0);MITTELWERT(B91:D91);WENN(PRODUKT(B91:D91);"";"!")) |
| H91 | =WENN(E91="!";"<<<";ZEICHEN(VERGLEICH(E91-1%;{0;2;3})+64)) |
| I91 | =WENN((MAX(B91:D91)<=4)*(MIN(B91:D91)>0);MITTELWERT(B91:D91);WENN((B91=0)*(C91=0)*(D91=0);"";"!")) |
| J91 | =WENNFEHLER(WAHL(AUFRUNDEN(I91;0);"A";"A";"B";"C");"<<<") |
| K91 | =WENN((MAX(B91:D91)<=4)*(MIN(B91:D91)>0);MITTELWERT(B91:D91);WENN((B91=0)*(C91=0)*(D91=0);"";"!")) |
| L91 | =WENNFEHLER(ZEICHEN(K91+64);"<<<") |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Deine Formel in L!