Wie kann ich bei einer Exceltabelle bestimmte Daten nach mehreren Kriterien Filtern und in einer neuen Tabelle anzeigen
Beispieltabelle im Anhang
Die Kriterien stehen in H2 bis K3
Ergebnisse sollen ab H6 / L6
angezeigt werden
Ich habe es schon mit Index und vergleich, ebenso mit sverweis probiert leider ohne Erfolg
Excel 2016 und Microsoft 365
Hallo,
für Excel 2016 in H6:
Code:
=WENNFEHLER(INDEX($A$2:$A$11;AGGREGAT(15;6;ZEILE($A$1:$A$11)/(($A$2:$A$11>=$H$2)*($A$2:$A$11<=$I$2)*($B$2:$B$11=$J$2)*($F$2:$F$11>$K$2));ZEILE()-5));"")
für 365 in H6:
Code:
=FILTER(A2:A11;(A2:A11>=H2)*(A2:A11<=I2)*(B2:B11=J2)*(F2:F11>K2))
Weil das jeweilige Datum nur einmal vorkommt (Zufall?) kannst du I6 bis L8 mit dem SVERWEIS ausfüllen lassen...
(Du musst in K2 das ">" - Zeichen entfernen... das wird dann in der Formel berücksichtigt...)
Moin und nur ergänzend!
Meine Filterformel ist länger.
Sie nutzt die strukturierten Verweise der intelligenten Tabelle und ist dadurch dynamisch.
Außerdem brauche ich nur eine einzige Formelzelle.
Da der Name nicht ausgegeben werden soll, nehme ich SPALTENWAHL()
Und (siehe @rate mit):
Das "> " aus K2 muss weg.
| H | I | J | K | L |
| 10 | Datum | Strecke | Abfahrt | Ankunft | Stunden |
| 11 | 01.01.2022 | München | 08:00:00 | 16:20:00 | 08:20:00 |
| 12 | 02.02.2022 | Nürnberg | 08:15:00 | 16:50:00 | 08:35:00 |
| 13 | 31.03.2022 | München | 08:50:00 | 15:30:00 | 06:40:00 |
| Zelle | Formel |
| H11 | =SPALTENWAHL(FILTER(Tabelle1;(Tabelle1[Fahrer]=J2)*(Tabelle1[Datum]>=H2)*(Tabelle1[Datum]<=I2)*(Tabelle1[Stunden]>K2));1;3;4;5;6) |
Gruß Ralf
Moin
Oder snb's favourite: Advanced filter.
Wobei dann die <= >= und > als String im Kriterienbereich sein müssen.
| H | I | J | K | L | M |
| 16 | Datum | Datum | Fahrer | Stunden | | |
| 17 | >=44562 | <=44651 | Fahrer A | >0,25 | | |
| 18 | Datum | Fahrer | Strecke | Abfahrt | Ankunft | Stunden |
| 19 | 01.01.2022 | Fahrer A | München | 08:00 | 16:20 | 08:20 |
| 20 | 02.02.2022 | Fahrer A | Nürnberg | 08:15 | 16:50 | 08:35 |
| 21 | 31.03.2022 | Fahrer A | München | 08:50 | 15:30 | 06:40 |
| Zelle | Formel |
| H17 | =">="&H2 |
| I17 | ="<="&I2 |
| J17 | =J2 |
| K17 | =">"&K2 |
Weißt Du, wie man dann die Spalte Fahrer wegbekommt?
Ausblenden zählt nicht!
Bei mir hat es funktioniert vorher die gewünschten Spalten-Überschriften in den Zielbereich zu kopieren.
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| H | I | J | K | L |
| 15 | Datum | Datum | Fahrer | Stunden | |
| 16 | >=01.01.2022 | <=31.03.2022 | Fahrer A | >08:00 | |
| 17 | | | | | |
| 18 | | | | | |
| 19 | | | | | |
| 20 | Datum | Strecke | Abfahrt | Ankunft | Stunden |
| 21 | 01.01.2022 | München | 08:00 | 16:20 | 08:20 |
| 22 | 02.02.2022 | Nürnberg | 08:15 | 16:50 | 08:35 |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Hallöchen,
wobei man beim Spezialfilter beachten muss, dass ein Datum bei Excel ggf mit 0:00 Uhr berücksichtigt wird und nicht mit 24:00 Uhr
Ab wann bzw. wie geht denn SPALTENWAHL? Bei mir bekomme ich #Überlauf
Zielbereich wie im Beispiel und ist leer, auch darunter stand nix, Hinweis mit H2 ist beachtet..
Moin André!
(20.12.2022, 16:48)schauan schrieb: [ -> ]Bei mir bekomme ich #Überlauf
Dann kennt Deine Version diese Funktion, ansonsten käme ja #NAME?
Zitat:Ab wann bzw. wie geht denn SPALTENWAHL?
Die
Online-Hilfe ist mittlerweile sehr aussagekräftig:
Windows: 2208 (Build 15601)
Mac: 16.65 (Build 220911)
Web: eingeführt 15-Sep-2022
iOS: 2.65 (Build 220905)
Android: 16.0.15629
Ich hänge mal meine Version von heute morgen an, SPALTENWAHL steht in H11
Gruß Ralf
Hab jetzt die Lösungen versucht irgendwie klappt das nicht
Vielleicht lässt es sich mit Pivot lösen
Irgendwie?
Lade die Datei mit Deinen Versuchen hoch!
Was zeigt Dir meine hochgeladene Datei?
Zitat:Vielleicht lässt es sich mit Pivot lösen
Vielleicht auch mit Datenschnitt?
Aber wer weiß das schon …