Clever-Excel-Forum

Hallo zusammen,
Ich hoffe ich habe hier nur eine Kleinigkeit für Euch. Bin aber hier und woanders nicht fündig geworden.

Ich möchte mit XVERWEIS nicht nur die eine gesuchte Spalte wiedergeben, sondern auch eine bestimmte Anzahl der links benachbarten Spalten.
Mein Screen macht es glaube ich sehr verständlich.
Also in dem Fall möchte ich neben der Spalte Mai auch die drei links benachbarten Spalten in gleicher Anordnung ausgeben.

Danke vorab

Andi

Hallo,

PHP-Code:
=INDEX($B$3:$G$7;ZEILE($A1);VERGLEICH($J$2;$B$3:$G$3;0)-4+SPALTE(A$1)) 

Hallo Andy,

oder als Matrixformel:

=INDEX(B3:F7;1;VERGLEICH(J2;B3:F3;0)-3):INDEX(B3:F7;ZEILEN(B3:F7);VERGLEICH(J2;B3:F3;0))

bzw ab 21:

=LET(x;VERGLEICH(J2;B3:F3;0);INDEX(B3:F7;1;x-3):INDEX(B3:F7;ZEILEN(B3:F7);x))

Hi,

mit Beginn der Tabelle unter Mai:

Code:
=INDEX($A$3:$F$7;;VERGLEICH($H$1;$A$3:$F$3;0)-4+SPALTE(A$1))

nach rechts ziehen.

oder mit neuen Funktionen:

Code:
=LET(x;VERGLEICH(H1;A3:F3;0);b;INDEX(A3:F7;;x-3);c;INDEX(A3:F7;;x);VSTAPELN(b:c))

Hi,

neue Funktionen, ohne ziehen

Code:
=LET(

a;B2:G6;

b;3;

c;XVERGLEICH(K1;ÜBERNEHMEN(a;1));

d;SEQUENZ(;b;c-b+1);

e;SPALTENWAHL(a;d);

e)

a: Tabelle
b: Anzahl gewünschter Spalten
c: Spalte des Werts von K1 im Tabellenkopf
d: gewünschte Spaltennummern
e: gewünschte Spalten

Hallo Helmut,

auch nicht schlecht, aber es werden 4Monate gewünscht, also sollte es doch eher so aussehen:

Code:
=LET(a;A3:G7;b;4;c;XVERGLEICH(K1;ÜBERNEHMEN(a;1));d;SEQUENZ(;b;c-b+1);e;SPALTENWAHL(a;d);e)

Funktioniert hiermit genauso:

Code:
=LET(x;VERGLEICH(H1;A3:F3;0);b;INDEX(A3:F7;;x-3);c;INDEX(A3:F7;;x);VSTAPELN(b:c))

AndiG

Gastlich

Ego

BoskoBiati

HKindler

BoskoBiati