Sehr geehrte Damen und Herren,
ich habe folgendes Problem: Ich möchte aus einem bestimmten Bereich Tabelle mit 2 Spalten, welche y und x Werte beinhaltet, zu dem ersten y Wert, der <= ein gebener Wert ist, den zugehörigen x Wert auslesen.
Normalerweise sollte das Problem mit =sverweis( C3;A:B;2;WAHR) (Beispiel) zu lösen sein, aber leider bekomme ich immer einen falschen Wert. Das Problem besteht darin, dass die Tabelle Werte eines Signals beinhaltet, welches ein gewissen Hintergrundrauschen hat und der gesuchte Wert mehrmals vorkommt, deswegen also nicht der erste Wert der <= des gegeben Wertes ausgegeben wird. Es geht darin einen Verfallsparameter darzustellen, also den Punkt an dem die Funktion 50% des peaks nach Erreichen des Maximums erreicht hat.
Jetzt ist die Frage, ob ich zu blöd bin mit der Funktion zu arbeiten, es eine alternative Funktion gibt oder man es z.B. über eine if Schleife lösen kann. Optimalerweise mit mehr als 2 Nachkommastellen, da sverweis leider nur mit bis zu 2 Nachkommastellen rechnen kann.
Es tut mir Leid, wenn die Frage vielleicht etwas basal ist, aber ich beschäftige mich noch so lange mit Excel und ich schaffe es gerade einfach nicht mich richtig tief in VBA einzulesen.
Ich würde mich über Tipps und Lösungsvorschläge freuen, die mir helfen auf die richtige Spur zu kommen.
Anbei eine Tabelle mit Wertepaaren als Beispiel.
Vielen Dank!
(06.01.2016, 23:46)Lor4x schrieb: [ -> ]Sehr geehrte Damen und Herren,
Jetzt ist die Frage, ob ich zu blöd bin mit der Funktion zu arbeiten, es eine alternative Funktion gibt oder man es z.B. über eine if Schleife lösen kann. Optimalerweise mit mehr als 2 Nachkommastellen, da sverweis leider nur mit bis zu 2 Nachkommastellen rechnen kann.
Es tut mir Leid, wenn die Frage vielleicht etwas basal ist...
Anbei eine Tabelle mit Wertepaaren als Beispiel.
Vielen Dank!
Hallo, wie kommst du denn darauf...? Was für ein Wert steht denn in C3 und was erwartest du für ein Resultat..?
C3 war nur als Beispiel gedacht. Ging aber leider nicht so richtig aus meiner Formulierung hervor.
Aber im Prinzip ist C3 immer =max(A:A) *0.5. Spielt doch aber eigentlich keine Rolle, oder?
(07.01.2016, 00:18)Lor4x schrieb: [ -> ]C3 war nur als Beispiel gedacht. Ging aber leider nicht so richtig aus meiner Formulierung hervor.
Aber im Prinzip ist C3 immer =max(A:A) *0.5. Spielt doch aber eigentlich keine Rolle, oder?
Hallo, aber was erwartest du für ein Ergebnis..? Und was meinst du mit den 2 Nachkommastellen..?
Ich möchte den zugehörigen Wert aus Spalte B auslesen. Also zum Beispiel wenn 6,5 der Maximalwert ist, will ich zu dem 1. Wert nach Erreichen des Masimums in Spalte A der <= 3,25 ist, den zugehörigen Wert in Spalte B auslesen .
Wenn man vorher berechnet, dass das Maximum bei 300 liegt, könnte die Funktion so lauten: =SVERWEIS(3.25;A300:B1400;2;WAHR). Ergebnis ist 1.06964286, es müsste aber 0.28214286 rauskommen, weil Zelle A316 den Wert beinhaltet der 3,25 am nächsten ist.
Sorry das mit den Nachkommastellen gilt lediglich für =sverweis(;;;FALSCH).
(07.01.2016, 00:39)Lor4x schrieb: [ -> ]Ich möchte den zugehörigen Wert aus Spalte B auslesen. Also zum Beispiel wenn 6,5 der Maximalwert ist, will ich zu dem 1. Wert in Spalte A der <= 3,25 ist, den zugehörigen Wert in Spalte B auslesen .
Hallo, meinst du so..?
=INDEX(B:B;VERGLEICH(KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&C3));A:A;0))
(07.01.2016, 00:39)Lor4x schrieb: [ -> ]...
Sorry das mit den Nachkommastellen gilt lediglich für =sverweis(;;;FALSCH).
Hallo, das ist schlullibulli... WAHR und FALSCH hat was mit genauer oder nicht genauer Übereinstimmung zu tun. Bei WAHR muss die Suchspalte im Übrigen aufsteigend sortiert sein...
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | C | D |
| 3 | 3,31455956 | 0,28035714 |
| 4 | 3,25 | 0,28214286 |
| Zelle | Formel |
| C3 | =MAX(A:A)/2 |
| D3 | =INDEX(B:B;VERGLEICH(KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&C3));A:A;0)) |
| D4 | =INDEX(B:B;VERGLEICH(KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&C4));A:A;0)) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo,
hier mal drei Varianten:
| 6,62911913 |
| 135 |
| 0,28035714 |
| 0,28035714 |
| 0,28035714 |
| Zelle | Formel |
| D1 | =MAX(A:A) |
| D2 | =VERGLEICH(D1;A:A;0) |
| D3 | {=INDEX(B:B;MIN(WENN(INDEX(A:A;D2):A9999<=D1/2;ZEILE(INDEX(A:A;D2):A9999))))} |
| D4 | {=INDEX(B:B;VERGLEICH(KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&MAX(A:A)/2));A:A;0))} |
| D5 | {=INDEX(B:B;MIN(WENN(INDEX(A:A;VERGLEICH(MAX(A:A);A:A;0)):A9999<=MAX(A:A)/2;ZEILE(INDEX(A:A;VERGLEICH(MAX(A:A);A:A;0)):A9999))))} |
| Achtung, Matrixformel enthalten! |
| Die geschweiften Klammern{} werden nicht eingegeben. |
| Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
(07.01.2016, 06:41)BoskoBiati schrieb: [ -> ]Hallo,
hier mal drei Varianten:
...
Hallo Edgar, die Variante in D4 ist ja praktisch mein Vorschlag (und braucht btw. nicht mit Strg+Enter+Umsch abgeschlossen werden)...
Und hier mal noch n Gedicht..:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B | C | D | E |
| 1 | Wert1 | Wert2 | | Wert1 | Wert2 |
| 2 | 1,02395442 | 0,00089286 | | 3,289442079 | |
| 3 | 1,01026076 | 0,00178571 | | | |
| 4 | 1,01848112 | 0,00267857 | | 0,280357143 | |
| 5 | 1,02414531 | 0,00357143 | | 0,280357143 | |
| 6 | 1,02782599 | 0,00446429 | | 0,280357143 | |
| 7 | 1,03014477 | 0,00535714 | | 0,280357143 | |
| 8 | 1,02763511 | 0,00625 | | | |
| 9 | 1,01731133 | 0,00714286 | | | |
| 10 | 1,00691413 | 0,00803571 | | | |
| 11 | 1,01351073 | 0,00892857 | | | |
| 12 | 1,00493062 | 0,00982143 | | | |
| 13 | 1,00634147 | 0,01071429 | | | |
| 14 | 1,00689088 | 0,01160714 | | | |
| 15 | 1,00385627 | 0,0125 | | | |
| Zelle | Formel |
| D2 | =KKLEINSTE(A:A;ZÄHLENWENN(A:A;"<="&MAX(A:A)/2)) |
| D4 | =DBMAX(A1:B1199;2;D1:E2) |
| D5 | =DBMIN(A1:B1199;2;D1:E2) |
| D6 | =DBSUMME(A1:B1199;2;D1:E2) |
| D7 | =DBAUSZUG(A1:B1199;2;D1:E2) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Schon mal vielen Dank für die Antworten, das hat mich schon enorm weiter gebracht!
Leider habe ich die Logik, aber noch nicht 100% verstanden. Ich habe es die verschiedenen Möglichkeiten nochmal mit anderen Datensätzen durchgespielt und mir gefällt die wenn-Verknüpfung am Besten.
=INDEX(G:G;MIN(WENN(INDEX(F:F;VERGLEICH(MAX(F:F);F:F;0)):F9999<=T5;ZEILE(INDEX(F:F;VERGLEICH(MAX(F:F);F:F;0)):F9999))))
Die Variante =INDEX(G:G;VERGLEICH(KKLEINSTE(F:F;ZÄHLENWENN(F:F;"<="&T5));F:F;0)) zeigt das Ergebnis bei anderen Datensätzen leider etwas falsch an, ich habe heute aber keine Geduld mir zu überlegen warum :(.
Jetzt möchte ich den ersten Wert ermitteln der >= T5 ist und diesmal aber in dem Wertebereich bis zu dem Wert von L2(Maximalwert). Ich hab versucht mir das zu überlegen und bin auf folgendes gekommen:
=INDEX(G:G;MIN(WENN(F1:INDEX(F:F;VERGLEICH(Max(F:F);F:F;0))>=T5;ZEILE(F1:INDEX(F:F;VERGLEICH(Max(F:F);F:F;0))))))
was aber nicht funktioniert, da F1:Index() irgendwie nicht funktioniert.
Könnten Sie mir da nochmal kurz was zu sagen? Zu den DB Funktionen habe ich auch einen Versuch gemacht, aber noch nicht so 100% verstanden wie die Kriterien definiert werden müssen.
Alles (inklusive meine Versuch mit der Db Funktion) ist nochmal in der angehängten Tabelle zu finden.
Ich bin auch offen für weitere Erklräungen. Habe schon viel dadurch gelernt.
Viele Grüße
Tim