Clever-Excel-Forum

Moin!
Ich glaube, ihr beiden schrammt knapp an der eigentlichen Problematik vorbei.
Dem TE geht es doch "nur" um die Anzeige.
Da dürfte TEXT() helfen:

	B	C
4		Ihr Guthaben beträgt 500,66 €
5	500,66 €

Zelle	Formel
C4	=WENN(B5>0;"Ihr Guthaben beträgt "&TEXT(B5;"#.##0,00 €");WENN(B5<0;"Sie müssen nachzahlen "&TEXT(B5;"- #.##0,00 €");""))

Kleine Korrektur:
Das - in der Formel zur Anzeige negativer Werte ist falsch!
Korrekt ist:
=WENN(B5>0;"Ihr Guthaben beträgt "&TEXT(B5;"#.##0,00 €");WENN(B5<0;"Sie müssen nachzahlen "&TEXT(B5;"#.##0,00 €");""))
Wobei man das TEXT-Gedöns besser hinten anhängen sollte:
=WENN(B5>0;"Ihr Guthaben beträgt ";WENN(B5<0;"Sie müssen nachzahlen ";""))&TEXT(B5;"#.##0,00 €")

Gruß Ralf

Hi Ralf,

Minusbeträge nachzahlen finde ich gut.

Schade, nun doch nicht mehr. 

Gruß Uwe

Stimmt!  

Folglich sollte folgendes reichen:

	B	C
4		Ihr Saldo beträgt: -500,66 €
5	-      500,66 €

Zelle	Formel
C4	=WENN(B5;"Ihr Saldo beträgt: "&TEXT(B5;"#.##0,00 €");"")

Moin Ralf,

wieso passt mein Rat nicht?

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C
4		Ihr Guthaben beträgt 500,6589
5	500,66 €
6		Ihr Guthaben beträgt 500,66

Zelle	Formel
C4	=WENN(B5>0;"Ihr Guthaben beträgt "&B5;WENN(B5<0;"Sie müssen nachzahlen "&B5;""))
C6	=WENN(B5>0;"Ihr Guthaben beträgt "&RUNDEN(B5;2);WENN(B5<0;"Sie müssen nachzahlen "&RUNDEN(B5;2);""))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Moin Günter!
Oben schriebst Du kürzen und bist jetzt auf runden umgeschwenkt.
Den Unterschied brauche ich Dir ja nicht erklären.

	J	K	L
5	123,456789	123,45	123,46

Zelle	Formel
K5	=KÜRZEN(J5;2)
L5	=RUNDEN(J5;2)

Außerdem fehlt bei Dir das Eurozeichen, halte ich aber auch für vernachlässigenswert.

All das kann man aber mittels TEXT() verwursten, wie oben gezeigt:

	J	K	L	M
5	123,456789	123,45	123,46	Guthaben: 123,46 €

Zelle	Formel
K5	=KÜRZEN(J5;2)
L5	=RUNDEN(J5;2)
M5	="Guthaben: "&TEXT(J5;"#.##0,00 €")

Gruß Ralf

Du hast Recht, Ralf. Beim Begriff "kürzen" hat mich meine Gedankenlosgkeit übermannt. 

Hallo Leute,

ihr seid echt super.


Danke für die Hilfe.