Clever-Excel-Forum

Hallo zusammen,

Ich habe nicht sehr viel Anhung von Excel und brauche eure Hilfe.  :19:

Ich habe eine Absenzenliste von Mitarbeitern erstellt.
Der erste Reiter ist die Gesamtübersicht, danach kommen die Monate Januar, Februar, März etc...

Im ersten Reiter möchte ich nun verschiedene Absenzarten (Krankheit, Unfall, Mutterschaft, Vaterschaft, etc) der Mitarbeiter zusammenführen. Natürlich ist es so, dass wenn Mitarbeiter XY welcher erst im Mai angefangen hat in den Reitern Januar-April nicht vorhanden ist.

Nun habe ich mit SVERWEIS gearbeitet, hier meine Formel:

=SVERWEIS(A267;January!$A$3:$AN$287;30;FALSCH)+SVERWEIS(A267;February!$A$3:$AN$287;30;FALSCH)+SVERWEIS(A267;March!$A$3:$AN$287;30;FALSCH)+SVERWEIS(A267;April!$A$3:$AN$285;30;FALSCH)+SVERWEIS(A267;May!$A$3:$AN$293;30;FALSCH)+SVERWEIS(A267;June!$A$3:$AN$293;30;FALSCH)+SVERWEIS(A267;July!$A$3:$AN$286;30;FALSCH).

Soweit so gut... nun tauch bei einigen MA natürlich die Fehlermeldung NV auf, da die werte nicht überall sind.

Ich habe dann versuch jeweils eine Formel mit WENNFEHLER einzubauen. Aber bei über 12 Reitern, sagt mir das Excel, dass die Formel zu lang ist. 

Kann mir jemand weiterhelfen?

Vielen herzlichen Dank im Voraus.

LG
Noé

Hola,

wenn du alles untereinander auf ein Blatt schreibst reicht eine einfache Summewenn() Formel völlig aus.

Gruß,
steve1da

Hallo!

Danke für weine Antwort. Nein es ist nicht alles auf einem Blatt, ich möchte die Summen von 12 Tabellenblättern addieren.

Im Anhang habe ich ein Beispiel vorbereitet. Ich möchte auf dem Tabellenblatt 2015 in Spalte C die Summe aller  Absenzen mit AZ von Januar bis Dezember pro Mitarbeiter. 


Mit Summewenn klappt das irgendwie auch nicht

LG
Noé

Hallo Noé

Zitat:Nein es ist nicht alles auf einem Blatt, ich möchte die Summen von 12 Tabellenblättern addieren.

Ich denke das ist Steve schon klar gewesen.
Er wollte dir nur eine einfache Lösung präsentieren.

Da du offenbar aber komplizierte Lösungen bevorzugst:
http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=233
http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=234
http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=342

Hallo

Ach so, dann hab ich's falsch verstanden, sorry.

Besten Dank für die Links. Ich habe versucht aber ich blick nicht ganz durch. Ich versteh diese Formeln nicht ganz. 

Trotzdem vielen herzlichen Dank für eure Antworten!

Liebe Grüsse und ein frohes neues Jahr :)
Noé

Hi Noé,

aus shift-dels zweitem Link adaptiert:

2015

	A	B	C
1	NAME	Krankheit	Mit AZ
2	Anni		264
3	Austin		298
4	Barbara
5	Brigit		256
6	Brigit		256
7	Domi		216
8	Jasmin		88
9	Lyn
10	Nicole		112
11	Noé		94
12	Pat		86
13	Romi		118
14	Susi		64
15	Tom		8

Formeln der Tabelle

Zelle Formel C2 =SUMME(SUMMEWENN(INDIREKT("'"&{"Januar"."Februar"."März"."April"."Mai"."Juni"."Juli"."August"."September"."Oktober"."November"."Dezember"}&"'!a:a");A2;INDIREKT("'"&{"Januar"."Februar"."März"."April"."Mai"."Juni"."Juli"."August"."September"."Oktober"."November"."Dezember"}&"'!c:c")))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8


Ich denke, so willst du es haben?

Ergebnis "0" kannst du mit einer benutzerdefinierten Formatierung 0;; ausschalten

(01.01.2016, 19:22)WillWissen schrieb: [ -> ]Hi Noé,

aus shift-dels zweitem Link adaptiert:

...

Ich denke, so willst du es haben?

Ergebnis "0" kannst du mit einer benutzerdefinierten Formatierung 0;; ausschalten

Hi Günter, es geht aber auch kürzer... Wichtig für Faule, wie mich ..:

Arbeitsblatt mit dem Namen '2015'
	A	B	C
1	NAME	Krankheit	Mit AZ
2	Anni		264
3	Austin		88
4	Barbara
5	Brigit		256
6	Brigit		256
7	Domi		216
8	Jasmin		88
9	Lyn
10	Nicole		112
11	Noé		94
12	Pat		86
13	Romi		118
14	Susi		64
15	Tom		8

Zelle	Formel
C2	{=SUMME(SUMMEWENN(INDIREKT(TEXT(1&-ZEILE($A$1:$A$12);"MMMM")&"!A1:A100");A2;INDIREKT(TEXT(1&-ZEILE($A$1:$A$12);"MMMM")&"!C1:C100")))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Die einfachste und wohl übersichtlichste Lösung: Kopiere alle Monatsergebnisse untereinander und mache daraus eine PivotTabelle. Damit kannst du hervorragend alles erdenkliche auswerten; Monatsübersicht, Quartal, ... Für das erste Halbjahr habe ich das einmal für dich gemacht ... (bequemlichkeitshalber alles im Januar zusammengefasst).

Eine andere Lösung wäre mit Power Query, da kann dann alles so bleiben, wie es ist. Auf Anfrage stelle ich auch solch eine Musterdatei hier ein.

Hallo zusammen,

Sorry für meine späte Antwort.

Lieber Günter, das ist perfekt, hat tiptop geklappt. Vielen herzlichen Dank!!!!!!! Ich hätte das NIE herausgefunden.

Vielen Dank euch allen für eure Hilfsbereitschaft :D

Ich wünsche euch einen guten Start ins neue Jahr!!!!


Liebe Grüsse
Noé