Moin!
Wer schon immer mal wissen wollte, an welchen Daten sich der böse Tag in diesem Jahrhundert befindet, braucht kein VBA mehr, sondern spillt mit folgender Formel die Daten:
=LET(
Beginn;DATUM(2000;1;1);Jahre;100;
Zeitraum;SEQUENZ(365,2425*Jahre;;Beginn);
FILTER(Zeitraum;(TAG(Zeitraum)=13)*(WOCHENTAG(Zeitraum;2)=5)))
Gruß Ralf
Moin Ralf
Nett.
Wenn ich das Startdatum auf meinen Geburtstag setze dann habe ich heute Freitag den 13. zum 100. Mal erlebt.
Ich hätte jetzt nicht gedacht, dass Du schon soooo alt bist! 
Ernsthaft:
Ich sehe da keine Fehler-Ursache.
Gerade erst geschnallt!
Ich eruiere kurz …
Hah!
Ich habe 103!
Du Jungspund mit Baujahr 64!
Nette Spielerei und ein schönes Beispiel für LET!
(13.01.2023, 18:38)RPP63 schrieb: [ -> ]Hah!
Ich habe 103!
Damit liegt dein Geburtsdatum im Zeitraum 13.07.62 bis 13.09.63.
Nö!
Wenn, dann doch eher im Zeitraum vom 1
4.07.1962 bis …
Ich habe übrigens ein KFZ-Kennzeichen für mein nächstes Auto reserviert:
Stadt-RP 3563
war noch frei!
Als es noch keinen SPILL-FILTER gab,
musste man ein wenig mehr rechnen (mit dem Vorteil, theoretisch auch 1.000.000 Folgedatümer bilden zu können, weil kein Wegfilterbedarf bestand):
C2: Ausgangsdatum
C3: Folgedatümer mit feststehendem Datumstag und -wochentag des Ausgangsdatums
=C2+(CODE(TEIL(WENN(TAG(C2)=TAG(C2+(CODE(TEIL(
"J'F0FF`J0=J=J'F0FJ`J0=J=J'F0FJ`J0=J=J'm0FJmJ0JJd";
MONAT(C2)+MAX(TAG(C2)-28;)*12;1))-35)*7);
"J'F0FF`J0=J=J'F0FJ`J0=J=J'F0FJ`J0=J=J'm0FJmJ0JJd";
"0=F0FFS`0S=00=F0FFS`0S=00=F0F`S`0S=0==`0F`z`0`=z");
MONAT(C2)+MAX(TAG(C2)-28;)*12;1))-35)*7
-UND(TAG(C2+{0;366})=31)*(MONAT(C2)=12)*518
... im folgenden umgemünzt auf eine Spillformel:
C3#:
=LET(b;C2;n;103;
x;"J'F0FF`J0=J=J'F0FJ`J0=J=J'F0FJ`J0=J=J'm0FJmJ0JJd";
SCAN(b;SEQUENZ(n);LAMBDA(a;c;
a+(CODE(TEIL(WENN(TAG(a)=TAG(a+(CODE(TEIL(x;
MONAT(a)+MAX(TAG(a)-28;)*12;1))-35)*7);x;
"0=F0FFS`0S=00=F0FFS`0S=00=F0F`S`0S=0==`0F`z`0`=z");
MONAT(a)+MAX(TAG(a)-28;)*12;1))-35)*7
-UND(TAG(a+{0;366})=31)*(MONAT(a)=12)*518)))
)