Hallo zusammen,
in der angehängten Tabelle geht es darum, eine Formel zu entwickeln welche man in Zelle D2 eingibt und dann bestenfalls einfach nur runter ziehen kann.
Hintergrund ist der, dass der Bereich A2:C... aus einem anderen System in Excel gemapt wird. Und in Spalte D sollen in Excel die entsprechen Summen berechnet werden...
Danke u. Gruß
Daniel
Hallo,
Falls es nur um D2 geht:
falls du eine Formel für alle Ergebnisse der Spalte D benötigst:
Hätte ich hier eine Lösung mit einer (ausblendbaren) Hilfsspalte: ("Gesamtpreis" kommt dann in E1.)
Für D2:
Code:
=WENN(C2<>"";C2*B2;"")
runterziehen.
für E2:
Code:
=WENN((C2="")*(C3="");SUMME($E$3:$E$21)/2;WENN((C3>0)*(C2="");WENN((D3<>"")*(D2="");SUMME(D3:INDEX($D4:$D$34;VERGLEICH(WAHR;$D4:$D$34="";0)));"");C2*B2))
Sieht dann so aus:
Tabelle1 | A | B | C | D | E |
| 1 | Artikel Nr. | MENGE | Einzelpreis | Gesamtpreis | |
| 2 | | | | | 26450 |
| 3 | | | | | 5830 |
| 4 | BG 230 | 1 | 230 | 230 | 230 |
| 5 | BZ 231 | 1 | 560 | 560 | 560 |
| 6 | BT 232 | 2 | 780 | 1560 | 1560 |
| 7 | BH 233 | 1 | 390 | 390 | 390 |
| 8 | BG 234 | 3 | 940 | 2820 | 2820 |
| 9 | BG 235 | 1 | 270 | 270 | 270 |
| 10 | | | | | 15090 |
| 11 | AG 230 | 1 | 580 | 580 | 580 |
| 12 | AZ 231 | 6 | 870 | 5220 | 5220 |
| 13 | AT 232 | 1 | 360 | 360 | 360 |
| 14 | AH 233 | 1 | 440 | 440 | 440 |
| 15 | AG 234 | 8 | 980 | 7840 | 7840 |
| 16 | AG 235 | 1 | 650 | 650 | 650 |
| 17 | | | | | 5530 |
| 18 | YS 123 | 1 | 380 | 380 | 380 |
| 19 | YX 893 | 2 | 450 | 900 | 900 |
| 20 | HF 456 | 1 | 690 | 690 | 690 |
| 21 | OP 321 | 4 | 890 | 3560 | 3560 |
| verwendete Formeln | |
| Zelle | Formel | Bereich | N/A |
| D2: D21 | =WENN(C2<>"";C2*B2;"") | | |
| E2:E21 | {=WENN((C2="")*(C3="");SUMME($E$3:$E$21)/2;WENN((C3>0)*(C2="");WENN((D3<>"")*(D2="");SUMME(D3:INDEX($D4:$D$34;VERGLEICH(WAHR;$D4:$D$34="";0)));"");C2*B2))} | $E$2 | |
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!| Excel-Inn.de |
| Hajo-Excel.de |
| XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
| Add-In-Version 19.15 einschl. 64 Bit |
Hallo,
das geht auch so:
[html]
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B | C | D |
| 1 | Artikel Nr. | MENGE | Einzelpreis | Gesamtpreis |
| 2 | | | | 26.450 |
| 3 | | | | 5.830 |
| 4 | BG 230 | 1 | 230 | 230 |
| 5 | BZ 231 | 1 | 560 | 560 |
| 6 | BT 232 | 2 | 780 | 1.560 |
| 7 | BH 233 | 1 | 390 | 390 |
| 8 | BG 234 | 3 | 940 | 2.820 |
| 9 | BG 235 | 1 | 270 | 270 |
| 10 | | | | 15.090 |
| 11 | AG 230 | 1 | 580 | 580 |
| 12 | AZ 231 | 6 | 870 | 5.220 |
| 13 | AT 232 | 1 | 360 | 360 |
| 14 | AH 233 | 1 | 440 | 440 |
| 15 | AG 234 | 8 | 980 | 7.840 |
| 16 | AG 235 | 1 | 650 | 650 |
| 17 | | | | 5.530 |
| 18 | YS 123 | 1 | 380 | 380 |
| 19 | YX 893 | 2 | 450 | 900 |
| 20 | HF 456 | 1 | 690 | 690 |
| 21 | OP 321 | 4 | 890 | 3.560 |
| Zelle | Formel |
| D2 | =SUMME(D3:D3000)/2 |
| D3 | =WENN(A3="";SUMME(D4:INDEX(D:D;AGGREGAT(15;6;ZEILE($A4:$A$1000)/($A4:$A$1000="");1)-1));C3*B3) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
[/html]
Sind zwei Formeln, ginge auch in einer, auch wenn es nicht sinnvoll ist:
Code:
=wenn(zeile()=2;SUMME(D$3:D$3000)/2;WENN(A2="";SUMME(D3:INDEX(D:D;AGGREGAT(15;6;ZEILE($A3:$A$1000)/($A3:$A$1000="");1)-1));C2*B2))
in D2, nach unten ziehen!
@Luffy, gleiches Problem wie hier:
http://www.clever-excel-forum.de/thread-...l#pid59687
und gleiche Lösung!
Vielen Dank an alle fleißigen Formelentwickler,
Die Lösung von BoskoBiati ist genau das, was ich gebraucht habe. Vielen Dank!