Hallo !
Ich bin etwas ratlos. Ich muss eine errechnete Anzahl von Tagen in Jahre, Monate und Tage umrechnen.
Hat bisher immer gut geklappt. Ich habe dazu folgende Formel genutzt:
=DATEDIF(H3;HEUTE();"y")&" Jahr "
&DATEDIF(H3;HEUTE();"ym") &" Monat/e "
&DATEDIF(H3;HEUTE();"md")&" Tag/e"
Nun kam ich heute 1.3.2023 mit einer Anzahl von 151 Tagen auf
0 Jahre
5 Monate
- 1 Tage
Hat das mit dem 28. Februar tun? Wie kann ich das lösen, dass kein -1 Tag dort steht.
Vielen Dank für Euren Support.
Liebe Grüße aus dem Büro,
Claire
(01.03.2023, 11:26)Elex schrieb: [ -> ]Hi
Problem und Lösung.
https://support.microsoft.com/de-de/offi...32a451b35c
Gruß Elex
Hi Elex,
vielen Dank für Deine Antwort... aber leider bin ich zu doof dazu die Formel passend umzuschreiben...
alles was ich versuchen klappt nicht....
Könntest du mir aushelfen und mir sagen wie es richtig heißen müsste?
LG Claire
Was ist daran so schwer? Steht doch fast so wie du es brauchst auf der verlinkten Seite. Und zwar im letzten Bild:
![[Bild: a50cd076-9f82-47e6-83a5-6f408a682f84.png]](https://support.content.office.net/de-de/media/a50cd076-9f82-47e6-83a5-6f408a682f84.png)
Diese Formel verwendest du statt deinem Formelteil
DATEDIF(H3;HEUTE();"md") wobei du statt
E17 natürlich
HEUTE() brauchst.
Hallo,
hier nochmal alternative Varianten für die Berechnung ohne Datedif:
Jahre =GANZZAHL((HEUTE()-H3)/365)
Monate =REST(GANZZAHL(TAGE360(H3;HEUTE();WAHR)/30);12)
Tage =REST(TAGE360(H3;HEUTE();WAHR);30)
Wobei die Frage ist, ob das gewünschte Ergebnis herauskommt. Zum Beispiel vom 28.2.19 bis 29.2.20 kommt 1 Jahr und 0 Monate und 1 Tag heraus. Für mich ist es plausibel, da es genau 1 Jahr und 1 Tag sind. Wenn man beides als Monatsletzten sieht, könnte man hier auch genau 1 Jahr annehmen.
Hi
Bei der Geschichte ist die Frage wie ich die bereits in der Monatssumme erfassten Tage ansehe.
Code:
____|_____A____|_____B____|__C__|___D__|__E_|__F_|
1|Von |Bis |Jahre|Monate|Tage|Tage|
2|25.01.2023|01.03.2023| 0| 1| 4| 6|
3|26.01.2023|01.03.2023| 0| 1| 3| 5|
4|27.01.2023|01.03.2023| 0| 1| 2| 4|
5|28.01.2023|01.03.2023| 0| 1| 1| 3|
6|29.01.2023|01.03.2023| 0| 1| 1| 2|
7|30.01.2023|01.03.2023| 0| 1| 1| 1|
8|31.01.2023|01.03.2023| 0| 1| 1| 1|
9|01.02.2023|01.03.2023| 0| 1| 0| 0|
10|02.02.2023|01.03.2023| 0| 0| 27| 29|
11|03.02.2023|01.03.2023| 0| 0| 26| 28|
12|04.02.2023|01.03.2023| 0| 0| 25| 27|
13|05.02.2023|01.03.2023| 0| 0| 24| 26|
C2 =DATEDIF(A2;B2;"y")
D2 =DATEDIF(A2;B2;"ym")
E2 =B2-EDATUM(A2;D2+C2*12)
F2 =REST(TAGE360(A2;B2;WAHR);30)
Gruß Elex
@Elex Wenn ich mir das so ansehe, sollte ich über die Funktion für die Tage nochmal nachdenken ... das kann bei 31 Tagen nicht das richtige Ergebnis liefern (z. B. 30.07. bis 31.08.) ...
Hier mal ein anderer Versuch für die Tages-Formel:
PHP-Code:
=HEUTE()-EDATUM(H3;GANZZAHL(TAGE360(H3;HEUTE();WAHR)/30))
Aber wie gesagt, es ist fraglich, ob das Ergebnis so gewollt ist. Beispiele für evtl. kritische Daten:
30.07.2022 bis 01.09.2022
28.02.2019 bis 29.02.2020
Jedenfalls klappt deine Formel so jetzt.
Das erste Beispiel sehe ich eigentlich als richtig.
Über 28.02.2019 bis 29.02.2020 müssen wohl beide Formeln hinwegsehen.
GANZZAHL könnte man auch weglassen, da EDATUM die Nachkommastellen eh abschneidet:
PHP-Code:
=HEUTE()-EDATUM(H3;TAGE360(H3;HEUTE();WAHR)/30)