Clever-Excel-Forum

Hallo zusammen,

ich habe ein größeres Problem und hoffe mir kann hier einer weiterhelfen oder einen kleinen Denkanstoß geben.
in M6 wird bei mir folgende Formel ausgewiesen:

=WENN(ODER(LINKS(I6;2)="KF";LINKS(I6;2)="KS";LINKS(I6;3)="KVF";LINKS(I6;3)="KVS");(K6-J6)-ZEIT(0;30;0);WENN(LINKS(I6;2)="KG";L6/24;""))

Wenn in I6 bestimmte Arbeitsmuster vorhanden sind soll die Formel die Arbeitszeit errechnen und eine halbe Stunde pause Abziehen und das Ergebnis in Industrieminuten angeben -> Das funktioniert auch alles wunderbar.

Es soll folgende Funktion hinzugefügt werden:

Wenn in F6 einer dieser Buchstaben stehen ("U"; "G"; "ZU"; "zK"; "zV") soll die Sollarbeitszeit in L6 herangezogen werden, steht in F6 nichts oder ein anderer Buchstabe soll die Berechnungslogik von oben weiter angewandt werden.

mein jetziger Lösungsweg der leider nicht funktioniert, sieht wie folgt aus:

=WENN(ODER(LINKS(I6;2)="KF";LINKS(I6;2)="KS";LINKS(I6;3)="KVF";LINKS(I6;3)="KVS");WENN(ODER(F6="U";F6="G";F6="ZU";F6="zK";F6="zV");(K6-J6)*24*60; (K6-J6)-ZEIT(0;30;0)); WENN(LINKS(I6;2)="KG";L6/24; ""))

vielen Dank vorab für eure Hilfe/Denkanstöße.

Hallo,

eine Beispieldatei hilft helfen.

Hi,

Code:
=WENN(WENN(ODER(F6="U";F6="G";F6="ZU";F6="zK";F6="zV";LINKS(I6;2)="KG");L6/24;wenn(ODER(LINKS(I6;2)="KF";LINKS(I6;2)="KS";LINKS(I6;3)="KVF";LINKS(I6;3)="KVS");K6-J6-0,5/24;"")

(13.01.2024, 17:53)BoskoBiati schrieb: [ -> ]Hi,

Code:
=WENN(WENN(ODER(F6="U";F6="G";F6="ZU";F6="zK";F6="zV";LINKS(I6;2)="KG");L6/24;wenn(ODER(LINKS(I6;2)="KF";LINKS(I6;2)="KS";LINKS(I6;3)="KVF";LINKS(I6;3)="KVS");K6-J6-0,5/24;"")

Hallo,

deine Formel weißt mir zu viele geöffnete Klammern auf ( (= 10x ) = 8x, die Formel kann ich so in Excel leider nicht einsetzen.

Ich habe eine kleine Beispieldatei eingefügt. (musste Sie entsprechend anpassen, dadurch haben sich die Formeln ein wenig verschoben).

VG☺

Hi,

1. passen die Zellbezeichnungen in Deinen Formeln nicht zur Tabelle (z.B. LINKS(I6;2)="KG" )
2. kann man das Problem mit den Klammern selbst lösen, indem man die Formel in der Bearbeitungsleiste Zeichen für Zeichen durchgeht, dann sieht man welche Klammern zusammen gehören.

Code:
=WENN(ODER(F3="U";F3="G";F3="ZU";F3="zK";F3="zV";LINKS(F3;2)="KG");L3/24;WENN(ODER(LINKS(I3;2)="KF";LINKS(I3;2)="KS";LINKS(I3;3)="KVF";LINKS(I3;3)="KVS");K3-J3-0,5/24;""))

Hi,

statt bei Start und Ende unzählige WENN() zu verwenden, solltest du dir mal die VERWEIS-Funktionen anschauen, hier wäre der SVERWEIS bzw. bei aktuellem Excel der XVERWEIS passend. Wenn du Muster/Start/Ende als Tabelle in Q2:S10 schreibst, dann lautet z.B. die Formel für die Startzeit statt

Code:
=WENN(F3="KF02"; 5,5/24;

     WENN(F3="KF03"; 6,5/24;

          WENN(F3="KS02"; 14/24;

               WENN(F3="KS06"; 14/24;

                    WENN(F3="KG51/01"; ZEIT(7;0;0);

                         WENN(F3="KVF1"; ZEIT(5;30;0);

                              WENN(F3="KVS1"; ZEIT(14;0;0);

                                   WENN(F3="KS62"; ZEIT(14;0;0);

                                        WENN(F3="KF62"; ZEIT(5;30;0); 0)

                                   )

                              )

                         )

                    )

               )

          )

     )

)

einfach nur

Code:
=SVERWEIS($F3;$Q$2:$S$10;2;FALSCH)

und die Muster/Zeiten sind auch wesentlich leichter und übersichtlicher zu pflegen.

Und wenn du die Logik deiner Arbeitsmuster besser durchdenkst, könnte auch hier die WENN-Schlacht deutlich einfacher ausfallen.

Hi,

könnte man auch so verkürzen:

Code:
=WENN(ODER(F3={"U";"G";"ZU";"zK";"zV"};LINKS(F3;2)="KG");L3/24;WENN(ODER(LINKS(I3;2)={"KF";"KS"};LINKS(I3;3)={"KVF";"KVS"});K3-J3-0,5/24;""))

Celo0611

Klaus-Dieter

BoskoBiati

Celo0611

BoskoBiati

HKindler

BoskoBiati