Clever-Excel-Forum

Moin zusammen,

Ich arbeite an einer Berufsschule und versuche diese digitaler zu gestalten.
Dazu habe ich eine Notenübersicht erstellt. Die Noten haben unterschiedliche Gewichtungen, soweit funktioniert die Tabelle aber.
In Zeile 6 stehen die Gewichtungen, ab Zeile 8 die jeweiligen Noten der Azubis. Mit meiner jetzigen Formel klappt die Berechnung an sich gut, bis auf eine Ausnahme, für die ich bisher keine Lösung gefunden habe.

Wenn eine Person eine Prüfungsleistung aus irgendeinem Grund nicht erbracht hat, oder noch nicht alle Noten eingetragen sind, dann zerschießt das die Endnote.
Wenn beispielsweise nur die ersten 2 Noten eingetragen sind, kommt eine Endote von 0,6 heraus, was natürlich nicht geht.

Plan ist: 
Es sollen nur die Zellen berücksichtigt und mit der jeweiligen Gewichtung mulitpliziert werden, in denen auch (schon) eine Note steht (im Beispiel zu sehen an Person 6)
Ich habe schon Dinge ausprobiert mit "Istzahl" und "Summewenn ">0"" Geschichten, aber sobald ich eine Note herausnehme (oder sie noch fehlt) kommt das gleiche Ergebnis dabei raus, wie bei meiner jetzigen Formel.
Diese lautet übrigens:
=SUMMENPRODUKT(C8:J8;$C$6:$J$6)/SUMME($C$6:$J$6)
Diese steht in der Spalte "schriftlich 1. AJ)

Wenn also eine Gewichtung z.B. 15% beträgt, und diese Note aber nicht eingetragen ist, soll einfach ohne die 15% gerechnet werden.

Ich hoffe die Frage ist deutlich geworden, bzw. nicht zur kompliziert beschrieben.
Anbei meine "Übungstabelle" in der ich rumprobiere.

Vielen Dank schonmal im Voraus!

Hi,

=SUMMENPRODUKT(C8:J8;$C$6:$J$6)/SUMMEWENNS($C$6:$J$6;C8:J8;"<>")

bei der Gesamtnote dann analog.

Und wenn dich das #DIV/0! stört, dann musst den Fehler halt abfangen z.B. mit WENNFEHLER().

Moin Helmut,

vielen Dank für deine Antwort.
Das hat ja einfacher geklappt als erwartet, ich übe derzeit noch und probiere viel herum :)
Mich stört das Div/0 an sich nicht, aber da ich ja auch die anderen von dieser Tabelle überzeugen möchte, würde ich den Fehler doch gern nicht anzeigen lassen.
Wie baue ich dann die Wennfehler() Funktion am besten in die Formel ein?

Beste Grüße

---

War vielleicht noch zu früh morgens..

hab es nun selbst doch hinbekommen  
Nun lautet die Formel:
=WENNFEHLER(SUMMENPRODUKT(C8:J8;$C$6:$J$6)/SUMMEWENNS($C$6:$J$6;C8:J8;"<>");"")

Falls es da doch noch Verbesserungsbedarf gibt, gern nochmal Bescheid geben :)

Hi,

siehste, geht doch.

Als Tipp, falls dir manche Funktionen nicht geläufig sind (so wie bis gerade eben WENNFEHLER)Sobald du die öffnende Klammer hinter dem Befehl geschrieben hast, wird dir unterhalb der Eingabe eine Kurzbeschreibung mit den Parametern angezeigt. Dort kann man mit der Maus auf den Befehl klicken und landet dann auf der Hilfeseite. Diese Seite hilft einem in den allermeisten Fällen bereits ausreichend gut weiter. Glaube mir, kein einziger Mensch wird alle Excel-Funktionen mit allen Parametern und deren Auswirkungen auswendig kennen.

Moin,

ja das kleine Feld mit den Bedingungen habe ich gesehen, aber nie auf die Hilfeseite geachtet.. :D
Mein Problem lag eher darin, dass ich unsicher war, wo die Wennfehler Funktion hingehört, aber wie gesagt mit etwas mehr Hirnanstrengung war es dann doch sehr logisch :)

Mal schauen welche Möglichkeiten ich nun noch so finde um uns allen die Arbeit zu erleichtern und man nicht mehr alles per Hand ausrechnen muss..

Vielen Dank!

Jetzt ist doch nochmal ein Problem bzw. eine Frage aufgetreten.

Die Notenübersicht läuft soweit, zur Zeit mit der Formel:

=WENNFEHLER(SUMMENPRODUKT(C8:J8;$C$6:$J$6)/SUMMEWENNS($C$6:$J$6;C8:J8;"<>");"")

Wenn jetzt in eine Zelle eingetragen wird, dass jemand bei einer Prüfung krank war (warum auch immer die Kollegen das möchten statt die Zelle leer zu lassen), wird diese Zelle wieder in die Berechnung genommen und mit 0 berechnet. Zerstört dann natürlich wieder die Gesamtnote.
Welche Möglichkeit habe ich nun, damit eine Zelle nur mit in die Berechnung genommen wird, wenn diese eine Zahl enthält und bei Text oder leerer Zelle soll diese nicht miteinfliessen?
Die Lösung ist vermutlich einfacher als gedacht (habe an ISTZAHL Prüfung gedacht) aber noch nicht so hinbekommen, dass es läuft.

Vielen Dank nochmal.

Hi,

vielleicht meinst Du so was:

=WENNFEHLER(SUMMENPRODUKT(C8:J8;$C$6:$J$6)/SUMMENPRODUKT(--ISTZAHL(C8:J8);C$6:J$6);"")

Hey,

ja Danke das scheint genau so zu funktionieren :)
jetzt möhte ich natürlich Wissen was dahinter steckt, also das doppel Minus sorgt quasi dafür, dass ein numerischer Wert berücksichtigt wird? Und wieso ist dadurch die Summewenns Formel nicht mehr nötig?
Mir gehts häufig darum, zu verstehen wieso das jetzt so klappt wie es klappt :D

Auf alle Fälle schon mal ein großes Dankeschön!

Hi,

SUMMEWENNS kann eine ZAHL nicht einwandfrei als solche identifizieren.
Daher wird es durch SUMMENPRODUKT ersetzt, das im Prinzip nichts anderes macht.

Zitat:SUMMENPRODUKT(--ISTZAHL(C8:J8);C$6:J$6)

ISTZAHL liefert erstmal WAHR oder FALSCH. Damit kann SUMMENPRODUKT aber nicht rechnen. Durch das Doppelminus wird 1 (WAHR) bzw. 0 (FALSCH) draus - und damit hat man 2 Arrays, aus denen man die Summe der jeweiligen Produkte errechnen kann - und das ist dann im Prinzip das Selbe wie SUMMEWENN(s).
Statt dem Doppelminus kann man auch irgendeine mathematisch neutrale Operation durchführen: *1, +0 etc. - also z.B.:

SUMMENPRODUKT(ISTZAHL(C8:J8)+0;C$6:J$6)

Es wäre besser die Daten ganz anders zu strukturieren: wie ein DataBase.
Dann braucht man kaum Formeln, und kann man die Ergebnisse auswerten in einer Pivottable.
Schau mal Arbeitsblatt AJ3 an.