Clever-Excel-Forum

Moin moin zusammen,

hab ein kleines Problem, bei dem ich einfach nicht weiter weiß.

Und zwar bin ich dabei eine Tabelle zu erstellen, die mir anhand von zwei Parametern (PLZ und Gewicht) einen Wert aus einer bereits vorhanden Tabelle auswerfen soll.


Mein Problem ist, dass ich in der Frachttabelle aus der die Fracht ermittelt werden soll, eine Gewichtsstaffelung habe (50, 100, 150, 200, 250, 300, 400 usw.) und die Sendungen natürlich Gewichte haben die dazwischen liegen, deshalb soll er in der Spalte immer den nächst höheren Wert nehmen. Also wenn die Sendung ein Gewicht von 101 kg hat soll sie den Wert aus der Spalte für 150 kg nehmen.

Hier mal meine Funktion:

=INDEX(B2:AK96;VERGLEICH(J3;A2:A96;0);VERGLEICH(G3;B1:AK1;-1)))

Die erste Vergleichsformel ist für das PLZ-Gebiet und die zweite soll nach dem Gewicht "suchen". Egal wie ich es drehe und wende, er wirft mir entweder #NV oder den Wert zum nächst niedrigeren Gewicht raus.

Bin am verzweifeln...


Hoffe Ihr könnt mir weiter helfen :)

Hallo,

ich habe jetzt weder Lust noch Zeit aufgrund deiner Formel eine Tabelle aufzubauen, deswegen einfach mal eine Beispielstabelle die ich verwende.

Vielleicht hilft dir das als Ansatz weiter - und wenn nicht dann wäre deine Tabelle mit dem entsprechenden Aufbau von Vorteil.

Nachtrag: Datei gelöscht weil fehlerhaft - die korrekte Formel für den dargestellten Tabellenaufbau steht im Beitrag von Edgar.

Hallo Peter,

Deine Tabelle hat offensichtlich einen kleinen Fehler, die Bezüge im letzten Index sind nicht fixiert. Außerdem wirft sie einen Fehler aus bei Werten <10:

Arbeitsblatt mit dem Namen 'Frachtkosten_Gewicht'
	A	B	C	D	E	F	G	H	I	J	K
1	Gewicht	bis	bis	bis	bis	bis	bis	bis	bis	bis	bis
2	Spedition	10	20	30	40	50	60	70	80	90	100
3	S1	1,00	7,00	13,00	19,00	25,00	31,00	37,00	43,00	49,00	55,00
4	S2	2,00	8,00	14,00	20,00	26,00	32,00	3,05	44,00	50,00	56,00
5	S3	3,00	9,00	15,00	21,00	27,00	33,00	39,00	45,00	51,00	57,00
6	S4	4,00	10,00	16,00	22,00	28,00	34,00	40,00	46,00	52,00	58,00
7	S5	5,00	11,00	17,00	23,00	29,00	35,00	41,00	47,00	53,00	59,00
8	S6	6,00	12,00	18,00	24,00	30,00	36,00	42,00	48,00	54,00	60,00
9
10
11	Berechnung der Frachtkosten
12	Lieferant	Gewicht	Preis	Peter, korr.	Edgar
13	S1	5	#NV	#NV	1,00
14	S1	10	7,00	1,00	1,00
15	S1	11	7,00	7,00	7,00
16	S1	19	7,00	7,00	7,00
17	S1	20	13,00	7,00	7,00
18	S2	20	14,00	8,00	8,00

Zelle	Formel
C13	=WENN(ISTNV(VERGLEICH(B13;B$2:K$2;0));INDEX(B$3:K$8;VERGLEICH(A13;A$3:A$8;0);VERGLEICH(B13;B$2:K$2;1)+1);INDEX(B$3:K$8;VERGLEICH(A13;A$3:A$8;0);VERGLEICH(B13;B2:K2;1)))
D13	=WENN(ISTNV(VERGLEICH(B13;B$2:K$2;0));INDEX(B$3:K$8;VERGLEICH(A13;A$3:A$8;0);VERGLEICH(B13;B$2:K$2;1)+1);INDEX(B$3:K$8;VERGLEICH(A13;A$3:A$8;0);VERGLEICH(B13;$B$2:$K$2;1)))
E13	=INDEX($B$3:$K$8;VERGLEICH(A13;$A$3:$A$8;0);VERGLEICH(B13+(REST(B13;10)<>0)*10;$B$2:$K$2;1))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Hallo,

na toll - poste ich hier so ein halbfertiges, fehlerhaftes Teil.

Danke für die Info und die Korrektur.