Wer kann mir helfen den Text von Spalte C in dem das Datum enthalten ist im Format JJJJMMTT umwandeln in das Datumsformat TT.MM.JJJJ und von diesen dann 28 Tage abziehen und in Spalte A anzeigen. In meinen vorliegenden Fall 20220120 das ja 20.01.2022 bedeutet sollte dann 20.01.2022 ergeben werden minus 28 Tage.
DANKE für die HILFE! Ich weiss nicht weiter.
Gruss
Karl
Moin!
| A | B | C |
1 | Datum | | Bezeichnung |
2 | 23.12.2021 | | StapelBriefe_S-20220120-001 |
Zelle | Formel |
A2 | =LET(t;TEIL(RECHTS(C2;12);1;8);
d;--(RECHTS(t;2)&"."&TEIL(t;5;2));
d-28) |
oder noch kürzer:
=LET(t;TEIL(RECHTS(C2;12);1;8);(RECHTS(t;2)&"."&TEIL(t;5;2))-28)
bzw. dann (siehe Maninweb) als überlaufende Formel:
=LET(t;TEIL(RECHTS(C2:C24;12);1;8);(RECHTS(t;2)&"."&TEIL(t;5;2))-28)
Gruß Ralf
Hallo,
Code:
E2=LET(Bezeichnung;$C2;Datumstext;TEIL(Bezeichnung;1+FINDEN("-";Bezeichnung);8);DATUM(LINKS(Datumstext;4);TEIL(Datumstext;5;2);RECHTS(Datumstext;2)))
Für ein ggf. dynamisches Array kannst Du auch statt $C2 dann $C2:$C24 nehmen.
Gruß
DANKE schon mal
Die Formel funktioniert fast wenn sich aber das Jahr ändert z.B. "StapelBriefe_S-20250120-001" das ja das Jahr 2025 entspricht ändert sich das Ergebnis nicht es erscheint ebenfalls 23.12.2021 müsste ja abzüglich der 28 Tage 23.12.2024 sein.
Kann man das irgendwie mit einbauen
Gruss
Karl
Das erledigt die Formel von maninweb!
Deshalb:
Augen auf bei der Bereitstellung von Beispieldaten!
VIELEN DANK
Die Formel funktioniert TOP
Schönen Sonntag noch
DANKE
Hi,
noch eine Variante:
=TEXT(TEIL(C2;FINDEN("-";C2)+1;8);"0000-00-00")-28
Hallo,
die -28 hatte ich aber vergessen ;-)
Gruß