Hallo
Ich habe in A1 ein Datum. Nun will ich, dass er mir berechnet. Welches Datum der erste Sonntag des Monats aus dem Datum in A1 ist.
Beispiel: Wenn in A1 07.09.2024 steht, dann soll er mir in A2 den 01.09.2024 anzeigen, da es der erste Sonntag in dem Monat war. Wenn in A1 17.12.2023 steht, dann soll er mir in A2 den 03.12.2023 anzeigen usw.
Kann mir da einer mit einer Formel weiterhelfen?
Danke
LG Mathias
Hallöchen,
z.B.
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B |
| 1 | 17.12.2023 | 03.12.2023 |
| Zelle | Formel |
| A1 | =HEUTE() |
| B1 | =DATUM(JAHR(A1);MONAT(A1);1)+1-WOCHENTAG(DATUM(JAHR(A1);MONAT(A1);1))+WENN(1<WOCHENTAG(DATUM(JAHR(A1);MONAT(A1);1));7;0) |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365 |
| Diese Tabelle wurde mit Tab2Html (v2.7.2) erstellt. ©Gerd alias Bamberg |
Hallo zusammen, schönen dritten Advent.
Hätte auch mal einen Lösungsansatz, Datum steht in A1
Gruß Holger
Code:
=DATUM(JAHR(A1);MONAT(A1);1)+WAHL(WOCHENTAG(DATUM(JAHR(A1);MONAT(A1);1));0;6;5;4;3;2;1)
PHP-Code:
=EOMONTH(A1;-1)-WEEKDAY(EOMONTH(A1;-1);2)+7
Hallo,
Erst mal ein großes Lob an alle. Ihr seid ja sehr schnell. Finde ich echt super.
Ich werde es mit den von euch beschriebenen Formeln probieren. Sollte ich noch Fragen haben, schreibe ich sofort.
Dankeschön
LG Mathias
Hat funktioniert.
Danke danke
noch 'ne Variante um das Datum des ersten Sonntages eines bestimmten Monates zu ermitteln:
=ARBEITSTAG.INTL(MONATSENDE(A1;-1);
1;"111111
0")
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B |
| 1 | 17.12.2023 | 03.12.2023 |
| Zelle | Formel |
| B1 | =ARBEITSTAG.INTL(MONATSENDE(A1;-1);1;"1111110") |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021 |
| Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg |
Den Trick mit ARBEITSTAG.INTL gefunden hier:
https://www.contextures.com/exceldatenthdaymonth.html
Gruß
Fred
PHP-Code:
=A1-WEEKDAY(A1;2)-7*(INT(DAY(A1)/7)-1)
Freds Lösung ist die kürzeste. Und gleichzeitig verwendet sie das Argument nur einmal.
Hallöchen,
1)
eine hätte ich auch noch
=LET(x;A1;z;MONATSENDE(x;-1);z-WOCHENTAG(z;2))+7
2)
die zweite von snb ist doch eingedeutscht immer noch 1 kürzer als die von Fred, oder hab ich mich da verzählt?
Braucht man es hingegen absolutistisch
wird es dann mit Fred's Lösung wg. dem einen Argument kürzer