Hallo zusammen,
ich habe eine Liste mit Mehrfachnennungen und würde gerne eine neue Spalte erstellen, in der jede Nennung aus der Liste nur einmal genannt wird. In etwa so:
Ursprungsspalte:
Tina
Tina
Tina
Julia
Julia
Lucas
Lucas
Neue Spalte:
Tina
Julia
Lucas
Dahinter würde ich gerne die Summe der Werte von Tina, von Julia etc. zusammenrechnen.
Kann mir jemand da weiterhelfen?
Danke und lieben Gruß!
Hi Julia,
bin nur am Handy - deshalb ganz kurz:
Mach dir eine Kopie der Liste, markiere sie, im Menueband Duplikate entfernen.
Hey,
danke, den Eintrag hatte ich schon gesehen und leider nur Bahnhof verstanden aber ich schau ihn mir nochmal an... Hatte gehofft dass es da eine einfachere Lösung geben könnte aber naja... Auf auf ;)
Lieben Gruß
Hallo,
Tabelle3 | A | B | C | D | E |
| 1 | | | | | |
| 2 | | Tina | 1 | 100 | |
| 3 | | Tina | | 50 | |
| 4 | | Tina | | 300 | |
| 5 | | Julia | 4 | 40 | |
| 6 | | Julia | | 60 | |
| 7 | | Lucas | 6 | 435 | |
| 8 | | Lucas | | 21 | |
| 9 | | | | | |
| 10 | | | | | |
| 11 | | Tina | | 450 | |
| 12 | | Julia | | 100 | |
| 13 | | Lucas | | 456 | |
| 14 | | | | | |
| verwendete Formeln | |
| Zelle | Formel | Bereich | N/A |
| C2 | =WENN(ZÄHLENWENN(B2:$B$2;B2)=1;ZEILE(C1);"") | | |
| C3:C8 | =WENN(ZÄHLENWENN(B$2:$B3;B3)=1;ZEILE(C2);"") | | |
| B11:B13 | =WENNFEHLER(INDEX($B$2:$B$8;KKLEINSTE($C$2:$C$8;ZEILE(B1)));"") | | |
| D11: D13 | =SUMMEWENN(Namen;B11;Werte) | | |
| definierte Namen | |
| Name | Bezieht sich auf | Tabelle | Z1S1-Formel |
| Namen | =Tabelle3!$B$2:$B$8 | | =Tabelle3!R2C2:R8C2 |
| Werte | =Tabelle3!$D$2:$D$8 | | =Tabelle3!R2C4:R8C4 |
| Excel-Inn.de |
| Hajo-Excel.de |
| XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
| Add-In-Version 19.15 einschl. 64 Bit |
so?
Hallo,
oder vergiss das ganze Formelgedöns und nimm eine Pivottabelle.
Bezogen auf das Beispiel von luffy:
die Hilfspalte C ist für die PT nicht notwendig und kann gelöscht werden - in B1 und C1 eine Überschrift setzen - B2 markieren - Einfügen - Pivottable und dem Assistenten folgen. Ziehe das Feld der Spalte B in die Zeilenbeschriftung und das Feld der Spalte C in das Wertefeld.
Das wars.
Hallo, oder mit Formel (ohne Hilfsspalte dafür) mit AGGREGAT() ..:
| Arbeitsblatt mit dem Namen 'Blatt1' |
| | B | C |
| 2 | Tina | 100 |
| 3 | Tina | 50 |
| 4 | Tina | 300 |
| 5 | Julia | 40 |
| 6 | Julia | 60 |
| 7 | Lucas | 435 |
| 8 | Lucas | 21 |
| 9 | | |
| 10 | | |
| 11 | Tina | 450 |
| 12 | Julia | 100 |
| 13 | Lucas | 456 |
| Zelle | Formel |
| B11 | =WENNFEHLER(INDEX($B$2:$B$8;AGGREGAT(15;6;ZEILE(A$1:A$7)/(VERGLEICH($B$2:B$8;B$1:B$7;0)=ZEILE(A$2:A$8));ZEILE(A1)));"") |
| C11 | =WENN(B11="";"";SUMMEWENN($B$2:$B$8;B11;$C$2:$C$8)) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo, oder mit DBSUMME() statt SUMMEWENN()..:
| Arbeitsblatt mit dem Namen 'Blatt1 (2)' |
| | B | C | D | E | F | G |
| 1 | Name | Wert | | | Name | Wert |
| 2 | Tina | 100 | | | <>"" | |
| 3 | Tina | 50 | | | | 1006 |
| 4 | Tina | 300 | | | Tina | 450 |
| 5 | Julia | 40 | | | Julia | 100 |
| 6 | Julia | 60 | | | Lucas | 456 |
| 7 | Lucas | 435 | | | | |
| 8 | Lucas | 21 | | | | |
| Zelle | Formel |
| G3 | =DBSUMME(B1:C8;2;F1:G2) |
| F4 | =WENNFEHLER(INDEX($B$2:$B$8;AGGREGAT(15;6;ZEILE(A$1:A$7)/(VERGLEICH($B$2:B$8;B$1:B$7;0)=ZEILE(A$2:A$8));ZEILE(A1)));"") |
| G4 | {=MEHRFACHOPERATION(;F2)} |
| F5 | =WENNFEHLER(INDEX($B$2:$B$8;AGGREGAT(15;6;ZEILE(A$1:A$7)/(VERGLEICH($B$2:B$8;B$1:B$7;0)=ZEILE(A$2:A$8));ZEILE(A2)));"") |
| G5 | {=MEHRFACHOPERATION(;F2)} |
| F6 | =WENNFEHLER(INDEX($B$2:$B$8;AGGREGAT(15;6;ZEILE(A$1:A$7)/(VERGLEICH($B$2:B$8;B$1:B$7;0)=ZEILE(A$2:A$8));ZEILE(A3)));"") |
| G6 | {=MEHRFACHOPERATION(;F2)} |
| Achtung, Matrixformel enthalten! |
| Die geschweiften Klammern{} werden nicht eingegeben. |
| Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
(11.08.2016, 11:55)Jockel schrieb: [ -> ]Hallo, oder mit Formel (ohne Hilfsspalte dafür) mit AGGREGAT() ..:
Hallihallo,
die Formeln kann ich aber normal benutzen und muss sie nicht als Matrixformeln aktivieren oder? :)
Meine Datei ist mittlerweile leider quälend langsam und braucht um die 15-20min zur Berechnung, deswegen gehe ich lieber früher als später auf Nummer sicher.
Vielen Dank!
(11.08.2016, 13:30)Julia_a schrieb: [ -> ]Hallihallo,
die Formeln kann ich aber normal benutzen und muss sie nicht als Matrixformeln aktivieren oder? :)
Meine Datei ist mittlerweile leider quälend langsam und braucht um die 15-20min zur Berechnung, deswegen gehe ich lieber früher als später auf Nummer sicher.
Vielen Dank!
Hallo, ich habe keine Matrixformel(n) gepostet, auch die Mehrfachoperation ist keine Matrixformel sieht nur so aus... Also entweder hast du in deiner Datei viele (andere) Matrixformeln oder volatile Funktionen, oder viele bedingte Formatierungen (oder alles zusammen...) Dann sollte man sich über einen Neuaufbau der Datei Gedanken machen...
Volatile Funktionen:
Diese Liste erhebt keinen Anspruch auf Vollständigkeit.
- Heute
- Jetzt
- Zufallszahl
- Indirekt
- Bereich.Verschieben
- Zelle
- Info