Clever-Excel-Forum

Hallo Excel Gemeinde,
nach langem probieren und lesen, finde ich leider keine Lösung.
Daher meine frage an euch, ob jemand ein Tipp hat wie man eigentlich eine recht einfache Auswertung umsetzt.

Ich hab in einer Spalte Uhrzeiten stehen. Diese möchte ich auswerten wieviel Uhrzeiten es zwischen 5:45 bis 13:45 , 13:45 bis 21:45 und 21:45 und 5:45 gibt.
Mein Ansatz war

Zeitfenster:

=ZÄHLENWENNS(INDIREKT("'" & R5 & "'!AY2:AY200"); ">="&ZEIT(21;46;0); INDIREKT("'" & R5 & "'!AY2:AY200"); "<="&ZEIT(5;45;0))
Ergebnis : 0

=ZÄHLENWENNS(INDIREKT("'" & R5 & "'!AY2:AY200"); ">="&ZEIT(5;46;0); INDIREKT("'" & R5 & "'!AY2:AY200"); "<="&ZEIT(13;45;0))
Ergebnis : 74

=ZÄHLENWENNS(INDIREKT("'" & R5 & "'!AY2:AY200"); ">="&ZEIT(13;46;0); INDIREKT("'" & R5 & "'!AY2:AY200"); "<="&ZEIT(21;45;0))
Ergebnis : 1

Summe aller Einträge 73 Huh

06:01:24
06:02:28
03:08:03
00:16:00
00:16:17
00:16:23
00:16:29
00:16:36
00:24:45
00:24:51
00:24:58
00:25:04
00:25:10
00:25:15
00:25:21
03:42:53
09:20:53
00:36:21
01:02:10
13:12:54
11:14:06
05:14:26
03:08:29
03:09:16
11:49:06
06:20:03
06:16:21
03:42:59
03:09:47
03:42:29
07:08:24
09:46:33
22:22:17
15:47:27
00:00:00
00:00:00
00:00:00
00:00:00
00:00:00
00:00:00
07:49:51
13:37:09
23:32:08
13:07:35
02:37:48
01:50:48
00:06:59
00:34:21
06:16:38
06:20:12
00:40:00
03:22:13
02:28:09
03:25:56
07:08:44
03:36:09
08:14:01
09:46:43
12:42:16
13:10:13
13:15:32
23:35:27
04:40:46
02:11:48
04:41:33
11:14:19
13:13:12
13:23:06
13:25:07
13:31:54
03:34:22
03:45:05
05:53:41

Hola,

Code:
=SUMMENPRODUKT(($AY$2:$AY$74>ZEIT(5;45;0))*($AY$2:$AY$74<=ZEIT(13;45;0)))

Code:
=SUMMENPRODUKT(($AY$2:$AY$74>ZEIT(13;45;0))*($AY$2:$AY$74<=ZEIT(21;45;0)))

Code:
=SUMMENPRODUKT(($AY$2:$AY$74>ZEIT(21;45;0))+($AY$2:$AY$74<=ZEIT(5;45;0)))

Bereiche und Indirekt() musst du noch anpassen.
Gruß,
steve1da

Hola,

denada.

Ich habs angepasst mit einem für mich nicht verständlichem Ergebnis.

Code:
=ZÄHLENWENNS(INDIREKT("'" & R5 & "'!AY2:AY200"); ">="&ZEIT(21;46;0); INDIREKT("'" & R5 & "'!AY2:AY200"); "<="&ZEIT(5;45;0))

Code:
=SUMMENPRODUKT(((INDIREKT("'" & R5 & "'!AY2:AY200") >= ZEIT(5;45;0)))*((INDIREKT("'" & R5 & "'!AY2:AY200") <= ZEIT(13;45;0))))

Code:
    Zählewenns    Summenprodukt

5:45-13:45    0    74

13:45-21:45    74    1

21:45-5:45    1    0

Vielleicht ist mein Ansatz komplett falsch. Könnte Stunde für Stunde auszählen und dann zusammen Zählen, das ist jedoch zu viel Aufwand im Hintergrund.

Ich komme auf andere Ergebnisse.

Code:
=SUMMENPRODUKT((INDIREKT("'" & R5 & "'!AY2:AY200") >= ZEIT(5;45;0))*(INDIREKT("'" & R5 & "'!AY2:AY200") <= ZEIT(13;45;0)))

Code:
=SUMMENPRODUKT((INDIREKT("'" & R5 & "'!AY2:AY200") > ZEIT(13;45;0))*(INDIREKT("'" & R5 & "'!AY2:AY200") <= ZEIT(21;45;0)))

Code:
=SUMMENPRODUKT((INDIREKT("'" & R5 & "'!AY2:AY200")<>"")*((INDIREKT("'" & R5 & "'!AY2:AY200") >ZEIT(21;45;0))+(INDIREKT("'" & R5 & "'!AY2:AY200") < ZEIT(5;45;0))))

Hallo,

danke für die Hilfe. Fehler gefunden. Thumps_up

Code:
=SUMMENPRODUKT((INDIREKT("'" & R5 & "'!AY2:AY200") >= ZEIT(5;45;0))*(INDIREKT("'" & R5 & "'!AY2:AY200") <= ZEIT(13;45;0))*(INDIREKT("'" & R5 & "'!$BK$2:$BK$200")="Abgeschlossen"))

Jetzt passt es zusammen.

frasch74

steve1da

frasch74

steve1da

frasch74