Hallo zusammen,
ich melde mich mal wieder mit einer Frage.
Ich habe eine Liste mit Tageswerten, teilweise von allen Tagen eines Monats und teilweise von nur ein paar Tagen. Nun möchte ich gerne eine Monatsübersicht erstellen und Excel folgendes berechnen lassen:
- Gesamtsumme der Werte aus einem Monat
- Wenn möglich soll Excel anzeigen, ob ein Monat komplett ist oder ob nur Werte aus einzelnen Tagen beinhaltet sind
Gibt es dafür eine Formelkombination bzw. einen Vorschlag für eine Hilfsspalte, wie ich mir das einrichten kann?
Vielen Dank für Vorschläge und liebe Grüße!
Julia
Hallo,
nach sowas kann man suchen!
SUMMEWENNS
ZÄHLENWENNS
SUMMENPRODUKT
und nicht zu vergessen eine PIVOT-Tabelle!
Hallo,
vielen Dank für die schnelle Antwort. Leider fehlt mir allerdings das Wissen, um die Lösung so direkt umsetzen zu können. Ich möchte ja, dass Excel in einer Spalte die verschiedenen genannten Monate auflistet. Und wenn möglich, daneben die Summe des jeweiligen Monats. Muss ich die möglichen Monate dafür manuell aufzählen oder erkennt Excel automatisch, welche Monate in den Datumszellen enthalten sind?
Danke!!
Hallo,
da ich Deine Tabelle nicht kenne, kann ich nicht mehr dazu sagen.
Hallo,
ich habe mal eine Beispieltabelle erstellt, um zu zeigen, was ich mir so vorstelle. Die gelben Felder sollten idealerweise von Excel berechnet werden. Die Liste mit den Daten links und den Werten wird mit der Zeit erweitert.
Wäre für jede Hilfe oder einen Lösungsansatz sehr dankbar!
Hallo, das geht z.B. so..:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| D | E | F | G |
1 | Monatsverkauf | Summe | gezählte Tage | Monat komplett |
2 | Juni | 47 | 8 | nein |
3 | Juli | 196 | 31 | ja |
4 | August | 84 | 13 | nein |
Zelle | Formel |
E2 | =SUMMENPRODUKT((TEXT($A$2:$A$100;"MMMM")=D2)*1;$B$2:$B$100) |
F2 | =SUMMENPRODUKT((TEXT($A$2:$A$100;"MMMM")=D2)*1) |
G2 | =WENN(J2<TAG(MONATSENDE((1&"."&D2)+0;0));"nein";"ja") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo,
die Monate mußt Du als Datum von Hand eintragen, sonst wird das zu aufwändig.
[html]
Arbeitsblatt mit dem Namen 'Tabelle1' |
| D | E | F | G |
1 | Monatsverkauf | Summe | gezählte Tage | Monat komplett |
2 | Juni | 47 | 8 | nein |
Zelle | Format | Wert |
D2 | MMMM | 01.06.2016 |
Zelle | Formel |
E2 | =SUMMEWENNS(B:B;A:A;">="&D2;A:A;"<="&MONATSENDE(D2;0)) |
F2 | =ZÄHLENWENNS(A:A;">="&D2;A:A;"<="&MONATSENDE(D2;0)) |
G2 | =WENN(F2=TAG(MONATSENDE(D2;0));"ja";"nein") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
[/html]
(10.08.2016, 14:09)BoskoBiati schrieb: [ -> ]Hallo,
die Monate mußt Du als Datum von Hand eintragen, sonst wird das zu aufwändig...
Hallo Edgar, gar nicht wahr... :15: :21:
Tausend Dank für die Antworten! :43:
Hi,
das geht auch mit PivotTable und ein paar Hilfsspalten:
Tabelle1 | I | J | K | L | M | N | O | P | Q | R |
2 | Zeilenbeschriftungen | Anzahl von Tagesverkauf | | | | | | | | |
3 | Jun | 8 | nein | | 01.06.2016 | 30.06.2016 | 30 | | Jan | 1 |
4 | Jul | 31 | ja | | 01.07.2016 | 31.07.2016 | 31 | | Feb | 2 |
5 | Aug | 13 | nein | | 01.08.2016 | 31.08.2016 | 31 | | Mrz | 3 |
6 | | | | | | | | | Apr | 4 |
7 | | | | | | | | | Mai | 5 |
8 | | | | | | | | | Jun | 6 |
9 | | | | | | | | | Jul | 7 |
10 | | | | | | | | | Aug | 8 |
11 | | | | | | | | | Sep | 9 |
12 | | | | | | | | | Okt | 10 |
13 | | | | | | | | | Nov | 11 |
14 | | | | | | | | | Dez | 12 |
verwendete Formeln | |
Zelle | Formel | Bereich | N/A |
K3:K5 | =WENN(PIVOTDATENZUORDNEN("Tagesverkauf";$I$2;"Tag ";I3)=O3;"ja";"nein") | | |
M3:M5 | =DATUM(JAHR(HEUTE());SVERWEIS(I3;$Q$3:$R$14;2;0);1) | | |
N3:N5 | =MONATSENDE(M3;0) | | |
O3:O5 | =N3-M3+1 | | |
Excel-Inn.de |
Hajo-Excel.de |
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
Add-In-Version 19.08 einschl. 64 Bit |