Hallo,
ich möchte es irgendwie automatisieren Text aus mehreren Zellen mit Zeilenumbruch in eine zusammenzufügen.
Habe aber keine Ahnung wie ich das angehen soll.
Im Anhang ist eine Datei wie es aussehen sollte.
Die Überschriften sind immer so ähnlich benannt wie dargestellt, Anzahl der Textzeilen darunter variiert aber.
[
attachment=45176]
Schon mal vielen Dank für jede Hilfe
Hallo,
sind die Überschriften länger/kürzer als der Text darunter.
Es wird halt ein Unterschied von Texten und Überschriften benötigt.
Moin
Die Lösung ist so ähnlich wie diese:
Code:
=TEXTVERKETTEN(ZEICHEN(10);WAHR;A2:A3)
Der Text ist immer länger.
@shift-del
Danke,
funktioniert so aber gibt es einen Weg das zu automatisieren?
Wie zB.: ich füge die Formel/Makro/... neben der Überschrift ein und das Verketten passiert bis zur nächsten Überschrift.
Hallo,
um welche max Länge handelt es sich?
Zitat:Die Überschriften sind immer so ähnlich benannt wie dargestellt,
Das heißt genau?
Es muss ein verwendbares Kennzeichen geben.
Überschriften sind immer 8 Zeichen ("Sektor 1", "... 2", "... 3")
Textlänge ist 10- ca. 70 Zeichen.
Hallo Beulinski,
die zu verkettenden Bereiche zwischen den Überschriften automatisch / dynamisch ermitteln geht mit (viel) INDEX und VERGLEICH.
Z.B. mit einer Hilfsspalte:
| Arbeitsblatt mit dem Namen 'mit Hilfsspalte' |
| A | B | C |
| 1 | Sektor 1 | 2 | text 1
text 2 |
| 2 | text 1 | 0 | |
| 3 | text 2 | 0 | |
| 4 | Sektor 2 | 3 | text 1
text 2
text 3 |
| 5 | text 1 | 0 | |
| 6 | text 2 | 0 | |
| 7 | text 3 | 0 | |
| 8 | Sektor 3 | 6 | text 1
text 2
text 3
text 4
xyz
Hallo |
| 9 | text 1 | 0 | |
| 10 | text 2 | 0 | |
| 11 | text 3 | 0 | |
| 12 | text 4 | 0 | |
| 13 | xyz | 0 | |
| 14 | Hallo | 0 | |
| Zelle | Formel |
| B1 | =WENN(ZÄHLENWENN(A1;"Sektor*");WENNFEHLER(VERGLEICH("Sektor*";INDEX($A$1:$A$30;ZEILE()+1):$A$30;0)-1;ANZAHL2(INDEX($A$1:$A$30;ZEILE()+1):$A$30));0) |
| C1 | =WENN(B1>0;TEXTVERKETTEN(ZEICHEN(10);0;INDEX($A$1:$A$30;ZEILE()+1):INDEX($A$1:$A$30;ZEILE()+B1));"") |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021 |
| Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg |
Ohne Hilfsspalte geht auch, die Formel wird halt länger und komplexer:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
| 1 | Sektor 1 | | text 1
text 2 |
| 2 | text 1 | | |
| 3 | text 2 | | |
| 4 | Sektor 2 | | text 1
text 2
text 3 |
| 5 | text 1 | | |
| 6 | text 2 | | |
| 7 | text 3 | | |
| 8 | Sektor 3 | | text 1
text 2
text 3
text 4
xyz
Hallo |
| 9 | text 1 | | |
| 10 | text 2 | | |
| 11 | text 3 | | |
| 12 | text 4 | | |
| 13 | xyz | | |
| 14 | Hallo | | |
| Zelle | Formel |
| C1 | =WENN(ZÄHLENWENN(A1;"Sektor*");TEXTVERKETTEN(ZEICHEN(10);0;INDEX($A$1:$A$30;ZEILE()+1):INDEX($A$1:$A$30;ZEILE()+WENNFEHLER(VERGLEICH("Sektor*";INDEX($A$1:$A$30;ZEILE()+1):$A$30;0)-1;ANZAHL2(INDEX($A$1:$A$30;ZEILE()+1):$A$30))));"") |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021 |
| Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg |
(in Spalte C halt noch den Textumbruch einschalten, damit die Werte in den Zellen untereinander dargestellt werden)
Siehe angehängte Beispieldatei.
Gruß
Fred