Servus nochmal zusammen,
bin mir nich sicher wie genau ich den Thread nenn soll ;)
ich bräuchte eine Formel die folgendes macht:
auf Tabbellenblatt 1 in Zelle A3 sollen ein ergebniss stehen das aus allen werten
in Tabellenblatt 2 der Spalte C, Zeile 5-25 addiert wird.
ABER nur DANN wenn in der Nachbarzelle eine 2 steht.
Beispiel:
Tabellenblatt 1 Zelle A3 = 100
Tabellenblatt 2 Zelle C5 =25 / Nachbarzellenwert B5 =2
Tabellenblatt 2 Zelle C11 =75 Nachbarzellenwert B11 =2
Hoffe das geht ;)
Gruß
lion
Hi lion,
schreibre in A3: =SUMMENPRODUKT((Tabelle2!$C$1:$C$20)*(Tabelle2!$D$1:$D$20=2))
Hallo lion
Code:
=SUMMEWENN(Tabelle2!B5:B25;2;Tabelle2!C5:C25)
Jungs ihr seits spitze... mag für euch alle hier ganz easy sein was ich brauch ... aber mir habt ihr scho so oft geholfen und meine arbeit dadurch erleichtert...
tausend dank
muss leider gestehn ich hab in meinem Bsp. einen gedankenfehler gehabt.
die Formel muss also noch erweitert werden oder komplett abgeändert.
excel soll folgenden Spalten nach dem Wert 1 abfragen
D; K; R; Y; AF; AM; AT; BA; BH; BO; BV; CC (immer von Zeile 19 bis 47)
wenn dieser vorkommt dann wie vorher die Nachbarzelle kopieren und addieren
Nachbarzellen
E; L; S; Z; AG; AN; AU; BB; BI; BP; BW
Hintergrund ist der ...
Excel soll mir die MwSt der Rechnung nicht im Leistungsmonat eintragen sondern in dem Monat wenn Sie bezahlt wird. der Wert 1 steht somit für Januar und wird von mir für die jeweiligen Monate dann abgeändert.
wenn nötig kann ich auch noch ein paar Bilder anhängen zum besseren verständniss.
Gruß und danke schonmal
lion
Hi,
Zitat:wenn nötig kann ich auch noch ein paar Bilder anhängen zum besseren verständniss.
bloß nicht!!! :32:Stelle uns bitte einen
Tabellenausschnitt oder eine
Mustertabelle vor. Wenn du die jeweiligen farbigen Texte anklickst, kannst du nachlesen, wied das geht.
so hier die musterdatei
Tabelle MWST ist von hand gerechnet und da hätte ich jetzt gern ne formel dazu :)
Hi,
(09.02.2016, 09:45)lion7123 schrieb: [ -> ]Tabelle MWST ist von hand gerechnet und da hätte ich jetzt gern ne formel dazu :)
schau mal hier, Formeln analog weiterführen:
MwSt | BD | BE | BF | BG |
| 5 | | MwSt | Einnahmen | |
| 6 | November | 0 | 0 | |
| 7 | Dezember | 28,5 | 150 | 381,9 |
| 8 | Januar | 353,4 | 1860 | |
| verwendete Formeln | |
| Zelle | Formel | Bereich | N/A |
| BF6 | =SUMMENPRODUKT((Rechnungen!E$19:E$47)*(Rechnungen!D$19: D$47=11))+SUMMENPRODUKT((Rechnungen!L$19:L$47)*(Rechnungen!K$19:K$47=11))+SUMMENPRODUKT((Rechnungen!S$19:S$47)*(Rechnungen!R$19:R$47=11)) | | |
| BF7 | =SUMMENPRODUKT((Rechnungen!E$19:E$47)*(Rechnungen!D$19: D$47=12))+SUMMENPRODUKT((Rechnungen!L$19:L$47)*(Rechnungen!K$19:K$47=12))+SUMMENPRODUKT((Rechnungen!S$19:S$47)*(Rechnungen!R$19:R$47=12)) | | |
| BG7 | =SUMME(BE6:BE8) | | |
| BE6:BE8 | =(BF6/100)*19 | | |
| BF8 | =SUMMENPRODUKT((Rechnungen!E$19:E$47)*(Rechnungen!D$19: D$47=1))+SUMMENPRODUKT((Rechnungen!L$19:L$47)*(Rechnungen!K$19:K$47=1))+SUMMENPRODUKT((Rechnungen!S$19:S$47)*(Rechnungen!R$19:R$47=1)) | | |
| Excel-Inn.de |
| Hajo-Excel.de |
| XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
| Add-In-Version 19.08 einschl. 64 Bit |
Besser und einfacher zum Auswerten wäre es, wenn alle Spalten untereinander geführt würden und dann eine Zusatzsspalte mit dem Monat eingefügt wird, dann könnte sogar noch alles ganz einfach per Pivot-Tabelle ausgewertet werden:
Rechnungen | B | C | D | E | F | G | H |
| 18 | Firma | Rechnung | Re-Monat | Leistungsmonat | Betrag | offen | bezahlt |
| 19 | Mustermann | | 11 | | 2500 | 2500 | 0 |
| 20 | Mustermann | | 11 | 12 | 70 | 70 | 70 |
| 21 | Mustermann | | 11 | 12 | 80 | 80 | 80 |
| 22 | Mustermann | | 12 | 1 | 1650 | 1650 | 1650 |
| 23 | Mustermann | | 12 | 1 | 210 | 210 | 210 |
| 24 | Mustermann | | 1 | | 2000 | 2000 | 0 |
| 25 | Mustermann | | 1 | | 0 | 0 | 0 |
| 26 | | | | | | | |
| 27 | | | | | | | |
MwSt | BD | BE | BF | BG | BH |
| 5 | | | MwSt | Einnahmen | |
| 6 | November | 11 | 0 | 0 | |
| 7 | Dezember | 12 | 28,5 | 150 | 381,9 |
| 8 | Januar | 1 | 353,4 | 1860 | |
| 9 | Februar | 2 | 0 | 0 | |
| 10 | März | 3 | 0 | 0 | 0 |
| 11 | April | 4 | 0 | 0 | |
| 12 | Mai | 5 | 0 | 0 | |
| 13 | Juni | 6 | 0 | 0 | 0 |
| 14 | Juli | 7 | 0 | 0 | |
| 15 | August | 8 | 0 | 0 | |
| 16 | September | 9 | 0 | 0 | 0 |
| 17 | Oktober | 10 | 0 | 0 | |
| verwendete Formeln | |
| Zelle | Formel | Bereich | N/A |
| BG6:BG9 | =SUMMENPRODUKT((Rechnungen!F19:F25)*(Rechnungen!E19:E25=BE6)) | | |
| BG10 | =SUMMENPRODUKT((Rechnungen!F22:F29)*(Rechnungen!E22:E29=BE10)) | | |
| BG11 | =SUMMENPRODUKT((Rechnungen!F22:F30)*(Rechnungen!E22:E30=BE11)) | | |
| BG12 | =SUMMENPRODUKT((Rechnungen!F22:F31)*(Rechnungen!E22:E31=BE12)) | | |
| BG13 | =SUMMENPRODUKT((Rechnungen!F22:F32)*(Rechnungen!E22:E32=BE13)) | | |
| BG14 | =SUMMENPRODUKT((Rechnungen!F22:F33)*(Rechnungen!E22:E33=BE14)) | | |
| BG15 | =SUMMENPRODUKT((Rechnungen!F22:F34)*(Rechnungen!E22:E34=BE15)) | | |
| BG16 | =SUMMENPRODUKT((Rechnungen!F22:F35)*(Rechnungen!E22:E35=BE16)) | | |
| BH7,BH10,BH13,BH16 | =SUMME(BF6:BF8) | | |
| BF6:BF17 | =(BG6/100)*19 | | |
| BG17 | =SUMMENPRODUKT((Rechnungen!F22:F36)*(Rechnungen!E22:E36=BE17)) | | |
| Excel-Inn.de |
| Hajo-Excel.de |
| XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
| Add-In-Version 19.08 einschl. 64 Bit |
Pivot:
Pivot-Auswertung | A | B | C |
| 1 | | | |
| 2 | | | |
| 3 | | Daten | |
| 4 | Leistungsmonat | Betrag | MWSt |
| 5 | 1 | 1860 | 353,4 |
| 6 | 12 | 150 | 28,5 |
| 7 | Gesamtergebnis | 2010 | 381,9 |
| Excel-Inn.de |
| Hajo-Excel.de |
| XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 |
| Add-In-Version 19.08 einschl. 64 Bit |
[
attachment=4130]
[
attachment=4131]
super die erste formel hat super funktioniert ... dadurch das ich sie um die anderen monate noch erweitert hab, ist sie jetzt recht lang geworden aber sie tut was sie soll..
die andere Idee von dir wollte ich jetzt nicht umsetzen da ich sonst bei null wieder anfangen müsste. Außerdem bin ich mir nicht sicher ob sich die liste so realisieren würde da an der originalen tabelle noch mehr sachen hängen.
aber wie gesagt es funtkioniert und in den nächsten monaten werde ich vill noch fehler oder verbesserungen vornehmen aber das muss man dann in der praxis sehen.
Gruß und schönen tag noch
lion
Hallo,
da reicht doch eine klitzekleine Formel:
| Arbeitsblatt mit dem Namen 'MwSt' |
| | BD | BE | BF | BG |
| 3 | UmSt. Jahr 2015 / 16 |
| 4 | | | | |
| 5 | | MwSt | Einnahmen | |
| 6 | November | 0,00 € | 0,00 € | |
| 7 | Dezember | 28,50 € | 150,00 € | 381,90 € |
| 8 | Januar | 353,40 € | 1.860,00 € | |
| 9 | Februar | 0,00 € | 0,00 € | |
| 10 | März | 0,00 € | 0,00 € | 0,00 € |
| 11 | April | 0,00 € | 0,00 € | |
| 12 | Mai | 0,00 € | 0,00 € | |
| 13 | Juni | 0,00 € | 0,00 € | 0,00 € |
| 14 | Juli | 0,00 € | 0,00 € | |
| 15 | August | 0,00 € | 0,00 € | |
| 16 | September | 0,00 € | 0,00 € | 0,00 € |
| 17 | Oktober | 0,00 € | 0,00 € | |
| Zelle | Formel |
| BE6 | =SUMMENPRODUKT((REST(SPALTE(Rechnungen!$D$19:$CC$47);7)=4)*(Rechnungen!$D$19:$CC$47=MONAT($BD6&0));(Rechnungen!$E$19:$CD$47))*0,19 |
| BF6 | =SUMMENPRODUKT((REST(SPALTE(Rechnungen!$D$19:$CC$47);7)=4)*(Rechnungen!$D$19:$CC$47=MONAT($BD6&0));(Rechnungen!$E$19:$CD$47)) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |