Hallo, bis jetzt hab ich es in Excel immer geschafft meine Probleme durch lesen von Beiträgen zu lösen, aber jetzt komme ich einfach nicht weiter.
Ich habe 2 Tabellen, später bis zu 4. In der Einen Tabelle habe ich Einzel- Doppel- und große Doppelzimmer. Diese kosten je nach Dauer des Aufenthalt unterschiedlich. In der 2. Tabelle habe ich Angebote, die genau wie die Zimmer mit der Länge des Aufenthalts anders kosten.
Nun würde ich gerne per Dropdown die Anzahl der Personen, die Art (Entweder z.b. DZ oder Angebot 1) die Nächte den Preis pro Nacht und den Gesamtpreis
Bis jetzt habe ich das Problem immer mit Ellen langen Wenn Funktionen gelöst, nun wird es aber langsam unübersichtlich.
[
attachment=7292]
Danke schon mal. :19:
Hallo Revej,
ich habe hier mal was gebastelt, ich würde es so machen. Spalte N kannst du ausblenden.
[
attachment=7296]
Hallo Revej,
hier noch eine Variante mit Sverweis/Vergleich und dynamischen Drop-Down
Gruß Hans
Hallo und vielen Dank für die Antworten.
Sieht beides schon mal sehr gut aus, werde beides nun mal ausprobieren und auf die großen Tabellen anwenden. Mal schauen wie es besser klappt.
Danke :28:
(06.10.2016, 12:28)wicky schrieb: [ -> ]Hallo Revej,
hier noch eine Variante mit Sverweis/Vergleich und dynamischen Drop-Down
Gruß Hans
Hallo Hans, deine Formel könnte man einwenig kürzen..:
Code:
=WENNFEHLER(D13*E13*SVERWEIS(B13;WAHL(1+(CODE(A13)=65);B3:E5;B8:E10);VERGLEICH(C13;WAHL(1+(CODE(A13)=65);B2:E2;B7:E7);0);0);"")
Hi,
(06.10.2016, 16:11)Jockel schrieb: [ -> ]Hallo Hans, deine Formel könnte man einwenig kürzen..:
Bei Auswahl von Angebot statt Zimmer wird nichts gerechnet, Absicht?
Hallo Ralf, ja. Wenn es keine Übereinstimmung gibt, gibt's kein Ergebnis ansosten sehr wohl...!
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F | G | H |
1 | | | | | | | | |
2 | | Zimmer | 1 bis 2 | 3 bis 6 | ab 7 | | | |
3 | | EZ | 40 | 30 | 20 | | | |
4 | | DZ | 44 | 30 | 22 | | | |
5 | | DZ_Plus | 46 | 36 | 26 | | | |
6 | | | | | | | | |
7 | | Angebot | 1 bis 2 | 3 bis 5 | ab 6 | | | |
8 | | P_1 | 70 | 60 | 50 | | | |
9 | | P_2 | 77 | 66 | 55 | | | |
10 | | P_3 | 78 | 68 | 58 | | | |
11 | | | | | | | | |
12 | Produkt | Typ | Nächte Typ | Nächte | Personen | | | |
13 | Angebot | P_1 | 1 bis 2 | 1 | 1 | 70,00 € | | 70,00 € |
Zelle | Formel |
F13 | =WENNFEHLER(WENN(A13="Zimmer";SVERWEIS(B13;$B$3:$E$5;VERGLEICH(C13;$B$2:$E$2;0);FALSCH)*E13*D13;WENN(A13="Angebot";SVERWEIS(B13;$B$8:$E$10;VERGLEICH(C13;$B$7:$E$7;0);FALSCH)*E13*D13;""));"") |
H13 | =WENNFEHLER(D13*E13*SVERWEIS(B13;WAHL(1+(CODE(A13)=65);B3:E5;B8:E10);VERGLEICH(C13;WAHL(1+(CODE(A13)=65);B2:E2;B7:E7);0);0);"") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo,
ein klein bißchen Umbau, dann geht das ganz einfach:
[html]
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E |
1 | | | ab _ Übernachtungen | | |
2 | | Zimmer | 1 | 3 | 7 |
3 | | EZ | 40 | 30 | 20 |
4 | | DZ | 44 | 30 | 22 |
5 | | DZ+ | 46 | 36 | 26 |
6 | | | | | |
7 | | Angebot | 1 | 3 | 6 |
8 | | P1 | 70 | 60 | 50 |
9 | | P2 | 77 | 66 | 55 |
10 | | P3 | 78 | 68 | 58 |
11 | | | | | |
12 | Produkt | Typ | Nächte | Personen | |
13 | Angebot | P3 | 5 | 1 | 340,00 € |
14 | | | | | |
15 | | | | | |
16 | | | | | |
17 | Zimmer | EZ | P_1 | 1 | |
18 | Angebot | DZ | P_2 | 2 | |
19 | | DZ+ | P_3 | 3 | |
20 | | | | 4 | |
Zelle | Format | Wert |
B8 | "P"Standard | 1 |
B9 | "P"Standard | 2 |
B10 | "P"Standard | 3 |
B13 | "P"Standard | 3 |
E13 | #.##0,00 € | 340 |
Name | Bezug |
Angebot | =Tabelle1!$B$8:$B$10 |
Produkt | =Tabelle1!$A$17:$A$18 |
Zimmer | =Tabelle1!$B$17:$B$19 |
Zelle | Formel |
E13 | =WENNFEHLER(INDEX(C2:$E$10;VERGLEICH(B13;$B$2:$B$10;0);VERGLEICH(C13;INDEX($C$2:$E$7;1+(CODE(A13)=65)*5;);1))*C13;"") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
[/html]
Hi Jörg,
(20.10.2016, 13:37)Jockel schrieb: [ -> ]Hallo Ralf, ja. Wenn es keine Übereinstimmung gibt, gibt's kein Ergebnis ansosten sehr wohl...!
jaa, klaar,
oh Mann, ich hatte nur auf Angebot gewechselt und in den anderen Spalten nix geändert. Peinlich!