Ich habe wahrscheinlich eine sehr einfache Aufgabe, die ich gerade nicht gelöst bekomme.
Ich muss aus einer Zelle 2 Werte Multiplizieren. Die Werte ergeben aus den Kriterien "Length" und "height".
Die Zelle sieht folgendermaßen aus:
length=2300,000 mm;material="blue";height=800,000 mm;chaindistance=960,000 mm;chain="2 way";walkway="no"
Der zweite Fall ist das ich den Wert aus "length" mit einem konstanten multiplizieren muss.
Die Werte "length" und "height" sind variablen, die immer wieder ausgelesen werden.
Ich hoffe jemand zaubert mir eine Lösung.
Danke
:17:
Hallo
Code:
=--TEIL(A1;SUCHEN("length";A1)+7;8)
=--TEIL(A1;SUCHEN("height";A1)+7;8)
Hallo,
Danke. Das ist viel einfacher, als ich dachte.
Habe zu kompliziert gedacht.
Ich muss jetzt nur aufpassen, dass die Werte nicht zu groß sind. Dann nimmt er die nächsten Angaben wie "mm" mit.
Das müsste ich geregelt kriegen.
Gruß
heppi14
Hallo, meinst du dann so..?
Arbeitsblatt mit dem Namen 'Tabelle2' |
| A |
1 | length=2300,000 mm;material="blue";height=800,000 mm;chaindistance=960,000 mm;chain="2 way";walkway="no" |
2 | |
3 | 2300 |
4 | 800 |
5 | 1840000 |
Zelle | Formel |
A3 | =--TEIL(A1;SUCHEN("length";A1)+7;SUCHEN("mm";A1)-(SUCHEN("length";A1)+7)) |
A4 | =--TEIL(A1;SUCHEN("height";A1)+7;SUCHEN("#";WECHSELN(A1;"mm";"#";2))-(SUCHEN("height";A1)+7)) |
A5 | =TEIL(A1;SUCHEN("length";A1)+7;SUCHEN("mm";A1)-(SUCHEN("length";A1)+7))*TEIL(A1;SUCHEN("height";A1)+7;SUCHEN("#";WECHSELN(A1;"mm";"#";2))-(SUCHEN("height";A1)+7)) |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
ja.
Vielen Dank. Genau das habe ich gesucht.
Ich muss jetzt nur prüfen, ob ich zukünftig zahlen haben werden die sehr groß sind.
Dann würde es schwierig werden.
Danke.
Gruß
Ich kürze Jockel etwas ab mit
http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=100:
A3:
=VERWEIS(9^9;1*LINKS(TEIL(A1;SUCHEN("length=";A1)+7;256);SPALTE(A1:IQ1)))
A4:
=VERWEIS(9^9;1*LINKS(TEIL(A1;SUCHEN("height=";A1)+7;256);SPALTE(A1:IQ1)))
A5:
=A3*A4
... wobei seine Lösung vermutlich bei Massengebrauch etwas schneller ist.
(28.12.2016, 23:12)lupo1 schrieb: [ -> ]Ich kürze Jockel etwas ab ...
... bei Massengebrauch ...
Hallo, ja kürze mich ruhig (ab)... ... aber musst du unbedingt auf meine Masse anspielen..? Das ist gemein.. ;-(