Hi,
ich bin auf der Suche nach einer Stückelung für Bargeldbeträge - Formel oder Matrix?
Also das Excel mir die Stückelung berechnet für einen Beitrag mit Anzahl 200er Scheine, 100, 50, 20, 10, 5..
Gibt ja unterschiedliche Ansätze, was ich so finde - nicht alles geht bei mir allerdings und wie macht man das am geschicktesten?
Ich habe eine Tabelle, wo Beträge drin sind und würde gerne pro Betrag (Zelle) in der Zeile die Stückelung berechnen, damit ich unten eine Summe bilden kann für die Scheine z.B.
Kann mir wer da einen guten Hinweis geben?
Danke
Hi,
gib mal im Suchfeld den Begriff Stückelung oder Bargeldstückelung ein. Das Thema wurde schon des Öfteren bearbeitet.
B1: =LET(
y;A1;
x;{500;200;100;50;20;10;5;2;1;0,5;0,2;0,1;0,05;0,02;0,01};
z;VSTAPELN(y;SCAN(y;x;LAMBDA(a;c;RUNDEN(a-KÜRZEN(a/c)*c;2))));
v;HSTAPELN(x;(WEGLASSEN(z;-1)-WEGLASSEN(z;1))/x);
FILTER(v;INDEX(v;;2)))
mit dem zu stückelnden Betrag in A1.
Hallo,
Anbei eine Beispieldatei mit Deinen Daten und den zugehörigen Lösungen (diese Datei wird ohne jegliche Gewährleistung zur Verfügung gestellt):
[
attachment=46583]
Die in dieser Datei verwendete Funktion ist eine Abwandlung dieser Funktion:
https://www.sulprobil.com/sbmincash_en/
Viele Grüße,
Bernd
Hallo,
bei meinem Vorschlag hast du etwas mehr Kombinationsmöglichkeiten...
Als Beispiel hatte ich jetzt einmal 960 Euro gewählt und das du keine 200 Euro Scheine einsetzen möchtest... (das kannst du in C2 bis H2 auswählen...)
Sehr witzig. Die 200 nimmt man bei mir einfach raus; dann geht das da auch.
Hi,
danke für eure Antworten.
(12.01.2023, 15:56)RPP63 schrieb: [ -> ]Moin!
Den Klassiker gibt es seit Äonen bei Excelformeln [klick mich]
Den hatte ich gefunden und versucht nach zu bauen für meine vorhandene Tabelle, dabei gab es leider Probleme. Der Download ist ja leider auch ganz anders aufgebaut, als das Bespiel der Seite.
(12.01.2023, 17:39)LCohen schrieb: [ -> ]B1: =LET(
y;A1;
x;{500;200;100;50;20;10;5;2;1;0,5;0,2;0,1;0,05;0,02;0,01};
z;VSTAPELN(y;SCAN(y;x;LAMBDA(a;c;RUNDEN(a-KÜRZEN(a/c)*c;2))));
v;HSTAPELN(x;(WEGLASSEN(z;-1)-WEGLASSEN(z;1))/x);
FILTER(v;INDEX(v;;2)))
mit dem zu stückelnden Betrag in A1.
Das sieht interessant aus, leider will mein Excel die Formal nicht - erkenne ich ad hoc noch nicht, warum. Muss ich mir - wie die anderen Ideen - noch mal anschauen
Danke.
EDIT: okay, anscheiend ging die Formel nur nicht unter MacOS Excel, unter Windows geht sie sofort.
@LCohen:
Chapeau!
Nur ein Vorschlag:
Damit man die vorhandene Stückelung nicht in die Matrix hämmern muss, bietet sich ja förmlich eine Verweis-Tabelle an.
Wandert auf jeden Fall in meine Formelsammlung!
Ich schlage vor, dass Du Dich hier oder auf Office-Hilfe.com verewigst, dann kann ich sofort einen Link setzen.
Hier meine unwesentliche Erweiterung mit der Verweis-Tabelle:
| A | B | C | D | E | F |
| 1 | 967,47 | 500,00 | 1 | | 500,00 | x |
| 2 | | 200,00 | 2 | | 200,00 | x |
| 3 | | 50,00 | 1 | | 100,00 | |
| 4 | | 10,00 | 1 | | 50,00 | x |
| 5 | | 5,00 | 1 | | 20,00 | x |
| 6 | | 2,00 | 1 | | 10,00 | x |
| 7 | | 0,20 | 2 | | 5,00 | x |
| 8 | | 0,01 | 7 | | 2,00 | x |
| 9 | | | | | 1,00 | |
| 10 | | | | | 0,50 | x |
| 11 | | | | | 0,20 | x |
| 12 | | | | | 0,10 | x |
| 13 | | | | | 0,05 | |
| 14 | | | | | 0,02 | |
| 15 | | | | | 0,01 | x |
| Zelle | Formel |
| B1 | =LET(
y;A1;
x;FILTER(E1:E15;F1:F15="x");
z;VSTAPELN(y;SCAN(y;x;LAMBDA(a;c;RUNDEN(a-KÜRZEN(a/c)*c;2))));
v;HSTAPELN(x;(WEGLASSEN(z;-1)-WEGLASSEN(z;1))/x);
FILTER(v;INDEX(v;;2))) |
Gruß Ralf
... das können wir gerne in unserem Beispielbereich aufnehmen
