Hallo zusammen,
brauche einmal eure Hilfe da ich wieder an meine Grenzen gestoßen bin!
Meine Beispieldatei hat 3 Tabellenbläter in denen jeweils in den gelb hinterlegten Zeilen (ab B3) nur die Wochentage automatisch für den jeweiligen Monat angezeigt werden sollen.
Tabellenblatt 1 = Nur Montags - Freitags
Tabellenblatt 2 = Nur Samstags
Tabellenblatt 3 = Nur Sonntags
So, dass ich in die Zeile A3 im Tabellenblatt MF-FR nur das 1.Datum von dem jeweiligen Monat eintragen kann und die Zellen werden dann automatisch mit den Wochentagen gefüllt.
Für MO-FR habe ich schon eine Formel im Netz gefunden (hoffentlich brauchbar 
). Hier wird jedoch der Folgemonat noch mit in die freien Zeilen geschrieben 
was ungünstig ist.
Für Samstags und Sonntags bekomme ich es aber einfach nicht hin.
Es wäre echt klasse wenn jemand für mich eine Lösung hätte.
Wenn es dann noch eine Möglichkeit für das Einbinden der Feiertage geben würde wäre es das i-Tüpfelchen !!!!!!
Vielen lieben Dank erst einmal
jokerjo1000
Moin
Immer wieder erstaunlich wie sich Leute absichtlich das Leben schwer machen.
Was meinst du denn damit ???
Das man so eine Datei auch anders aufbauen könnte ist mir bewusst, jedoch wird genau diese Datei schon seit Jahren so benutzt weil wohl auch einige andere Dateien darauf verknüpft sind. Jetzt hatte mich ein Arbeitskollege eben darum gebeten ob ich es so hinbekomme wie beschrieben
Hola,
was macht denn die Aufteilung für einen Sinn wenn der Aufbau der Daten immer gleich ist?
Gruß,
steve1da
Die Datei ist immer jeweils für einen Monat, so dass sich die Tage ja ständig ändern sobald das Datum in A3 geschrieben wird (zB. 01.01.2021, 01.02.2021,01.03.2021)
Schon klar, beantwortet aber meine Frage nicht. Warum die Aufteilung?
Ansonsten musst du halt abfragen, ob der Monat des Datums in C3, D3, F3... größer als der Monat in A3 ist. Wenn ja, dann "" ausgeben, ansonsten den Tag.
Den ersten Samstag/Sonntag im Monat erhältst du mit:
https://www.herber.de/excelformeln/pages...Monat.html
Da dann jeweils +7 rechnen und ebenfalls prüfen ob der Monat größer ist als der in A3.
(30.12.2021, 10:31)jokerjo1000 schrieb: [ -> ]jedoch wird genau diese Datei schon seit Jahren so benutzt
Da bleibt nichts als mit der Schulter zu zucken und sich dem nächsten Fall zuzuwenden.
Hallo zusammen,
Auch wenn ich dem zustimme das es eigentlich sinnvoller ist das ganze in einer einzigen Liste zu machen möchte ich das nicht so unbeantwortet stehen lassen.
hallo @jokerjo1000
Letztendlich kannst du dafür immer die gleichen Funktionen nutzen.
Formel für MF-FR!B3:
=A3+WAHL(WOCHENTAG(A3;2);0;0;0;0;0;3;2)
Für MF-FR!C3 zum kopieren nach rechts:
=B3+WAHL(WOCHENTAG(B3;2);1;1;1;1;3;2;1)
Erklärung:
1. WOCHENTAG(A3;2) prüft den Wochentag von A3 und gibt eine Zahl zwischen 1 und 7 zurück (Mo.-So)
2. Abhängig vom Wochentag werden in zu A3 (MF-FR!B3) durch die Funktion WAHL 0;0;0;0;0;3;2 Tage addiert
Bei den anderen Zellen musst du halt nur anpassen wie viele Tage dort abhängig vom Wochentag addiert werden sollen, in C3 und kopiert nach rechts immer 1;1;1;1;3;2;1
Genau so geht es weiter für Sa. und So.
Für SA!B3
=A3+WAHL(WOCHENTAG(A3;2);5;4;3;2;1;0;7)
Für SO!B3
=A3+WAHL(WOCHENTAG(A3;2);6;5;4;3;2;1;0)
Für die nachfolgenden Samstage / Sonntage B3+7 und nach rechts kopieren
eine bedingte Formatierung, die auf ungleichen Monat prüft, formatiert die Schrift in gelb und macht den falschen Eintrag "unsichtbar"
Das ist alles,
allen ein gesundes und glückliches neues Jahr
Holger
Moin!
Off Topic mal die Variante mit nur einer Formelzelle in aktuellen Excel-Versionen.
=LET(m;DATUM(2021;1;SEQUENZ(;31));FILTER(m;WOCHENTAG(m;2)<6))
| A | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T | U | V |
| 1 | Fr|01 | Mo|04 | Di|05 | Mi|06 | Do|07 | Fr|08 | Mo|11 | Di|12 | Mi|13 | Do|14 | Fr|15 | Mo|18 | Di|19 | Mi|20 | Do|21 | Fr|22 | Mo|25 | Di|26 | Mi|27 | Do|28 | Fr|29 | |
| Zelle | Formel |
| A1 | =LET(m;DATUM(2021;1;SEQUENZ(;31));FILTER(m;WOCHENTAG(m;2)<6)) |
Wenn man vom Monat eines beliebigen Ausgangsdatums in einer Zelle (X1) ausgeht, dann etwas länger so:
=LET(j;JAHR(X1);m;MONAT(X1);x;DATUM(j;m;SEQUENZ(;TAG(DATUM(j;m+1;0))));FILTER(x;WOCHENTAG(x;2)<6))
Für SA dann
WOCHENTAG(x;2)=6
für SO
WOCHENTAG(x;2)=7
| A | B | C | D | E | F | G | H | I | J | K | L | M | N | O | P | Q | R | S | T | U | V | W | X |
| 1 | Mi|01 | Do|02 | Fr|03 | Mo|06 | Di|07 | Mi|08 | Do|09 | Fr|10 | Mo|13 | Di|14 | Mi|15 | Do|16 | Fr|17 | Mo|20 | Di|21 | Mi|22 | Do|23 | Fr|24 | Mo|27 | Di|28 | Mi|29 | Do|30 | Fr|31 | 15.01.2020 |
| 2 | Sa|04 | Sa|11 | Sa|18 | Sa|25 | | | | | | | | | | | | | | | | | | | | |
| 3 | So|05 | So|12 | So|19 | So|26 | | | | | | | | | | | | | | | | | | | | |
| Zelle | Formel |
| A1 | =LET(j;JAHR(X$1);m;MONAT(X$1);x;DATUM(j;m;SEQUENZ(;TAG(DATUM(j;m+1;0))));FILTER(x;WOCHENTAG(x;2)<6)) |
| A2 | =LET(j;JAHR(X$1);m;MONAT(X$1);x;DATUM(j;m;SEQUENZ(;TAG(DATUM(j;m+1;0))));FILTER(x;WOCHENTAG(x;2)=6)) |
| A3 | =LET(j;JAHR(X$1);m;MONAT(X$1);x;DATUM(j;m;SEQUENZ(;TAG(DATUM(j;m+1;0))));FILTER(x;WOCHENTAG(x;2)=7)) |
Gruß Ralf
