Clever-Excel-Forum

Hi zusammen,

ich erstelle mir gerade ein VBA, dass beim verlassen einer Zelle Aktionen durchführt (z.B. ein VBA Makro per Call).
Das klappt erstmal.

Jedoch habe ich ein Problem wenn ich bei den gecallten VBA Makros mit ActiveCells arbeite.
Denn er gibt mir nicht die Adresse der verlassene Zelle, sondern der neu besuchten Zelle wieder.
Hüpfe ich also von F10 in G10, ist die aktive Zelle G10. Ist ja eig. auch richtig so. Jedoch möchte ich F10 erfasst haben.

Ebenso habe ich auch schon probiert, die aktive Zelle bereits im VBA Marko, dass das verlassen der Zelle zu erfassen.
Hier passiert aber genau das Selbe.

Um es möglichst einfach zu halten, habe ich mal folgenden Beispiel Code erstellt.

Ziel: Beim verlassen einer Zelle zwischen F2:F13 (z.B. F10 auf G10 oder F10 auf F11) soll die Variable A die Adresse F10 erfassen.

Vielen Dank & LG

Code:
Private Sub Worksheet_Change(ByVal Target As Range)

Dim a As String

a = ActiveCell.Address(0, 0)

If Not Application.Intersect(Target, Range("F2:F13")) Is Nothing Then

MsgBox "Im Bereich F2:F13 wurde eine Zelle geändert!"

MsgBox a

End If

End Sub

Hi,

schon mal darüber nachgedacht, was wohl die Variable Target darstellt? Das ist/sind genau die Zelle/Zellen, die geändert wurden.

Code:
Private Sub Worksheet_Change(ByVal Target As Range)

Dim a As String

a = Target.Address(0, 0)

If Not Application.Intersect(Target, Range("F2:F13")) Is Nothing Then

MsgBox "Im Bereich F2:F13 wurde eine Zelle geändert!"

MsgBox a

End If

End Sub

oder besser:

Code:
Private Sub Worksheet_Change(ByVal Target As Range)

Dim z As Range

Set z = Intersect(Target, Range("F2:F13"))

If Not z Is Nothing Then

    MsgBox "Im Bereich F2:F13 wurden Zellen geändert!"

    MsgBox z.Address(0, 0)

End If

End Sub

Hallo,

die aktive Zelle ist immer die, die aktuell markiert ist. Insofern kann dieser Ansatz nicht funktionieren. Beschreibe doch mal, wo die Reise hingehen soll, eventuell mit einer Beispieldatei.

Hi Klaus-Dieter,

also anbei mal ein vollständiges Beispiel.

Ändere ich einen Wert und verlasse anschließend die Spalte soll er den geänderten Wert für alle Zeilen der Spalte übernehmen mit dem selben Wert in Spalte A.

Ändere ich also in Zelle E10 den Wert von 150 auf 175, soll Excel den Wert auch in E8 und E9 von 150 auf 175 ändern.

Aktuell passiert aber noch folgendes:
Verlasse ich die Zelle nach unten (auf E11), übernimmt Excel die 100 in Zeile 11, 12 und 13.
Verlasse ich die Zelle nach rechts (auf F10), übernimmt Excel die nichts.
Verlasse ich die Zelle nach oben(auf E9), übernimmt Excel die 150 in Zeile 8, 9 und 10.
Verlasse ich die Zelle nach links (auf D10), übernimmt Excel das L in Zeile 8, 9 und 10.

Und ich bekomme es noch nicht hin, dass die neuen Werte im Spalte E überschrieben werden.

Der Tipp von HKindler hat in soweit schonmal geholfen, dass ich im ersten Call bereits die Adresse der verlassenen Zelle erhalte.
Da müsste ich mal rausfinden, wie ich das dann in den Call als Variable mitnehmen kann.

Oder - und das vermute ich jetzt mal - habt ihr eine viel smarte Idee wie man das lösen kann.

LG

Andre

Hi,

das ist aber ziemlich umständlich aufgezogen...

Code:
Private Sub Worksheet_Change(ByVal Target As Range)

Dim Bereich As Range

Dim Zelle As Range

Dim ID As Variant

Dim Wert As Variant

Set Bereich = Range("E2:E13")

If Not Intersect(Target, Bereich) Is Nothing Then

    If Target.CountLarge = 1 Then

        ID = Cells(Target.Row, 1)

        Wert = Target.Value

        Application.EnableEvents = False

        On Error Resume Next

        For Each Zelle In Bereich

            If Cells(Zelle.Row, 1) = ID Then

                Zelle.Value = Wert

            End If

        Next Zelle

        On Error GoTo 0

        Application.EnableEvents = True

    End If

End If

End Sub

Auch das ist noch ziemlich umständlich. Ich würde hier gar kein VBA verwenden, sondern mir irgenwo eine Tabelle mit allen ID anlegen und dort die Preise eintragen. in der gezeigten Tabelle würde ich die Preis dann mit einem Verweis holen.

Hallo

meine Methode ist, in einem normalen Modul mit Public statt Dim eine Öffentliche Variable festlegen.
In alten Dateien findet man statt Public oft Global. Diese Variable behält ihren Wert in allen Makros bei!
Sie muss somit in allen Makros immer gezielt gesetzt oder gelöscht werden. Solange bleibt sie erhalten.
Ob Zahl, String für Adresse, Object usw. ist egal. Jede Zuweisung ist möglich.

mfg Gast 123

Hallo Gast123,

kann man machen, ist aber nicht in jedem Fall sinnvoll.

Hi zusammen,

dankenochmal für euer schnelles Feedback.

HKindlers Lösung macht genau das was ich möchte. Daher alles super!

LG

Andre

DonnaWetta

HKindler

Klaus-Dieter

DonnaWetta

HKindler

Gast 123

Klaus-Dieter

DonnaWetta