Hallo,
Zitat:Hoffe wir bekommen das noch hin.
:67: Wir vielleicht, Du eher weniger.
Deine Vorgaben sind noch lückenhaft:
Code:
WENN(C1="EU";"7:00";WENN(C1="SD";"0:00";WENN(C1="SDA";"10:00";WENN(C1="SDE";"0:00";WENN(C1="DZA";"DZA";WENN(C1="FT";"7:00";WENN(C1="SU";"7:00";WENN(C1="ADB";"7:00";WENN(C1="TD";"7:00";" ")))))))))
WENN(C1="EU";"16:30";WENN(C1="SD";"24:00";WENN(C1="SDA";"24:00";WENN(C1="SDE";"12:00";WENN(C1="DZA";"DZA";WENN(C1="FT";"16:30";WENN(C1="TD";"16:30";" ")))))))
Beim Ende fehlen Angaben für SU und ADB!
Zwei Möglichkeiten:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B | C | D | E | F |
| 1 | Dienstag | 05.01.2016 | EU | 7:00 | 16:30 | 9,00 |
| 2 | Mittwoch | 06.01.2016 | EU | 7:00 | 16:30 | 9,00 |
| 3 | Donnerstag | 07.01.2016 | EU | 7:00 | 16:30 | 9,00 |
| 4 | Freitag | 08.01.2016 | EU | 7:00 | 12:00 | 4,50 |
| 5 | Samstag | 09.01.2016 | | | | |
| 6 | Sonntag | 10.01.2016 | | | | |
| Zelle | Formel |
| D1 | =WENN(C1="";"";WENN(C1="DZA";C1;WENN(C1="SDA";10/24;WENN(LINKS(C1;2)="SD";0;7/24)))) |
| E1 | =WENN(C1="";"";WENN(C1="DZA";C1;WENN(C1="SDE";0,5;WENN(LINKS(C1;2)="SD";1;(16,5-(REST(B1;7)=6)*4,5)/24)))) |
| F1 | =WENN(C1="";"";WENN(C1<>"DZA";E1-D1-(LINKS(C1;2)<>"SD")*0,5/24;0)*24) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B | C | D | E | F |
| 8 | Montag | 11.01.2016 | TD | 7:00 | 16:30 | 9,00 |
| 9 | Dienstag | 12.01.2016 | SDA | 10:00 | 0:00 | 14,00 |
| 10 | Mittwoch | 13.01.2016 | EU | 7:00 | 16:30 | 9,00 |
| 11 | Donnerstag | 14.01.2016 | DZA | DZA | DZA | |
| 12 | Freitag | 15.01.2016 | FT | 7:00 | 12:00 | 4,50 |
| 13 | Samstag | 16.01.2016 | SDE | 0:00 | 12:00 | 12,00 |
| 14 | Sonntag | 17.01.2016 | | | | |
| 15 | | | | | | |
| 16 | | | | | | |
| 17 | ADB | 07:00 | | | | |
| 18 | EU | 07:00 | 16:30 | | | |
| 19 | FT | 07:00 | 16:30 | | | |
| 20 | SD | 00:00 | 24:00:00 | | | |
| 21 | SDA | 10:00 | 24:00:00 | | | |
| 22 | SDE | 00:00 | 12:00 | | | |
| 23 | SU | 07:00 | | | | |
| 24 | TD | 07:00 | 16:30 | | | |
| Zelle | Formel |
| D8 | =WENN($C8="";"";WENN(C8="DZA";C8;VERWEIS($C8;$A$17:B$24))) |
| E8 | =WENN($C8="";"";WENN(C8="DZA";C8;VERWEIS($C8;$A$17:C$24)-(LINKS(C8;2)<>"SD")*(REST(B8;7)=6)*9/48)) |
| F8 | =WENN((C8="")+(C8="DZA");"";(E8-D8-(LINKS(C8;2)<>"SD")/48)*24) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Dankeschön BosKoBiati,
Nach Hunderten versuchen und viel Anstrengung hat es nun mit Hilfe deiner ersten Tabelle geklappt.
Ein paar kleine Änderungen musste ich vornehmen und erstmal deine Formeln nachvollziehen was mir nicht immer gelungen ist.
Die Formel die die Stunden zusammen zählt sieht jetzt so aus.
Code:
=WENN(C2="";"";WENN(C2="DZA";C2;WENN((C2="SD");(E2-D2)*24;WENN(C2="SDA";(E2-D2)*24;WENN(C2="SDE";(E2-D2)*24;WENN((E2-D2)*24>6;(E2-D2)*24-0,5;(E2-D2)*24))))))
Es klappt nun alles und bin sehr zufrieden. Danke an alle die mir geholfen haben.
Ich hoffe das ich jemanden auch mal behilflich sein kann.
Macht weiter so.
Mfg
First-Aid