Hallo,
ich habe eine Frage ob es möglich ist, Zahlenreihen die in bestimmten Zellen vorgegeben sind, automatisch nach unten zu kopieren.
Nacheinander sollen bestimmte Zahlenreihen wie 1, 2, 3 oder 1 - 16 immer wieder untereinander erscheinen, ohne das ich es hundertfach nach unten kopieren muss.
In der Beipieldatei wird es glaube ich deutlicher.
Ich könnte die Zahlenreihen auch von Hand kopieren, jedoch ist die Anzahl auzuwertender Daten doch erheblich.
Es wäre eine totale Erleichterung, wenn das ginge.
Danke und Gruß
Hallo,
warum schreist du uns an?
So wie du es in deiner Datei formuliert hast, geht das aus meiner Sicht nur mit einem Makro. Darf es so etwas sein?
Moin
Code:
=LET(
start;E9;
end;F9;
count;end-start+1;
repeat;I9;
ZUSPALTE(REST(SEQUENZ(count;repeat;start;1)-start;count)+start))
Sehr schön!
Da ich gerade dabei war, will ich meine Lösung nicht vorenthalten.
Ich habe die Sequenz-Länge mit den Wiederholungen multipliziert und verzichte auf ZUSPALTE().
Die REST()-Ermittlung mache ich genauso wie Detlef:
=REST(SEQUENZ((F9-E9+1)*I9;;E9)-E9;F9-E9+1)+E9
| E | F | G | H | I |
| 8 | Beginn | Ende | | | Wiederholungen |
| 9 | 8 | 13 | | | 2 |
| 10 | | | | | |
| 11 | | | | | |
| 12 | 8 | 8 | | | |
| 13 | 9 | 9 | | | |
| 14 | 10 | 10 | | | |
| 15 | 11 | 11 | | | |
| 16 | 12 | 12 | | | |
| 17 | 13 | 13 | | | |
| 18 | 8 | 8 | | | |
| 19 | 9 | 9 | | | |
| 20 | 10 | 10 | | | |
| 21 | 11 | 11 | | | |
| 22 | 12 | 12 | | | |
| 23 | 13 | 13 | | | |
| 24 | | | | | |
| Zelle | Formel |
| E12 | =REST(SEQUENZ((F9-E9+1)*I9;;E9)-E9;F9-E9+1)+E9 |
| F12 | =LET(
start;E9;
end;F9;
count;end-start+1;
repeat;I9;
ZUSPALTE(REST(SEQUENZ(count;repeat;start;1)-start;count)+start)) |
Gruß Ralf
Moin Ralf
Ich fand es charamant den Spalten-Parameter in SEQUENZ() mit der Anzahl der Wiederholungen zu belegen.
Hallo,
sehr nette Lösung von Euch Beiden, nur wird sie dem Frager nicht helfen, denn z.B. sind LET und SEQUENZ Funktionen, die es nur unter Office 365 gibt und der Frager hat Excel 2016 laufen!
Hallo g...,
zB (für E12):
=WENN(ZEILE()-ZEILE($E$11)>$F$9*$I$9;"";REST(ZEILE()-ZEILE($E$12);$F$9)+1)
Dann soll er halt auf Excel-Online ausweichen …
Ich suche meist die intellektuelle Herausforderung, Problemstellungen mit den neuen Funktionen zu lösen.
Wenn ich / wir das nicht täten, würden diese noch heute ein absolutes Nischendasein haben.
Außerdem wäre es nicht das erste mal, dass ein TE veraltete Profileinstellungen hat.
Gruß Ralf
Moin Günter
Die gezeigten Lösungen sind sicher auch für andere Anwender interessant.
Hallo Excel-PQ-Fan's,
hier meine PQ-Lösung, die ab Excel 2010 lauffähig ist.
Gruß von Luschi
aus klein-Paris
PS: kleine Korrektur im M-Code
statt: wieoft = #"Geänderter Typ"{0}[Column5],
so: wieoft = #"Geänderter Typ"{0}[Column6],