Hallo @all,
| A | B | C | D | E | F |
1 | | | | 23,00 € | 0,00 € | 23,00 € |
2 | | | x | 34,00 € | -13,60 € | 20,40 € |
3 | x | x | x | 34,00 € | -34,00 € | 0,00 € |
4 | x | | x | 34,00 € | -20,40 € | 13,60 € |
5 | x | | x | 34,00 € | -20,40 € | 13,60 € |
6 | x | | | 23,00 € | -4,60 € | 18,40 € |
Zelle | Formel |
E1 | =(ANZAHL2(A1)*0,2+ANZAHL2(B1:C1)*0,4)*D1*-1 |
F1 | =D1+E1 |
E2 | =(ANZAHL2(A2)*0,2+ANZAHL2(B2:C2)*0,4)*D2*-1 |
F2 | =D2+E2 |
E3 | =(ANZAHL2(A3)*0,2+ANZAHL2(B3:C3)*0,4)*D3*-1 |
F3 | =D3+E3 |
E4 | =(ANZAHL2(A4)*0,2+ANZAHL2(B4:C4)*0,4)*D4*-1 |
F4 | =D4+E4 |
E5 | =(ANZAHL2(A5)*0,2+ANZAHL2(B5:C5)*0,4)*D5*-1 |
F5 | =D5+E5 |
E6 | =(ANZAHL2(A6)*0,2+ANZAHL2(B6:C6)*0,4)*D6*-1 |
F6 | =D6+E6 |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Lässt sich die Formel in Spalte E kürzer schreiben?
Es sollen vom Wert im Spalte D für das x in A 20% und für die x in Spalte B und C je 40% berechnet und addiert werden.
Hallo Conny,
z.B. so: {=SUMME((A1:C1="x")*{0,2.0,4.0,4})*D1}
Gruß Uwe
Hallo, oder kürzer..: (sieht länger aus... aber...) @Uwe kann es sein dass du die Vorgabe "*-1" geflissentlich überlesen hast..?
Arbeitsblatt mit dem Namen 'Tabelle3' |
| G | H |
1 | 0 | 0 |
2 | -13,6 | 13,6 |
3 | -34 | 34 |
4 | -20,4 | 20,4 |
5 | -20,4 | 20,4 |
6 | -4,6 | 4,6 |
Zelle | Formel |
G1 | {=SUMME((A1:C1="x")*{20.40.40})%*-D1} |
H1 | {=SUMME((A1:C1="x")*{0,2.0,4.0,4})*D1} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg |
Hallo Jörg,
(13.11.2016, 17:03)Jockel schrieb: [ -> ]@Uwe kann es sein dass du die Vorgabe "*-1" geflissentlich überlesen hast..?
das hatte ich tatsächlich vergessen.
Und noch 2 Zeichen weniger: :17:
| F | G | H |
1 | 23,00 € | 0 | 0 |
2 | 20,40 € | | |
3 | 0,00 € | | |
4 | 13,60 € | | |
5 | 13,60 € | | |
6 | 18,40 € | | |
Formeln der Tabelle |
Zelle | Formel | G1 | {=SUMME((A1:C1="x")*{20.40.40})%*-D1} | H1 | {=SUMME((A1:C1>0)*{20.40.40})%*-D1} |
|
Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen! |
Matrix verstehen |
Gruß Uwe
Hallo ihr zwei,
das mit dem Minuszeichen habe sogar ich gemerkt und in der Formel geändert.
Zur Erklärung:
Ich habe ein Formular von meinem Arbeitgeber mit Eingabefeldern und geschützten Berechnungsfeldern.
Mir ist nur rätselhaft, wieso genau in diesem Feld der Ausfüllenden den Betrag selbst ausrechnen muss.
Deshalb die Formeln als Vorschlag für den "Formularentwickler".
Hallo,
geht bei gleicher Formellänge auch ohne Matrix!!!!:
Code:
=((A1<>"")/5+ANZAHL2(B1:C1)*0,4)*-D1
=(ANZAHL2(A1:C1)*0,4-(A1<>"")/5)*-D1