Clever-Excel-Forum

Hallo Community,

ich bin gerade dabei eine Excelliste zu programmieren, um mir die Arbeit ein wenig zu erleichtern.

Leider scheitere ich dabei an folgendem Problem:

Ich habe eine Mappe "Contacts)" mit einer Tabelle1 und möchte die Werte einer Spalte "Company" in die Tabelle "Closed" einer anderen Mappe "JAN" übertragen, wenn mehrere Kriterien zutreffen:
- Schlagwort ("Closed") in der Spalte "Status" der Tabelle1
- Datum >=01.12.2016
- Datum <=31.12.2016

Die Formel, die ich für ein Kriterium verwende, sieht wie folgt aus:
=INDEX(Contacts!D:D;SMALL(IF(Contacts!N$10:N$2500="Closed";ROW(Contacts!$10:$2500));ROW(A1)))

Wenn ich die Formel aber auf drei Kriterien erweitere, um das Datum mit einzubeziehen:
=INDEX(Contacts!D:D;SMALL(IF(AND(Contacts!O$10:O$2500<=D3;Contacts!O$10:O$2500>=C3;Contacts!N$10:N$2500="Closed");ROW(Contacts!$10:$2500));ROW(A1)))
bekomme ich eine "0" und in den nachfolgenden Zellen 'NUM!.

Habe die Tabelle mal beigefügt, die Formel mit den erweiterten Kriterien befindet sich in der Mappe "JAN" E6:E22.

Habt ihr irgendwelche Lösungen für das Problem?

Danke schonmal für eure Hilfe.

Gruß

Dennis

Hola,

das würde man so schreiben:

Code:
{=WENNFEHLER(INDEX(Contacts!D:D;KKLEINSTE(WENN((Contacts!O$10:O$2500<=$D$3)*(Contacts!O$10:O$2500>=$C$3)*(Contacts!N$10:N$2500="Closed");ZEILE(A$10:A$2500));ZEILE(A1)));"")}

Ohne Abschluss als Matrixformel:

Code:
=WENNFEHLER(INDEX(Contacts!D:D;AGGREGAT(15;6;ZEILE($A$10:$A$2500)/((Contacts!O$10:O$2500<=$D$3)*(Contacts!O$10:O$2500>=$C$3)*(Contacts!N$10:N$2500="Closed"));ZEILE(A1)));"")

Gruß,
steve1da

Super, hat geklappt :19:

Vielen Dank und einen guten Rutsch :15:

darkwraith

steve1da

darkwraith