Hallo Zusammen!
Versuche es jetzt schon mit allen möglichen Formeln und komme einfach nicht hin!
Wie lauten die Formeln für die Zellen I2 bis I12
Möchte nur den Dienstfreien Tag angezeigt bekommen!
Ich weis ihr könnt mir hier helfen!
Danke im Voraus und LG
Hi
das geht bestimmt besser, funktioniert aber mit deinen Daten
in J2 und runterziehen
Code:
={INDEX($B$1:$F$1;;MAX(WENN($B$15:$F$19=$H2;SPALTE($A:$E);-1)))}
Matrix-Formel(mit STRG-SHFT-ENTER abschliessen)
Hey ja das funktioniert!
Danke vielmals!
Kann mir Excel vielleicht noch das Feld Leer lassen anstelle von "#Wert" wenn ein Name nicht gefunden wird?
LG
(25.11.2016, 08:31)Gerald123 schrieb: [ -> ]Hey ja das funktioniert!
Danke vielmals!
Kann mir Excel vielleicht noch das Feld Leer lassen anstelle von "#Wert" wenn ein Name nicht gefunden wird?
LG
=WENNFEHLER(...;"") (... =deine Formel)
Hi,
sollte das dann so aussehen:
=WENNFEHLER(...;"") (...={INDEX($B$1:$F$1;;MAX(WENN($B$15:$F$19=$H2;SPALTE($A:$E);-1)))}
Funzt irgendwie nicht!!
LG
(25.11.2016, 14:00)Gerald123 schrieb: [ -> ]Hi,
sollte das dann so aussehen:
=WENNFEHLER(...;"") (...={INDEX($B$1:$F$1;;MAX(WENN($B$15:$F$19=$H2;SPALTE($A:$E);-1)))}
Funzt irgendwie nicht!!
LG
Nein.
Code:
{=WENNFEHLER(INDEX($B$1:$F$1;;MAX(WENN($B$15:$F$19=$H2;SPALTE($A:$E);-1)));"")}
(ungestestet)
Die geschwungenen Klammern nicht dazuschreiben sondern die Formel mit STRG + UMSCHALT + ENTER abschließen.
Hallo, ich würde so tun..:
Code:
=WENNFEHLER(INDEX($A$1:$F$1;AGGREGAT(14;6;SPALTE(A:F)/($A$15:$F$19=H2);1));"")
Ansonsten siehe unten..:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F | G | H | I | J | K |
1 | | Montag | Dienstag | Mittwoch | Donnerstag | Freitag | | | Dienstfrei | | |
2 | Tour 1 | MA 1 | MA 1 | MA 1 | MA 1 | SP 2 | | MA 1 | Freitag | Freitag | Freitag |
3 | Tour 2 | SP 2 | MA 2 | MA 2 | MA 2 | MA 2 | | MA 2 | Montag | Montag | Montag |
4 | Tour 3 | MA 3 | MA 8 | MA 3 | MA 3 | MA 3 | | MA 3 | Dienstag | Dienstag | Dienstag |
5 | Tour 4 | MA 4 | MA 7 | MA 4 | MA 4 | MA 4 | | MA 4 | Dienstag | Dienstag | Dienstag |
6 | Tour 5 | MA 5 | SP 1 | MA 5 | MA 5 | MA 5 | | MA 5 | Dienstag | Dienstag | Dienstag |
7 | Tour 6 | MA 6 | MA 6 | SP 2 | MA 6 | MA 6 | | MA 6 | Mittwoch | Mittwoch | Mittwoch |
8 | Tour 7 | MA 7 | | MA 7 | | MA 7 | | MA 7 | Donnerstag | Donnerstag | Donnerstag |
9 | Tour 8 | MA 8 | | MA 8 | | MA 8 | | MA 8 | Donnerstag | Donnerstag | Donnerstag |
10 | Tour 9 | MA 9 | SP 2 | MA 9 | MA 9 | MA 9 | | MA 9 | Dienstag | Dienstag | Dienstag |
11 | Tour 10 | SP 1 | | SP 1 | | SP 1 | | SP 1 | Donnerstag | Donnerstag | Donnerstag |
12 | | | | | | | | SP 2 | Donnerstag | Donnerstag | Donnerstag |
13 | | | | | | | | | | | |
14 | | | | | | | | | | | |
15 | Dienstfrei | MA 2 | MA 3 | MA 6 | MA 7 | MA 1 | | | | | |
16 | Dienstfrei | | MA 4 | | MA 8 | | | | | | |
17 | Dienstfrei | | MA 5 | | SP 1 | | | | | | |
18 | Dienstfrei | | MA 9 | | SP 2 | | | | | | |
19 | Dienstfrei | | | | | | | | | | |
Zelle | Formel |
J2 | {=WENNFEHLER(INDEX($B$1:$F$1;;MAX(WENN($B$15:$F$19=$H2;SPALTE($A:$E);-1)));"")} |
K2 | =WENNFEHLER(INDEX($A$1:$F$1;AGGREGAT(14;6;SPALTE(A:F)/($A$15:$F$19=H2);1));"") |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Danke an ALLE
Funktioniert natürlich bestens!
LG
(25.11.2016, 14:14)Gerald123 schrieb: [ -> ]Danke an ALLE
Funktioniert natürlich bestens!
LG
Hast du die matrixformelfreie Variante mit AGGREGAT() gesehen..?