Hallo,
würde gerne folgendes Umsetzen:
Ich habe eine Excel Tabelle mit vielen Kontaktdaten (Firma, Straße, Ort, Telefon etc., alle nach dem selben Schema sortiert). Jetzt würde ich gern in einer anderen Excel Tabelle bzw Arbeitsmappe eine Suchfunktion erstellen. Man sollte z.B. die ersten 4 Buchstaben in ein Suchfeld eintippen können und alle Firmen angezeigt bekommen, die diese 4 Buchstaben enthalten. Hat man die richtige Firma gefunden, sollen in einer Art Mustervisitenkarte alle benötigten Kontaktinformationen importiert werden (aus der großen Excel Tabelle).
Mein Ziel ist es, über eine Suchfunktion die benötigten Kontaktdaten zu importieren und übersichtlich darzustellen (es kommen noch weitere Felder hinzu). Meine Frage ist erstmal, ist das mit Excel möglich? Wenn ja, komme ich da an VBA wahrscheinlich nicht vorbei :20:
Wie gehe an dieses Thema heran? Muss ich die "große" Excel Tabelle mit den Kontaktdaten als Datenbank ansehen und verschiedene Datensätze importieren?
Danke schon mal vorab und schöne Feiertage!
Grüße Ben24
Hallo, ich sage mal: ja, das ist machbar. Ob da VBA nötig ist, hängt davon ab, wie du dir das Ganze vorstellst. Es könnte gut sein, dass man da kein VBA braucht. Poste doch bitte (d)eine (Beispiel) Datei... Nach Ansicht kann man mehr schreiben und sicher gezielter helfen.
Hallo,
so stelle ich mir das vor (siehe Anhang)
Arbeitsmappe 2 greift über die Suchfunktion auf Arbeitsmappe 1 zu. Wenn man die richtige Firma gefunden hat, werden die Daten aus Arbeitsmappe 1 in die grauen Felder importiert. Sind ähnliche Firmennamen vorhanden, soll in Arbeitsmappe 2 eine Art Auswahl möglich sein.
Grüße und vielen Dank!
(21.12.2016, 17:47)Ben24 schrieb: [ -> ]Hallo,
so stelle ich mir das vor (siehe Anhang)
...
Grüße und vielen Dank!
Hallo, und so könnte das aussehen - ohne VBA..:
| Arbeitsblatt mit dem Namen 'Tabelle2' |
| | A | B | C | D | E |
| 1 | Suchfunktion | Muste | | Mustermann GmbH | 1 |
| 2 | | | | Mustermann KG | 2 |
| 3 | | | | | |
| 4 | | | | | |
| 5 | Kontaktdaten: | 2 | | | |
| 6 | Firma | Mustermann KG | | | |
| 7 | Ort | Stuttgart | | | |
| 8 | Straße | Stuttgarter Str.1 | | | |
| 9 | Tel | | | | |
| 10 | etc…. | | | | |
| Zelle | Formel |
| D1 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$A$100;AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A1)));"") |
| E1 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A1));"") |
| D2 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$A$100;AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A2)));"") |
| E2 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A2));"") |
| D3 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$A$100;AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A3)));"") |
| E3 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A3));"") |
| D4 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$A$100;AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A4)));"") |
| E4 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A4));"") |
| D5 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$A$100;AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A5)));"") |
| E5 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A5));"") |
| B6 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$G$100;$B$5;VERGLEICH($A6;Tabelle1!$A$1:$G$1;0));"") |
| D6 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$A$100;AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A6)));"") |
| E6 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A6));"") |
| B7 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$G$100;$B$5;VERGLEICH($A7;Tabelle1!$A$1:$G$1;0));"") |
| B8 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$G$100;$B$5;VERGLEICH($A8;Tabelle1!$A$1:$G$1;0));"") |
| B9 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$G$100;$B$5;VERGLEICH($A9;Tabelle1!$A$1:$G$1;0));"") |
| B10 | =WENNFEHLER(INDEX(Tabelle1!$A$2:$G$100;$B$5;VERGLEICH($A10;Tabelle1!$A$1:$G$1;0));"") |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Vielen vielen Dank für deine Rückmeldung!
Leider funktionieren die Vorschläge(gelb) nicht bei mir. Wie lautet die Formel in B5?
Danke und Grüße
(22.12.2016, 12:05)Ben24 schrieb: [ -> ]Vielen vielen Dank für deine Rückmeldung!
Leider funktionieren die Vorschläge(gelb) nicht bei mir. Wie lautet die Formel in B5?
Danke und Grüße
Hallo, in deiner Datei klappt's doch...!!! B5 ist ein Eingabefeld - dort steht keine Formel.... Ist die Berechnung bei dir auf manuell gesetzt...? Ich habe das noch einwenig vereinfacht...:
| Arbeitsblatt mit dem Namen 'Tabelle2' |
| | A | B | C | D | E |
| 1 | Suchfunktion | Muster | | Mustermann GmbH | 1 |
| 2 | | | | Mustermann KG | 2 |
| 3 | | | | | |
| 4 | | | | | |
| 5 | Kontaktdaten: | 2 | | | |
| 6 | Firma | Mustermann KG | | | |
| 7 | Ort | Stuttgart | | | |
| 8 | Straße | Stuttgarter Str.1 | | | |
| 9 | Telefon | 01223/2314231 | | | |
| Zelle | Formel |
| D1 | =WENN(E1="";"";INDEX(Tabelle1!A:A;E1+1)) |
| E1 | =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$100)-1/(LINKS(Tabelle1!$A$2:$A$100;LÄNGE($B$1))=$B$1);ZEILE(A1));"") |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo,
die Berechnung ist auf Automatisch, muss ich das auf Manuell umstellen?
Ach B5 ist ein Eingabefeld...jetzt versteh ich deine Lösung auch
Danke!
Leider funktioniert die "Vorschau" weder auf automatischer noch manueller Berechnung in den Excel EInstellungen, mir wird kein Ergebnis Angezeigt. Wenn ich der Funktion WENNFEHLER() einen Ausgabewert gebe wird mir dieser angezeigt, irgendetwas mache ich also falsch
Grüße
Hallo Ben, nein - nicht auf manuell umstellen. Hier ist deine Datei zurück, bei mir sind Ergebnisse zu erkennen, wenn es denn welche gibt...
Hi Ben,
(22.12.2016, 13:54)Ben24 schrieb: [ -> ]Leider funktioniert die "Vorschau" weder auf automatischer noch manueller Berechnung in den Excel EInstellungen, mir wird kein Ergebnis Angezeigt. Wenn ich der Funktion WENNFEHLER() einen Ausgabewert gebe wird mir dieser angezeigt, irgendetwas mache ich also falsch
wenn Du in Deiner Datei ein Mal auf D1 und E1 gehst und Enter drückst, dann wird was angezeigt, diese Formeln dann runterziehen.