Clever-Excel-Forum

Hi zusammen, 
ich suche eine Formellösung als Alternative zur Pivot, die ich hierfür leider (!!!) nicht verwenden kann.

Im Grunde habe ich eine einfache Datentabelle mit mehreren Dimensionen (Länder, Produktkategorien, Filialen, Unterscheidung in Alt- und Neuware; usw.) und möchte diese ähnlich einer Pivot auswerten können.

Mit Summenprodukt i.V.m. Summewenns o.ä. komme ich nicht weiter, da Excel z.B. als ODER Bedinung nur Text in geschweiften Klammern akzeptiert, aber keine Bezüge.

Die folgende Formel funktioniert für die ausgewählten Suchkriterien im Bereich B3:B5 einwandfrei, sobald ich aber eine zusätzl. Bedingung mit aufnehme, geht nix mehr.

=SUMMENPRODUKT(SUMMEWENNS('BW Daten'!N:N;'BW Daten'!I:I;Tabelle1!$B$3:$B$5))

Hab mal eine Beispieldatei hochgeladen, dann wirds vielleicht deutlicher. Ich hoffe mir kann irgendwer helfen. Danke schon mal im Voraus!

Grüße
Markus

(30.03.2016, 13:29)markus.gerauer schrieb: [ -> ]Hi zusammen, 
...

Hab mal eine Beispieldatei hochgeladen...

Grüße
Markus

Hallo... so..? Wo denn? Und wieso schreibst du so klein..?

Hallo,

1. Die Formel arbeitet ohne Probleme mit mehreren Bedingungen, allerdings müssen die in der Reihenfolge vorliegen, wie sie aufgelistet sind und das für alle Bedingungen.
2. Summenprodukt ist überflüssig, es reicht Summe

Sieh Dir mal das beispiel an:

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C	D	E	I	J	N
1					x	p	5
2					z	q	3
3	x	p	x	p	y	r	8
4	y	q	z	q	a	s	1
5	z	r	y	r	c	v	2
6	23		21		x	p	5
7	16		13		y	q	6
8	23		21		z	r	7
9	16		13				9
10
11	23		21

Zelle	Formel
B6	{=SUMMENPRODUKT(SUMMEWENNS($N:$N;$I:$I;MTRANS(B$3:B$5);$J:$J;MTRANS(C$3:C$5)))}
D6	{=SUMMENPRODUKT(SUMMEWENNS($N:$N;$I:$I;MTRANS(D$3:D$5);$J:$J;MTRANS(E$3:E$5)))}
B7	{=SUMMENPRODUKT(SUMMEWENNS($N:$N;$I:$I;B$3:B$5;$J:$J;C$3:C$4))}
D7	{=SUMMENPRODUKT(SUMMEWENNS($N:$N;$I:$I;D$3:D$5;$J:$J;E$3:E$4))}
B8	{=SUMME(SUMMEWENNS($N:$N;$I:$I;MTRANS(B$3:B$5);$J:$J;MTRANS(C$3:C$5)))}
D8	{=SUMME(SUMMEWENNS($N:$N;$I:$I;MTRANS(D$3:D$5);$J:$J;MTRANS(E$3:E$5)))}
B9	{=SUMME(SUMMEWENNS($N:$N;$I:$I;B$3:B$5;$J:$J;C$3:C$4))}
D9	{=SUMME(SUMMEWENNS($N:$N;$I:$I;D$3:D$5;$J:$J;E$3:E$4))}
B11	{=SUMMENPRODUKT(($I:$I=MTRANS(B$3:B$5))*($J:$J=MTRANS(C$3:C$5))*$N:$N)}
D11	{=SUMMENPRODUKT(($I:$I=MTRANS(D$3:D$5))*($J:$J=MTRANS(E$3:E$5))*$N:$N)}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Was funktioniert ist das:

Arbeitsblatt mit dem Namen 'Tabelle1'
	F	G	H	I	J	K	O
1					x	r	5
2					z	q	5
3	x	p	q	r	y	p	5
4	z				a	s	1
5	y				c	v	2
6	27				x	p	4
7	18				y	q	4
8	27				z	r	4
9	18						9

Zelle	Formel
F6	=SUMMENPRODUKT(SUMMEWENNS($O:$O;$J:$J;F$3:F$5;$K:$K;G3:I3))
F7	=SUMMENPRODUKT(SUMMEWENNS($O:$O;$J:$J;F$3:F$5;$K:$K;G3:H3))
F8	{=SUMME(SUMMEWENNS($O:$O;$J:$J;F3:F5;$K:$K;G3:I3))}
F9	{=SUMME(SUMMEWENNS($O:$O;$J:$J;F$3:F$5;$K:$K;G3:H3))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg