Clever-Excel-Forum

Hallo liebe Excelfreunde :)

Ich komme leider nicht weiter. Habe schon viele verschiedene Einträge gelesen und kann nichts passendes finden. Vielleicht kann mir einer von Euch bei der kniffligen Frage weiterhelfen.

Beispiel:
Ich habe eine Reihe von Beschreibungen (Auto, Tür, Dach, Kotflügel, Reifen). Diese sollen in alle möglichen Kombinationen gebracht werden. Allerdings ohne Kombination mit sich selbst (Auto Auto). Es sollen außerdem keine Redundanzen vorhanden sein (Tür Auto - Auto Tür). Unten seht ihr eine Darstellung mit der ich gearbeitet habe, um das Problem klar zu machen. Falls man es in eine Matrix bekommt dürfen die Kombinationen im gelben und roten Bereich nicht dabei sein. Die Matrix sollte schlussendlich auch noch beliebig zu erweitern sein.

[
Bild bitte so als Datei hochladen: Klick mich!
]

Ich möchte nicht mit VBA arbeiten, nur reines Oberflächenexcel. Hat jemand von Euch eine Idee wie man vorgehen könnte? Würde mich wirklich sehr freuen :)

Beste Grüße
Euer Autofreak

Hallo,

so:

[html]

Arbeitsblatt mit dem Namen 'Tabelle1'
	H	I	J	K	L	M
13		a	b	c	d	e
14	a		b a	c a	d a	e a
15	b			c b	d b	e b
16	c				d c	e c
17	d					e d
18	e

Zelle	Formel
I14	=WENN(($H14=I$13)+(ZEILE(A1)>SPALTE(A1));"";I$13&" "&$H14)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[/html]

[
Bild bitte so als Datei hochladen: Klick mich!
]
Vielen Dank, Edgar. Bei mir kommt da jetzt so etwas raus.



Aber kann man das auch so in eine Formel fassen, dass die Ergebnisse aus den einzeln untereinander stehenden Worten generiert werden? Oder muss man dann schon programmieren?

Genial wäre es, wenn man am Ende so eine Darstellung bekommen würde. Leider bin ich da (noch) nicht so fit in Excel :s

[
Bild bitte so als Datei hochladen: Klick mich!
]

Hallo,

so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	a	a b
2	b	a c
3	c	a d
4	d	a e
5	e	b c
6		b d

Zelle	Formel
B1	=A1&" "&A2
B2	=WENNFEHLER(WENN(ZÄHLENWENN($B$1:B1;LINKS(B1;SUCHEN(" ";B1)-1)&"*")=ANZAHL2($A$1:$A$5)-VERGLEICH(LINKS(B1;SUCHEN(" ";B1)-1);$A$1:$A$5;0);INDEX($A$1:$A$5;VERGLEICH(LINKS(B1;SUCHEN(" ";B1)-1);$A$1:$A$5;0)+1)&" "&INDEX($A$1:$A$5;VERGLEICH(LINKS(B1;SUCHEN(" ";B1)-1);$A$1:$A$5;0)+2);LINKS(B1;SUCHEN(" ";B1)-1)&" "&INDEX($A$1:$A$5;VERGLEICH(TEIL(B1;SUCHEN(" ";B1)+1;99);$A$1:$A$5;0)+1));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Hi Edgar,

(28.04.2016, 15:53)BoskoBiati schrieb: [ -> ]so:

Die Formel ist klasse.
Ich habe natürlich gleich damit rumgespielt, was ist, wenn es mehr als nur 5 Komponenten sind?
Allein durch Verlängerung des Komponentenbereichs in der Formel geht das nicht.

Intelligente Tabelle:

Tabelle1

	A	B
1	Komponenten	"Kreuztabelle vertikal"
2	Auto	Auto Tür
3	Tür	Auto Dach
4	Dach	Auto Kotflügel
5	Kotflügel	Auto Reifen
6	Reifen	Auto Windschutzscheibe
7	Windschutzscheibe	Tür Dach
8		Tür Kotflügel
9		Tür Reifen
10		Tür Windschutzscheibe
11		Dach Kotflügel
12		Dach Reifen
13		Dach Windschutzscheibe
14		Kotflügel Reifen
15		Kotflügel Windschutzscheibe
16		Reifen Windschutzscheibe
17		Windschutzscheibe
18
19
20
21

verwendete Formeln
Zelle	Formel	Bereich	N/A
B2	=A2&" "&A3
B3:B21	=WENNFEHLER(WENN(ZÄHLENWENN($B$2:B2;LINKS(B2;SUCHEN(" ";B2)-1)&"*")=ANZAHL2([Komponenten])-VERGLEICH(LINKS(B2;SUCHEN(" ";B2)-1);[Komponenten];0);INDEX([Komponenten];VERGLEICH(LINKS(B2;SUCHEN(" ";B2)-1);[Komponenten];0)+1)&" "&INDEX([Komponenten];VERGLEICH(LINKS(B2;SUCHEN(" ";B2)-1);[Komponenten];0)+2);LINKS(B2;SUCHEN(" ";B2)-1)&" "&INDEX([Komponenten];VERGLEICH(TEIL(B2;SUCHEN(" ";B2)+1;99);[Komponenten];0)+1));"")

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.08 einschl. 64 Bit

Hallo Ralf,

ich kann Dein Problem nicht nachvollziehen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Komponenten
2	a	a b
3	b	a c
4	c	a d
5	d	a e
6	e	a f
7	f	a g
8	g	a h
9	h	b c
10		b d
11		b e
12		b f
13		b g
14		b h
15		c d
16		c e
17		c f
18		c g
19		c h
20		d e
21		d f
22		d g
23		d h
24		e f
25		e g
26		e h
27		f g
28		f h
29		g h
30

Zelle	Formel
B2	=A2&" "&A3
B3	=WENNFEHLER(WENN(ZÄHLENWENN($B$1:B2;LINKS(B2;SUCHEN(" ";B2)-1)&"*")=ANZAHL2(Tabelle1[Komponenten])-VERGLEICH(LINKS(B2;SUCHEN(" ";B2)-1);Tabelle1[Komponenten];0);INDEX(Tabelle1[Komponenten];VERGLEICH(LINKS(B2;SUCHEN(" ";B2)-1);Tabelle1[Komponenten];0)+1)&" "&INDEX(Tabelle1[Komponenten];VERGLEICH(LINKS(B2;SUCHEN(" ";B2)-1);Tabelle1[Komponenten];0)+2);LINKS(B2;SUCHEN(" ";B2)-1)&" "&INDEX(Tabelle1[Komponenten];VERGLEICH(TEIL(B2;SUCHEN(" ";B2)+1;99);Tabelle1[Komponenten];0)+1));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Enthält Dein Bereich Komponenten eine leere Zelle?

Hi Edgar,

hier ist meine Datei:
[attachment=5099]

Hallo,


liegt daran, dass Du die Spalte B in Deiner Tabelle hast. Somit sind die Leerzeilen im Bereich und werden mitberücksichtigt.

Lieber Edgar, lieber Ralf,

vielen Dank für Eure Unterstützung. Genau so habe ich mir es vorgestellt. Bis ich so etwas selbst hinbekomme dauert es wohl noch etwas, aber aus den Vorschlägen habe ich schon gelernt. Danke!

Gruß
Autofreak