Das Jahr neigt sich dem Ende zu und das bedeutet wohl überall, dass neue Kalender erstellt werden... ich reihe mich mal ein. :19:
Den angehängten Kalender habe ich für 2016 schon genutzt, möchte ihn aber nicht jedes Jahr auf's Neue händisch erstellen müssen.
Gesucht ist also ein Kalender, der
- sich bei Eingabe des aktuellen Jahres in P2 selbst aktualisiert (vor allem in Bezug auf die Anzahl der Monatstage (Schaltjahr)
- und bei händischer Eingabe möglichst weniger Zellen in C9, D9 und E9 und den darauf folgenden Zeilen den vorgegebenen Rhythmus selbst weiterschreibt.
Ich habe leider derzeit keine rechte Idee, wie ich richtig an die Sache herangehe. Hat jemand Vorschläge für mich?
Danke schon einmal im Voraus!
Hallo,
Zitat:sich bei Eingabe des aktuellen Jahres in P2 selbst aktualisiert (vor allem in Bezug auf die Anzahl der Monatstage (Schaltjahr)
dazu findest du über eine Google-Suche unzählige Vorschläge und Umsetzungen.
Man könnte z.B. in B1 mit eine Formel wie =DATUM(P2;1;1) arbeiten und die Zelle benutzerdefiniert mit dem Format T versehen. In A9 kommt die Formel =B1 und die Zelle wird benutzerdefiniert mit dem Format TTT versehen.
In B10 dann z.B. die Formel =WENN(B9="";"";WENN(MONAT(B9)=MONAT(B9+1);B9+1;"")) und einfach nach unten kopieren.
Zitat:und bei händischer Eingabe möglichst weniger Zellen in C9, D9 und E9 und den darauf folgenden Zeilen den vorgegebenen Rhythmus selbst weiterschreibt.
.
Da solltest du dich mal ein wenig darüber auslassen wie sich dieser Rythmus berechnet.
(19.11.2016, 10:21)Peter schrieb: [ -> ]Da solltest du dich mal ein wenig darüber auslassen wie sich dieser Rythmus berechnet.
Hallo Peter, danke einmal soweit für deine Antwort.
Der Rhythmus berechnet sich eigentlich ganz einfach: Er läuft immer von A bis D durch und das an zwei Tagen hintereinander. Startet Spalte C also am 1. Januar mit "A", so ist Spalte D automatisch "B" und Spalte E automatisch "C".
Das wird nun entweder noch einen Tag wiederholt - oder aber, sofern es schon der zweite Tag gewesen sein sollte, in der nächsten Zeile mit dem nächsten Buchstaben fortgesetzt.
War also Spalte E zuletzt "C", wie oben beschrieben, geht es in Spalte C weiter mit "D". Danach folgt wieder "A" in Spalte D und "B" in Spalte E.
Ich hoffe, das ist so weit verständlich.
Ich habe eine Idee:
Ich habe mir für 01.01.2017 das unformatierte Datum von Excel ausgeben lassen (Tag 42736).
Wenn ich nun die Buchstaben gedanklich Zahlen gleichsetze (A=1, B=2, C=3 und D=4), könnte ich doch eigentlich anhand der Teilbarkeit durch 4 und dem verbleibenden Rest für jeden Tag den entsprechenden Wert bestimmt, wenn ich weiß, dass der 01.01.2017 beispielsweise 3 entspricht.
Fragt sich nur noch, wie ich dahinkomme?!
Moin!
Hä? :20:
Die Werte stehen in C:F (A, B, C, D)
Markiere in der entsprechenden Zeile C:F und ziehe nach rechts.
Alternativ:
Gib im Namenfeld oben links C1:AB1 (Deinen Kalenderbereich) ein, Enter.
Start, Bearbeiten, Füllbereich, Reihe
Typ: Autoausfüllen, Enter
Fettich
Gruß Ralf
So, wie ich dich verstehe, ist der Füllbereich dann aber nicht dynamisch, würde sich also 2018 nicht anpassen, oder?
Die Buchstaben sind jahresübergreifend durchlaufend, d.h. zu Beginn 2018 sieht der Kalender anders aus als 2017.
Ich habe ein wenig herumgebastelt und eine Version hinbekommen, die sich laufend aktualisiert, allerdings mit Zahlen statt mit Buchstaben (Derzeit funktioniert nur der Mai).
Vielleicht ist damit besser verständlich, was ich meine.
Zur Erläuterung:
In N4 habe ich mein Startdatum, mit dem ich erstmals zu rechnen anfange. C8, D8 und E8 sind vorgegeben durch die Buchstaben, die Spalten darunter ergeben sich aus diesem Startwert.
Mir fehlt nun einzig noch ein Weg, statt der Zahlen wieder Buchstaben anzeigen zu lassen...
Hallo,
hier mal eine Version von mir:
[
attachment=8060]
Der erste und der zweite Monat sind unterschiedlich, der zweite Monat kann dann blockweise kopiert werden.
Hallo Edgar,
danke für deine Antwort und sorry für die späte Rückmeldung - war beruflich eingespannt.
Dein Kalender scheint auf den ersten Blick zu funktionieren, auch wenn ich mir über deine Herangehensweise noch nicht so ganz im Klaren bin...
Was mir aber aufgefallen ist:
Gebe ich ein neues Jahr ein, ändern sich die Buchstaben nicht. Der Kalender nimmt leider im Februar so auch keine Rücksicht auf Schaltjahre.
Wie kann ich denn festlegen, ob ich am 1. und 2. Januar den gleichen Buchstaben in der gleichen Schicht habe oder schon den nächsten?
Hallo,
hier mal eine Verbesserung:
| Arbeitsblatt mit dem Namen '2016' |
| | A | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q |
| 2 | | | | | | | | | | | | | Kalender | 2016 |
| 3 | | | | | | | | | | | | | Schichtbeginn | | | B | |
| 4 | Auswahl: | | | ohne | | | | | | | | | Durchlauf: | | | 2 | |
| 5 | | | | | | | | | | | | | | | | | |
| 6 | | | | | | | | | | | | | | | | | |
| 7 | Januar | | Februar | | Juli |
| 8 | | | Tag | Nacht | Zus. | | | | Tag | Nacht | Zus. | | | | Tag | Nacht | Zus. |
| 9 | Fr | 1 | B | C | D | | Mo | 1 | B | C | D | | Fr | 1 | D | A | B |
| 10 | Sa | 2 | C | D | A | | Di | 2 | B | C | D | | Sa | 2 | A | B | C |
| 11 | So | 3 | C | D | A | | Mi | 3 | C | D | A | | So | 3 | A | B | C |
| Zelle | Formel |
| A9 | =WENN(B9="";"";B9) |
| B9 | =WENN(MONAT(A$7)<>MONAT(A$7+ZEILE(A1)-1);"";A$7+ZEILE(A1)-1) |
| C9 | =ZEICHEN(REST(KÜRZEN((B9-$A$7+1)/2;);4)+CODE($P$3)) |
| D9 | =WENN(C9="";"";VERWEIS(C9;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| E9 | =WENN(D9="";"";VERWEIS(D9;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| A10 | =WENN(B10="";"";B10) |
| B10 | =WENN(MONAT(A$7)<>MONAT(A$7+ZEILE(A2)-1);"";A$7+ZEILE(A2)-1) |
| C10 | =WENN(B10="";"";WENN((C9=C8)+(P4=2);VERWEIS(C9;{"A";"B";"C";"D"};{"B";"C";"D";"A"});C9)) |
| D10 | =WENN(C10="";"";VERWEIS(C10;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| E10 | =WENN(D10="";"";VERWEIS(D10;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| G9 | =WENN(H9="";"";H9) |
| H9 | =WENN(MONAT(G$7)<>MONAT(G$7+ZEILE(G1)-1);"";G$7+ZEILE(G1)-1) |
| I9 | =WENN((VERWEIS(MAX(B9:B39);B9:C39)=VERWEIS(KGRÖSSTE(B9:B39;2);B9:C39));VERWEIS(VERWEIS(MAX(B9:B39);B9:C39);{"A";"B";"C";"D"};{"B";"C";"D";"A"});VERWEIS(MAX(B9:B39);B9:C39)) |
| J9 | =WENN(I9="";"";VERWEIS(I9;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| K9 | =WENN(J9="";"";VERWEIS(J9;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| G10 | =WENN(H10="";"";H10) |
| H10 | =WENN(MONAT(G$7)<>MONAT(G$7+ZEILE(G2)-1);"";G$7+ZEILE(G2)-1) |
| I10 | =WENN(H10="";"";WENN((I9=I8)+(VERWEIS(MAX(B9:B39);B9:C39)=I9)*(ZEILE()=10);VERWEIS(I9;{"A";"B";"C";"D"};{"B";"C";"D";"A"});I9)) |
| J10 | =WENN(I10="";"";VERWEIS(I10;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| K10 | =WENN(J10="";"";VERWEIS(J10;{"A";"B";"C";"D"};{"B";"C";"D";"A"})) |
| Zelle | Gültigkeitstyp | Operator | Wert1 | Wert2 |
| D4 | Liste | | =$B$44:$B$48 | |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
In P3 wird die erste Schicht eingetragen, in P4 ob es der erste oder zweite Tag der Schicht ist.
[
attachment=8142]Hallo Ratsuchender
Bin neu hier
Beim durch stöbern bin ich auf deine Anfrage getroffen
Habe mir erlaubt deinen Kalender zu downloaden und einiges geändert
Als Anlage übersende ich mal meinen Versuch
Ist ein automatischer Kalender, musst nur die Jahreszahl bei den Einstellungen und ggf. das Bundesland auswählen
Im Jahresplan hab ich die Schicht 1 genommen
Hoffe das ich dir helfen konnte