Clever-Excel-Forum

Liebe Experten,

folgendes Problem habe ich, zurzeit arbeite ich an einer Verrechnungsliste welche ich etwas automatisieren möchte.
Es handelt sich hier um Transporte welche monatlich abgerechnet werden.

Aktueller Stand ist folgender:
jeder einzelne Transport wird manuell eingeben --> das wird sich auch momentan nicht ändern.
Aber wenn es zur Verrechnung kommt, muss einzeln auf Kunden, Datum, Versandplz und Empfängerplz gefiltert werden.

Erster Schitt ist es, dass ich das Gewicht von allen Sendungen von einem Kunden mit gleichen Datum, Versandplz und Empfängerplz mit einer Summewenns formel erstellt habe.
=SUMMEWENNS($L$5:$L$1000;$A$5:$A$1000;$A5;$D$5:$D$1000;$D5;$I$5:$I$1000;$I5;$M$5:$M$1000;$M5)

Das Problem:
Das Gewicht ist essenziell, da es nicht nach Anzahl und Gewicht einer Sendungen verrechnet wird sonder mit dem Gesamtgewicht der Lieferung (gleichem Datum, Versender, Empfänger)!

Beispiel:
Kunde X; versendet am 8.11.;Versand von 1090; Empfänger 1230; 5 Sendungen á 25kg; entspricht 125kg Gesamtgewicht.
Jetzt möchte ich aber verhindern, dass ich diesen Wert mehrfach verrechne... da ja jetzt in jeder Zeile das Gesamtgewicht von 125kg steht.

Vielen Dank

MfG

Hallo,

deine Beschreibung reicht nicht aus, um dir gezielt Hilfe zu geben. Lade bitte eine Beispieldatei, die vom Aufbau her aber 100%-ig deinem Original gleichen muss, hoch. Es reichen etwa 20 Datensätze mit deinen bisherigen Formeln. Trage bitte noch in einigen Datensätzen dein Wunschergebnis ein. Lies mal bitte hier: http://www.clever-excel-forum.de/thread-326.html

Hallo WillWissen,

ist klar, nun habe ich eine Beispieldatei angefügt.
Im zweiten Reiter habe ich manuell eine Solltabelle erstellt und auch bei den ersten paar Datensätzen farblich markiert welche quasi gelöscht bzw. nicht angezeigt werden sollten.
Gelbe Markierung bedeutet, dass die Datensätze untereinander liegen, bei grünen Markierungen wiederum sind Datensätze dazwischen.

Das liegt daran, dass die Transporte nach Möglichkeit vergeben werden. Wenn ein Kunde am selben Tag nochmal anruft und um einen weiteren Transport bittet wird dieser danach hinzugefügt. Da die Transporte alle eine eigene Nummer haben.[attachment=8566]


Danke!

MfG MoZZo

Hola,

zur Info.

http://www.clever-excel-forum.de/thread-3037.html

Gruß,
steve1da

(20.12.2016, 10:05)steve1da schrieb: [ -> ]Hola,

zur Info.

http://www.clever-excel-forum.de/thread-3037.html

Gruß,
steve1da

Hallo,

ich habe linear ein Thema in einem weiterem Forum gestartet:
http://www.office-fragen.de/index.php/to...l#msg51047

MfG MoZZo

Hallo,

Arbeitsblatt mit dem Namen 'Beispieldatei'
	O	P	Q	R	S
1	Gesamtgewicht	Preis	Preis	Preis (35%)	Preis
2
3	KG Sendung	Preis	Preis	Preis (35%)	Preis
4	2	6,35 €	6,35 €	4,45 €	17,15 €
5	8	6,90 €	6,90 €	4,83 €	18,63 €
6	8	6,90 €	6,90 €	4,83 €	18,63 €
7	10	6,90 €			6,90 €
8	1,5	6,35 €			6,35 €
9	5	6,90 €			6,90 €
10	16,5	8,20 €			8,20 €
11					-   €
12					-   €
13	4	6,35 €			6,35 €
14	5,5	6,90 €			6,90 €
15	125	35,00 €	35,00 €	24,50 €	94,50 €
16					-   €
17					-   €
18					-   €
19					-   €

Zelle	Formel
O4	=WENN(ZÄHLENWENNS($A$4:$A4;$A4;$D$4:$D4;$D4;$I$4:$I4;$I4;$M$4:$M4;$M4)=1;SUMMEWENNS($L$4:$L$999;$A$4:$A$999;$A4;$D$4:$D$999;$D4;$I$4:$I$999;$I4;$M$4:$M$999;$M4);"")
P4	=WENN(O4="";"";INDEX(Beispielpreise!$B$1:$B$4;VERWEIS(O4;{0;5;15;35,01};{1;2;3;4}))*(1+(O4>35,01)*(O4-1)))
Q4	=WENN(H4="Sonderadresse";P4;"")
R4	=WENN(Q4="";"";P4*0,7)
S4	=SUMME(P4:R4)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Hallo BoskoBiati,

vielen Dank für deine Hilfe! Auf den ersten Blick und Prüfung scheint es perfekt zu funktionieren.
Ich danke dir!!!

Melde mich bei der nächsten Kontrolle nochmals!

MfG MoZZo