Hallo an alle,
ich habe gerade nochmal eine kleine Verständnisfrage:
Angenommen ich habe in Spalte A absolute Werte, in Spalte B Prozentwerte und in Spalte C und D und E möchte ich per WENN(UND 2 Bedingungen prüfen.
Code:
Zahl Prozent Zelle & % Spalte & % Spalte ohne %
23 0,184 =WENN(UND(A2>20;B2<35%);"Ja";"Nein") =WENN(UND(A:A>20;B:B<35%);"Ja";"Nein") =WENN(UND(A:A>20;B:B<35);"Ja";"Nein")
26 0,88 =WENN(UND(A3>20;B3<35%);"Ja";"Nein") =WENN(UND(A:A>20;B:B<35%);"Ja";"Nein") =WENN(UND(A:A>20;B:B<35);"Ja";"Nein")
Code:
Zahl Prozent Zelle & % Spalte & % Spalte ohne %
23 18,40% Ja Ja Ja
26 88,00% Nein Nein Ja
Die Prozentspalte ist auch als "Prozent" formatiert in Excel.
Meine Fragen hierbei sind nun:
1. Warum ist es kein Unterschied bei Spalte C und D, ob man die Spalte (A:A) oder die Zelle (A2) als Prüfungsbereich angibt? Es wird scheinbar jeweils nur die Zelle geprüft und nicht geguckt, ob irgendein Wert in der gesamten Spalte größer als 20 ist (ist auch so gewollt).
2. Wie sähe die Formel aus, wenn ich in der gesamten Spalte das Kriterium suchen wollte?
3. Warum verändert sich bei "Spalte ohne %" das Nein zum Ja, weil ich das "%" weggelassen habe? Muss man das mit angeben oder nicht? Hängt das dann von der Formatierung der Spalte "Prozent" ab?
Danke euch für eine Erklärung!
Anfängerfrage
Hallo,
Code:
WENN(UND(A:A>20;B:B<35%);"Ja";"Nein")
Das ist Quatsch, da man so keine ganze Spalte prüfen kann. Excel hilft sich hier, indem es die aktuelle Zeile auswertet!
Ganze Spalten prüft man mit Zählenwenn!
1% ergibt 0,01, wenn Du das % wegläßt und auf eine Prozent-formatierte Zelle anwendest entspricht das 100%
[html]
| Arbeitsblatt mit dem Namen 'Tabelle3' |
| | A | B | C | D | E | F | G | H |
| 1 | | | | | | | | |
| 2 | 23 | 18,4% | 1 | Ja | Ja | 1 | 1 | 1 |
| 3 | 26 | 88,0% | 0 | Nein | Ja | 1 | 0 | |
| 4 | 19 | 18,40% | 0 | Nein | Nein | 1 | 0 | |
| 5 | 19 | 88% | 0 | Nein | Nein | 1 | 0 | |
| 6 | | | | | | | 0 | |
| Zelle | Formel |
| C2 | =WENN(UND(A2>20;B2<35%);1;) |
| D2 | =WENN(UND(A:A>20;B:B<35%);"Ja";"Nein") |
| E2 | =WENN(UND(A:A>20;B:B<35);"Ja";"Nein") |
| F2 | =WENN(ZÄHLENWENN(A:A;">20")*ZÄHLENWENN(B:B;"<35%");1;) |
| G2 | =WENN((A2>20)*(B2<35%);1;) |
| H2 | =ZÄHLENWENN(G:G;1) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
[/html]
Hallo,
Zitat:B:B<35
35 = 3500%
1=100%
0,5 =50%
usw..
Bereichsüberprüfung könnte so aussehen
=WENN(UND(MIN(A1:A4)>20;MAX(B1:B4)<35%);"ja";"nein")
Das würde "ja" ausgeben wenn alle Zahlen im Bereich A1:A4 größer als 20 sind und alle Prozentwerte in B1:B4 kleiner als 35% sind.
A:A da wird die aktuelle Zeile in der sich die Formel befindet aus Spalte A genommen
Hallo Chris,
ich denke das sollte eher so aussehen:
Code:
=WENN(UND(MAX(A1:A4)>20;MIN(B1:B4)<35%);"ja";"nein")
[html]
| Arbeitsblatt mit dem Namen 'Tabelle3' |
| | A | B | C | D | E | F | G | H |
| 1 | | | | | | | 1 | |
| 2 | 23 | 18,4% | ja | Ja | Ja | ja | ja | nein |
| 3 | 26 | 88,0% | nein | Nein | Ja | | nein | ja |
| 4 | 19 | 18,40% | nein | Nein | Nein | | nein | |
| 5 | 19 | 88% | nein | Nein | Nein | | nein | |
| 6 | | | nein | Nein | Nein | | nein | |
| Zelle | Formel |
| C2 | =WENN(UND(A2>20;B2<35%);"ja";"nein") |
| D2 | =WENN(UND(A:A>20;B:B<35%);"Ja";"Nein") |
| E2 | =WENN(UND(A:A>20;B:B<35);"Ja";"Nein") |
| F2 | =WENN(ZÄHLENWENN(A:A;">20")*ZÄHLENWENN(B:B;"<35%");"ja";"nein") |
| G1 | =ZÄHLENWENN(G2:G6;"ja") |
| G2 | =WENN((A2>20)*(B2<35%);"ja";"nein") |
| H2 | =WENN(UND(MIN(A1:A4)>20;MAX(B1:B4)<35%);"ja";"nein") |
| H3 | =WENN(UND(MAX(A1:A4)>20;MIN(B1:B4)<35%);"ja";"nein") |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
[/html]
Hallo Edgar,
möglich,
dass wäre dann ein oder ;)
Hi,
je nachdem. Es ist ja nicht klar, ob alle Werte das Kriterium erfüllen müssen oder in jeder Spalte nur ein Wert.
Hi,
aus
Zitat:=WENN(UND(A2>20;B2<35%);"Ja";"Nein")
gehe ich davon aus das zumindest die Werte einer Zeile übereinstimmen sollen.
und das mit min, max hatte ich so ausgelegt. :)
"Das würde "ja" ausgeben wenn alle Zahlen im Bereich A1:A4 größer als 20 sind und alle Prozentwerte in B1:B4 kleiner als 35% sind."
sollte es ein ODER sein, dass zumindest die Zeilenbedingung erfüllt, könnte es so oder so ähnlich aussehen
{=WENN(SUMME((A1:A4>20)*(B1:B4<35%)*(B1:B4<>""));"Ja";"Nein")}
{} nicht eingeben sondern Formel wird mit Strg+Umschalt+Enter abgeschlossen.
Hallo,
dann hätte ich doch noch das:
[html]
| Arbeitsblatt mit dem Namen 'Tabelle3' |
| | A | B | C |
| 2 | 23 | 18,4% | 1 |
| 3 | 26 | 88,0% | 1 |
| 4 | 19 | 18,40% | FALSCH |
| 5 | 19 | 88% | |
| Zelle | Formel |
| C2 | =ZÄHLENWENNS(A:A;">20";B:B;"<35%") |
| C3 | =SUMMENPRODUKT((A:A>20)*(B:B>35%)) |
| C4 | =ZÄHLENWENNS(A:A;">20";B:B;"<35%")=ANZAHL(A:A) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
[/html]
Danke für euren zahlreichen Antworten mal wieder :D
Also das
A:A bzw
B:B verhält sich also hier in dieser Formel
Code:
WENN(UND(A:A>20;B:B<35%);"Ja";"Nein")
wie das
A2 bzw.
B:2 in dieser Formel?!
Code:
=WENN(UND(A2>20;B2<35%);"Ja";"Nein")
Da beide dann dasselbe liefern, welche wäre denn die "sauberere" Formel?
Danke nochmal!
Hallo,
nochmal ganz deutlich:
Code:
WENN(UND(A:A>20;B:B<35%)
geht gar nicht! Das liefert zwar hier aufgrund der Bedingung den Wert genau für die Zeile, in der die Formel steht, aber im Normalfall bringt sie nur Fehler!!!