Moin, moin liebe Excel Spezialisten,
mein Problem liegt in der Sortierung meiner Bundesliga Tabelle bei Punkt und Torgleichheit da wird mir ein Fehler angezeigt.[
attachment=5951]
In meiner Hilfstabelle wird der Platz dann zweimal vergeben, ist ja auch OK so aber in der Richtigen Tabelle wird dann ein Fehler angezeigt.
Kann mir da jemand weiterhelfen.
Zusammen schaffen wir das, naja mehr Ihr als ich.
Hallo!
Hilft dir das weiter?
Austria Rapid gleiche Tordifferenz, Rapid hat aber ein Tor mehr geschossen.
daher besserer Platz.
Tabelle2 | A | B | C | D | E | F | G | H | I | J |
| 4 | Verein | Punkte | Tore gesch. | Tore eralten | Differenz | Patz | Verein | Punkte | Tordiff, | Punkte |
| 5 | Kärnten | 20 | 19 | 48 | -29 | 1 | Rapid | 41,0019004 | 19 | 41 |
| 6 | Lask | 41 | 41 | 30 | 11 | | Austria | 41,0019004 | 19 | 41 |
| 7 | Austria | 41 | 42 | 23 | 19 | 3 | Lask | 41,0011004 | 11 | 41 |
| 8 | Rapid | 41 | 43 | 24 | 19 | 4 | Salzburg | 40,0012004 | 12 | 40 |
| 9 | Mattersburg | 35 | 42 | 35 | 7 | | Altach | 40,0012004 | 12 | 40 |
| 10 | Innsbruck | 23 | 23 | 40 | -17 | 6 | Sturm | 37,0016004 | 16 | 37 |
| 11 | Salzburg | 40 | 41 | 29 | 12 | 7 | Mattersburg | 35,0007004 | 7 | 35 |
| 12 | Altach | 40 | 41 | 29 | 12 | 8 | Innsbruck | 22,9983002 | -17 | 23 |
| 13 | Sturm | 37 | 44 | 28 | 16 | | Ried | 22,9983002 | -17 | 23 |
| 14 | Ried | 23 | 23 | 40 | -17 | 10 | Kärnten | 19,9971002 | -29 | 20 |
| 15 | | | | | | | | | | |
| 16 | | | | | | Patz "1" händisch eingeben | | | | |
| 17 | | | | | | | | | | |
| Formeln der Tabelle |
| Zelle | Formel | | E5 | =C5-D5 | | G5 | {=INDEX($A$4:$A$59;VERGLEICH(H5;B$4:B$59+E$4:E$59%%+C$4:C$59%%%%-ZEILE($4:$58)%%%%%%;0))} | | H5 | {=KGRÖSSTE(B$5:B$59+E$5:E$59%%+C$5:C$59%%%%-ZEILE($5:$59)%%%%%%;ZEILE()-ZEILE($H$4))} | | I5 | =INDEX(E:E;VERGLEICH(G5;A:A;0)) | | J5 | =H5 | | F6 | =WENN(RUNDEN(H6;5)=RUNDEN(H5;5);"";ZEILE()-ZEILE($F$4)) |
|
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen! |
| Matrix verstehen |
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß
Wilfried
Hi,
(06.07.2016, 15:19)diddl schrieb: [ -> ]Kann mir da jemand weiterhelfen.
ich habe es versucht nachzuvollziehen, aber ich komme mit Deinen Formeln nicht zurecht.
Wenn ich jetzt mal bloß Deine Hilfstabelle nach Spalte Z absteigend sortiere, dann müßte doch in der Spalte O die Rangfolge von 1 bis 18 aufsteigend sortiert sein (mit Doppelten), aber nachdem diese Sortierung kurz aufblitzt, wird sie gleich wieder total durcheinandergewürfelt.
Da sind dann die Vereinsnamen nicht mehr den richtigen Toren, Punkten oder G U V zugeordnet, denn Deine SUMMEWENN-Formeln in Spalte Q-X beziehen sich immer noch auf die alten Zellen in Spalte P (vor der Sortierung), in denen nach der Sortierung aber andere Vereinsnamen stehen.
Und in der Formel in Spalte Z kannst Du anstatt (V5-X5) auch Y5 schreiben, wenn Du die Tordifferenz eh schon ausrechnest.
Über diese Formel:
=SVERWEIS(11;$O$5:$Z$22;1;FALSCH)
suchst Du für die Haupttabelle die Rangfolge aus der Hilfstabelle raus. Für Platz 11 gibt es dort aber keinen Rang, deswegen steht da #NV und daraufhin werden alle anderen Spalten-Werte für Platz 11 auch nicht gefunden.
Hier ist Deine Tabelle nach dem Vorschlag von Wilfried angepasst:
[
attachment=5958]
Tabelle | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T | U | V | W | X | Y | Z |
| 4 | Platz | Verein | Spiele | Punkte | Tor dif. | Tore | G | U | V | | | Verein | Spiele | Punkte | G | U | V | Tore | Tor dif. | |
| 5 | 1 | | Bayern München | 7 | 21,001900249995 | 19 | 25 | : | 6 | 7 | 0 | 0 | | | Bayern München | 7 | 21 | 7 | 0 | 0 | 25 | : | 6 | 19 | 21019025 |
| 6 | 2 | | Borussia Dortmund | 7 | 19,001000179987 | 10 | 18 | : | 8 | 6 | 1 | 0 | | | Frankfurt | 7 | 12 | 4 | 0 | 3 | 11 | : | 14 | -3 | 11997011 |
| 7 | 3 | | M'gladbach | 7 | 17,000700139988 | 7 | 14 | : | 7 | 5 | 2 | 0 | | | Hoffenheim | 7 | 7 | 2 | 1 | 4 | 8 | : | 11 | -3 | 6997008 |
| verbundene Zellen |
| C4: D4 |
| H4:J4 |
| V4:X4 |
| verwendete Formeln | |
| Zelle | Formel | Bereich | N/A |
| B6:B7 | =WENN(RUNDEN(F6;5)=RUNDEN(F5;5);"";ZEILE()-ZEILE($B$4)) | | |
| D5: D7 | {=INDEX($P$4:$P$22;VERGLEICH(F5;R$4:R$22+Y$4:Y$22%%+V$4:V$22%%%%-ZEILE($4:$22)%%%%%%;0))} | $D$5 | |
| E5:E7 | =SVERWEIS(D5;$P$5:$Z$22;2;FALSCH) | | |
| F5:F7 | {=KGRÖSSTE(R$5:R$22+Y$5:Y$22%%+V$5:V$22%%%%-ZEILE($5:$22)%%%%%%;ZEILE()-ZEILE($F$4))} | $F$5 | |
| G5:G7 | =H5-J5 | | |
| H5:H7 | =SVERWEIS(D5;$P$5:$Z$22;7;FALSCH) | | |
| J5:J7 | =SVERWEIS(D5;$P$5:$Z$22;9;FALSCH) | | |
| K5:K7 | =SVERWEIS(D5;$P$5:$Z$22;4;FALSCH) | | |
| L5:L7 | =SVERWEIS(D5;$P$5:$Z$22;5;FALSCH) | | |
| M5:M7 | =$E5-$K5-$L5 | | |
| P5: P7 | =Spielplan!D5 | | |
| Q5:Q7 | =SUMMEWENN(Spielplan!$D$5:$D$310;Tabelle!$P5;Spielplan!$L$5:$L$310)+SUMMEWENN(Spielplan!$F$5:$F$310;Tabelle!$P5;Spielplan!$M$5:$M$310) | | |
| R5:R7 | =SUMMEWENN(Spielplan!$D$5:$D$310;Tabelle!$P5;Spielplan!$J$5:$J$310)+SUMMEWENN(Spielplan!$F$5:$F$310;Tabelle!$P5;Spielplan!$K$5:$K$310) | | |
| S5:S7 | =(SUMMEWENN(Spielplan!$D$5:$D$310;Tabelle!$P5;Spielplan!$N$5:$N$310)+SUMMEWENN(Spielplan!$F$5:$F$310;Tabelle!$P5;Spielplan!$O$5:$O$310))/3 | | |
| T5:T7 | =SUMMEWENN(Spielplan!$D$5:$D$310;Tabelle!$P5;Spielplan!$P$5:$P$310)+SUMMEWENN(Spielplan!$F$5:$F$310;Tabelle!$P5;Spielplan!$Q$5:$Q$310) | | |
| U5:U7 | =Q5-$S5-$T5 | | |
| V5:V7 | =SUMMEWENN(Spielplan!$D$5:$D$310;Tabelle!$P5;Spielplan!$G$5:$G$310)+SUMMEWENN(Spielplan!$F$5:$F$310;Tabelle!$P5;Spielplan!$I$5:$I$310) | | |
| X5:X7 | =SUMMEWENN(Spielplan!$D$5:$D$310;Tabelle!$P5;Spielplan!$I$5:$I$310)+SUMMEWENN(Spielplan!$F$5:$F$310;Tabelle!$P5;Spielplan!$G$5:$G$310) | | |
| Y5:Y7 | =V5-X5 | | |
| Z5:Z7 | =R5*1000000+Y5*1000+V5 | | |
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!| Excel-Inn.de |
| Hajo-Excel.de |
| XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
| Add-In-Version 19.08 einschl. 64 Bit |
(07.07.2016, 07:45)Wilfried Höttl schrieb: [ -> ]Hilft dir das weiter?
Danke für die schnelle Antwort.
die muss ich mir jetzt mal in aller Ruhe reinziehen, ist ja ziemlich komplex das ganze. Was passiert wenn Austria und Rapid die gleiche Anzahl Tore geschossen und die gleiche Anzahl Tore kassiert haben?
Liebe Grüße Dieter
Es funktioniert ihr seid die GRÖßTEN DANKE
(07.07.2016, 10:44)Rabe schrieb: [ -> ]Hier ist Deine Tabelle nach dem Vorschlag von Wilfried angepasst:
Tiefste Verbeugung ihr seid die Größten. Danke für die schnelle Hilfe.
Habe die Formel noch nicht ganz verstanden aber das kommt sicher noch.
Liebe Grüße Dieter