Clever-Excel-Forum

Normale Version: Makro automat. Verknuepfung aktualis. aber dateien sind Kennwort geschuetzt
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Hallo,

Kuwer hatte mir ja den schlanken code gegeben (nochmals Danke dafuer - hat mir sehr geholfen) damit sich in meiner MasterDatei automatisch die Verknuepfungen aktualiseren.


Code:
Sub Makro4()
   Dim strVerzeichnis As String
   Dim StrDatei As String
   Dim StrTyp As String
   Dim Dateiname As String
   strVerzeichnis = "C:\Users\gillnerc\desktop\desktop\cashneeds\current week\"
   StrTyp = "*.xlsm"
   Dateiname = Dir(strVerzeichnis & StrTyp)
   Do While Dateiname <> ""
       Workbooks.Open Filename:=strVerzeichnis & Dateiname
       ThisWorkbook.ChangeLink Name:=Dateiname, NewName:=Dateiname, Type:=xlExcelLinks
       ActiveWorkbook.Close True
       Dateiname = Dir
   Loop
End Sub


Nun muss ich aber alle QuellDateien mit einem Kennwort schuetzen und dann funktioniert die oben genannte Loesung natuerlich nicht mehr. Ich hatte es dann mit dem Makro Recorder versucht. Schritt 1 oeffent die Dateien mit Kennwortschutz - Das klappt ohne Problem
Schritt 2 sollte dann die Verknuepfungen aktualisieren, das klappt nicht mehr .
Hat vielleicht jemand eine Idee?


Code:
Sub OeffneKennwortDatei()
Dim Mappe As Workbook
Set Mappe = Application.Workbooks.Open(Filename:="C:\Users\gillnerc\desktop\desktop\cashneeds\Testmacro\next week\IT_cashneeds.xlsm", Password:="Treasury")
Set Mappe = Application.Workbooks.Open(Filename:="C:\Users\gillnerc\desktop\desktop\cashneeds\Testmacro\next week\DE_cashneeds.xlsm", Password:="DE1648")
Set Mappe = Application.Workbooks.Open(Filename:="C:\Users\gillnerc\desktop\desktop\cashneeds\Testmacro\next week\PL_cashneeds.xlsm", Password:="Mieszko966")
Windows("Cash Needs Europe week49_WE12-9_nextweekBeta.xlsm").Activate
    ActiveWorkbook.ChangeLink Name:="PL_cashneeds.xlsm", NewName:= _
        "PL_cashneeds.xlsm", Type:=xlExcelLinks
    ActiveWorkbook.ChangeLink Name:="IT_cashneeds.xlsm", NewName:= _
        "IT_cashneeds.xlsm", Type:=xlExcelLinks
    ActiveWorkbook.ChangeLink Name:="DE_cashneeds.xlsm", NewName:= _
        "DE_cashneeds.xlsm", Type:=xlExcelLinks
    Windows("PL_cashneeds.xlsm").Activate
    ActiveWindow.Close
    Windows("DE_cashneeds.xlsm").Activate
    ActiveWindow.Close
    Windows("IT_cashneeds.xlsm").Activate
    ActiveWindow.Close
    ActiveWorkbook.Save
End Sub
Hallo,

mit einer zusätzlichen Funktion z.B. so:
Sub Makro4()
  Dim strVerzeichnis As String
  Dim strDatei As String
  Dim StrTyp As String
  strVerzeichnis = "C:\Users\gillnerc\desktop\desktop\cashneeds\current week\"
  StrTyp = "*.xlsm"
  strDatei = Dir(strVerzeichnis & StrTyp)
  Do While strDatei <> ""
      Workbooks.Open Filename:=strVerzeichnis & strDatei, Password:=HolePasswort(strDatei)
      ThisWorkbook.ChangeLink Name:=strDatei, NewName:=strDatei, Type:=xlExcelLinks
      ActiveWorkbook.Close True
      strDatei = Dir
  Loop
End Sub

Private Function HolePasswort(strDatei As String) As String
 Select Case strDatei
   Case "IT_cashneeds.xlsm": HolePasswort = "Treasury"
   Case "DE_cashneeds.xlsm": HolePasswort = "DE1648"
   Case "PL_cashneeds.xlsm": HolePasswort = "Mieszko966"
 End Select
End Function
Gruß Uwe
Whao! Danke!
ich muss jetzt mal was Spenden hier fuer den Laden, stark wie ich hier immer Hilfe bekomme.
Und auf der Arbeit bin ich immer der Held mit den Loesungen Smile
Aber ich bin schon transparent und sage immer dass ich viel support aus dem Internet bekomme