Hallo!! :)
möchte in der angehängten Tabelle, ein Problem lösen, das ich zwar einfach mit VBA lösen könnte, aber nicht die geringste Ahnung habe wie ich da mit 'ner Formel rangehe:
Wenn die Kombination C3 + D3
mit einer Kombination im Bereich F3:G10 übereinstimmt,
soll aus der entsprechenden Zeile, der Wert aus Spalte H, in Zelle A3 eingetragen werden.
Wäret Ihr so lieb, mich da etwas anzuschubsen? ;)
Dankeschön!!
LG Michael
Hi Michael,
baue dir 2 Hilfsspalten (farbig hinterlegt) und blende sie einfach aus.
FORUM | A | B | C | D | E | F | G | H | I |
| 1 | Partnerin | Datum | Tag | Nr | HS | | Tag | Nr | HS |
| 2 | | | | | | | | | |
| 3 | Jutta | 01.02.2017 | Mi | 1 | Mi1 | | Mo | 1 | Mo1 |
| 4 | Jutta | 01.02.2017 | Mi | 2 | Mi2 | | Di | | Di |
| 5 | Jutta | 02.02.2017 | Do | 1 | Do1 | | Mi | 1 | Mi1 |
| 6 | 0 | 03.02.2017 | Fr | | Fr | | Mi | 2 | Mi2 |
| 7 | 0 | 04.02.2017 | Sa | | Sa | | Do | 1 | Do1 |
| 8 | 0 | 05.02.2017 | So | | So | | Fr | | Fr |
| 9 | Anja | 06.02.2017 | Mo | 1 | Mo1 | | Sa | | Sa |
| 10 | 0 | 07.02.2017 | Di | | Di | | So | | So |
| 11 | Jutta | 08.02.2017 | Mi | 1 | Mi1 | | | | |
| 12 | Jutta | 08.02.2017 | Mi | 2 | Mi2 | | | | |
| 13 | Jutta | 09.02.2017 | Do | 1 | Do1 | | | | |
| 14 | | 10.02.2017 | Fr | 0 | Fr0 | | | | |
| 15 | | 11.02.2017 | Sa | 0 | Sa0 | | | | |
| 16 | | 12.02.2017 | So | 0 | So0 | | | | |
| 17 | Anja | 13.02.2017 | Mo | 1 | Mo1 | | | | |
| 18 | | 14.02.2017 | Di | 0 | Di0 | | | | |
| 19 | Jutta | 15.02.2017 | Mi | 1 | Mi1 | | | | |
| 20 | Jutta | 15.02.2017 | Mi | 2 | Mi2 | | | | |
| Formeln der Tabelle |
| Zelle | Formel | | A3 | =WENNFEHLER(INDEX($J$3:$J$10;VERGLEICH(E3;$I$3:$I$10;0));"") | | E3 | =C3&D3 | | I3 | =G3&H3 |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Hallo Steve,
danke, auf den ersten Blick nicht wirklich, aber mal sehen, ob ich da einen Ansatz für meine Lösung finde.
Diese Matrixfunktionen sind für mich irgendwie nicht wirklich nachvollziehbar. ;)
LG Michael
Hallo,
so:
Code:
=WENN(INDEX(H:H;VERGLEICH(C3&D3;F:F&G:G;0))<>"";INDEX(H:H;VERGLEICH(C3&D3;F:F&G:G;0));"")
mit STRG+SHIFT+ENTER abschließen!
genau nach dem gezeigten Link!
Hi Edgar,
da wäre aber doch eine Hilfsspaltenlösung einer ressourcenfressenden Matrix-Lösung vorzuziehen.
Hallo, ich hätte das so gelöst...:
off topic:
ganz toller Betreff... da sieht man, dass du dir richtig Mühe gegeben hast...
| Arbeitsblatt mit dem Namen 'FORUM' |
| | A | B | C | D | E | F | G | H |
| 1 | Partnerin | Datum | Tag | Nr | | Tag | Nr | Partnerin |
| 2 | | | | | | | | |
| 3 | Jutta | 01.02.2017 | Mi | 1 | | Mo | 1 | Anja |
| 4 | Jutta | 01.02.2017 | Mi | 2 | | Di | | |
| 5 | Jutta | 02.02.2017 | Do | 1 | | Mi | 1 | Jutta |
| 6 | | 03.02.2017 | Fr | | | Mi | 2 | Jutta |
| 7 | | 04.02.2017 | Sa | | | Do | 1 | Jutta |
| 8 | | 05.02.2017 | So | | | Fr | | |
| 9 | Anja | 06.02.2017 | Mo | 1 | | Sa | | |
| 10 | | 07.02.2017 | Di | | | So | | |
| 11 | Jutta | 08.02.2017 | Mi | 1 | | | | |
| 12 | Jutta | 08.02.2017 | Mi | 2 | | | | |
| 13 | Jutta | 09.02.2017 | Do | 1 | | | | |
| 14 | | 10.02.2017 | Fr | 0 | | | | |
| 15 | | 11.02.2017 | Sa | 0 | | | | |
| Zelle | Format | Wert |
| A3 | Standard;; | Jutta |
| Zelle | Formel |
| A3 | =INDEX($H$3:$H$10;AGGREGAT(15;6;ZEILE($F$3:$F$10)-2/(($F$3:$F$10=C3)*($G$3:$G$10=D3));1)) |
| Zelle | Gültigkeitstyp | Operator | Wert1 | Wert2 |
| A1 | Eingabe | zwischen | | |
| A2 | Eingabe | zwischen | | |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
(04.11.2016, 14:32)WillWissen schrieb: [ -> ]Hi Edgar,
da wäre aber doch eine Hilfsspaltenlösung einer ressourcenfressenden Matrix-Lösung vorzuziehen.
Hallo Günter, ohne Hilfsspalte und ohne Matrixformel ginge auch ..:
siehe (auch) -->
http://www.clever-excel-forum.de/thread-...l#pid57149
Code:
=WENNFEHLER(VERWEIS(2;1/($F$3:$F$10&"*"&$G$3:$G$10=C3&"*"&D3);$H$3:$H$10);"")
Ihr seid spitze!!!
Die Matrixlösung funktioniert einwandfrei, Ressourcenfresser ist hierbei nicht relevant. ;)
Die anderen Vorschläge probiere ich noch aus.
Auf jeden Fall schon mal: Herzlichen Dank!! :98:
LG Michael
(04.11.2016, 14:36)Jockel schrieb: [ -> ]...off topic: ganz toller Betreff... da sieht man, dass du dir richtig Mühe gegeben hast...
Hallo Jörg,
war das jetzt mathematisch, wissenschaftlich oder ernst oder oder... gemeint??? :19:
Gruß Michael