N'abend allerseits,
ich habe ein vertikales jahresdatumblatt von Spalte A8:A373
und die Werte stehen in J8:J373...z.b U
Wie müsste die Formel lauten,um mir das Datum von bis anzeigen zu lassen.
Danke
Hallo s...,
ich habs so verstanden (siehe Anlage)
von:
=WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($J$8:$J$373)/($J$8:$J$373=$O$5)/($A$8:$A$373>P7);1));"")
bis:
=WENN(O8="";"";INDEX($A:$A;AGGREGAT(15;6;ZEILE($J$9:$J$374)/($J$9:$J$374<>$O$5)/($A$9:$A$374>O8);1)-1))
moin Ego,
deine Formel funktioniert soweit.
Nur das Problem ist,das sich der Zeilenbereich zw. Schaltjahr und normalen Jahren verändert.
Für dieses (Schalt)Jahr '24 stimmen die Angaben mit ....ZEILE($J$9:$J$374)/($J$9:$J$374<>$O$5)/($A$9:$A$374>O11);1)-1))
Im Jahr'25 sieht dies anders aus. Da hab ich nur ein Zeilenbereich von a8-a372. So wird dann mit dieser
Formel Jahresübergreifend das Datum angezeigt.
Kann man dies irgendwie korregieren,so das nur bis Jahresende das datum angezeigt wird?
Danke
Hallöchen,
mal umständlich? gedacht
=WENN(TAG(MONATSENDE(A8;1))=29;Formel für Schaltjahr;Formel für ungeschaltenes Jahr)
(Man könnte die Zelle auch per INDEX berechnen, im Prinzip z.B. statt ... $A$8:$A$373 ... dann $A$8:INDEX($A$372:$A$373;1+(TAG(MONATSENDE(A8;1))=29)))
Andererseits, falls Du die Datei jährlich erneuerst, ersetze einfach die Zahl
Hallo,
meine Frage ist, warum ändert sich der Beginn der Reihe in Abhängigkeit davon, ob das Jahr ein Schaltjahr ist oder nicht?
Theoretisch sollte der 1.1 immer in A8 stehen. Dann ist es völlig egal, ob der Zeilenbereich 365 oder 366 Werte umfasst.
Ansonsten wäre für den Rest des Jahrhunderts folgende Formel möglich:
Code:
=WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE(INDEX(J:J;8+(REST(JAHR(HEUTE());4)=0)):INDEX(J:J;372+(REST(JAHR(HEUTE());4)=0)*2))/(INDEX(J:J;8+(REST(JAHR(HEUTE());4)=0)):INDEX(J:J;372+(REST(JAHR(HEUTE());4)=0)*2)<>O5)/(INDEX(A:A;8+(REST(JAHR(HEUTE());4)=0)):INDEX(A:A;372+(REST(JAHR(HEUTE());4)=0)*2)>O5);1));"")
Einfacher wäre es, wenn die Jahreszahl irgenwo als Zahl stehen würde.
Oder (falls das in MAC 2016 schon funktioniert) so:
Code:
=LET(a;8+(REST(JAHR(HEUTE());4)=0);b;372+(REST(JAHR(HEUTE());4)=0);WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE(INDEX(J:J;a):INDEX(J:J;b))/(INDEX(J:J;a):INDEX(J:J;b)<>O5)/(INDEX(a:a;a):INDEX(a:a;b)>11);1));""))
Hi Edgar,
ich glaube, da sind die Beschreibungen vielleicht etwas durcheinander gekommen.
Die Ursprüngliche Aufgabe war ja
Zitat:ich habe ein vertikales jahresdatumblatt von Spalte A8:A373
und die Werte stehen in J8:J373...z.b U
Wie müsste die Formel lauten,um mir das Datum von bis anzeigen zu lassen.
und ich gehe mal davon aus, dass sich nur am Ende was "e"ndert
Der urlaub wird übrigens wohl nur bis zum 31.12. angezeigt, wenn das Datum in Spalte A nur bis zum 31.12. geht. Das wäre im normalen Jahr ja automatisch eins weniger, wenn man das korrekt ausfüllt
Allerdings, @Ego, ich bekomme #ZAHL wenn ich Urlaub bis zum 31.12.2024 nehme
Bis zum 30. geht.
Hallo André,
jep.
=WENN(O8="";"";INDEX($A:$A;AGGREGAT(15;6;ZEILE($J$9:$J$374)/($J$9:$J$374<>$O$5)/($A$8:$A$373>=O8);1)-1))
anstelle von
=WENN(O8="";"";INDEX($A:$A;AGGREGAT(15;6;ZEILE($J$9:$J$374)/($J$9:$J$374<>$O$5)/($A$9:$A$374>O8);1)-1))
@Egon,schauan...
ja,man darf wirklich nur bis zum 31.12. Einträge machen.
Egal welchen Jahr man auswählt.Und sich dadurch auch die Zeilennummern um 1 ändert.
Es funkt. und das zählt. :)