Hallo zusammen,
ich bräuchte noch einmal eure Hilfe.
Eine Zeile hat folgende Formel:
=SUMMENPRODUKT((F5:F22>0)*(F5:F22<499))+ZÄHLENWENN(F5:F22;"x")
Jetzt soll er auch zählen, Wenn in einer Zeile ein X mit einer Zahl steht. Aber nur die X wo die Zahl zwischen 0 und 499 liegt.
Sprich: wenn in der Zeile X360 steht, soll er zählen. Steht da X500, dann nicht.
hat da jemand eine Idee? Ich benutze Excel 2003
Besten Dank
Danny
Hallo Dany
ich würde dazu raten, das "x" in einer separaten Spalte zu platzieren. Die Berechnung wäre viel einfacher und präziser, siehe Beispiel unten
X360 ist halt für Excel keine Zahl sondern Text der nur wie eine Zahl aussieht.
Um das zu lösen muss man zwangsläufig den Text zerlegen um an die Zahlen zu kommen und sie auszuwerten.
Ein weiteres Problem ist Excel 2003. Da liegen 18 Jahre dazwischen.
Ich bin mir daher auch nicht sicher ob die folgende Matrix-Formel überhaupt funktioniert
WICHTIG: Eingabe mit der Tastenkombination [STRG]+[Shift]+[Return] abschießen.
Die Formel steht dann in {=Formel} geschweiften Klammern.
=SUMME((WENN(F5:F22="x";1;(RECHTS("0"&F5:F22;3)*1))>0)*(WENN(F5:F22="x";1;(RECHTS("0"&F5:F22;3)*1))<499))
Gruß Holger
Tabelle1 | F | G |
| 5 | x | 222 |
| 6 | | |
| 7 | | |
| 8 | x | |
| 9 | | 222 |
| 10 | X | 222 |
| 11 | | 500 |
| 12 | X | |
| 13 | | |
| 14 | X | 700 |
| 15 | | 700 |
| 16 | x | 498 |
| 17 | | |
| 18 | | |
| 19 | | |
| 20 | | |
| 21 | | |
| 22 | | |
| 23 | | 6 |
| Formeln der Tabelle |
| Zelle | Formel | | G23 | =SUMMENPRODUKT((G5:G22>0)*(G5:G22<499)+(F5:F22="x")*(G5:G22="")) |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Moin,
ich weiß jetzt natürlich nicht, ob Excel 2003 die Formeln kennt. Probiers einfach.
Du musst aber mit einer Hilfsspalte arbeiten.
| B | C | D |
| 1 | Eingabe | Hilfsspalte | Ergebnis |
| 2 | 23 | 23 | 5 |
| 3 | x45 | 45 |
| 4 | 450 | 450 |
| 5 | x78 | 78 |
| 6 | 650 | 650 |
| 7 | 150 | 150 |
| Zelle | Formel |
| C2 | =ZAHLENWERT(WENN(ISTTEXT(B2);WECHSELN(B2;LINKS(B2;1);"");B2)) |
| D2 | =ZÄHLENWENN(C2:C12;"<500") |
| C3 | =ZAHLENWERT(WENN(ISTTEXT(B3);WECHSELN(B3;LINKS(B3;1);"");B3)) |
| C4 | =ZAHLENWERT(WENN(ISTTEXT(B4);WECHSELN(B4;LINKS(B4;1);"");B4)) |
| C5 | =ZAHLENWERT(WENN(ISTTEXT(B5);WECHSELN(B5;LINKS(B5;1);"");B5)) |
| C6 | =ZAHLENWERT(WENN(ISTTEXT(B6);WECHSELN(B6;LINKS(B6;1);"");B6)) |
| C7 | =ZAHLENWERT(WENN(ISTTEXT(B7);WECHSELN(B7;LINKS(B7;1);"");B7)) |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365 |
| Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg |
Zitat:=SUMMENPRODUKT((F5:F22>0)*(F5:F22<499))+ZÄHLENWENN(F5:F22;"x")
jetzt soll er auch zählen, Wenn in einer Zeile ein X mit einer Zahl steht. Aber nur die X wo die Zahl zwischen 0 und 499 liegt.
Sprich: wenn in der Zeile X360 steht, soll er zählen. Steht da X500, dann nicht.
Hallo @StefanB
wenn ich das richtige sehe, so werden "X" ohne Werte nicht berücksichtigt, oder...
+ZÄHLENWENN(F5:F22;"x") müsste dann noch dahinter
Gruß Holger
@echo - Hallo Holger,
ein alleinstehendes x gibt den Wert 0 zurück. In meinem ersten Beispiel wird das aber mitgezählt. Das ist natürlich quatsch und wäre somit falsch.
So müsste es dann aussehen...
| B | C | D |
| 1 | Eingabe | Hilfsspalte | Ergebnis |
| 2 | x | 0 | 4 |
| 3 | x45 | 45 |
| 4 | 450 | 450 |
| 5 | x78 | 78 |
| 6 | 650 | 650 |
| 7 | 150 | 150 |
| Zelle | Formel |
| C2 | =ZAHLENWERT(WENN(ISTTEXT(B2);WECHSELN(B2;LINKS(B2;1);"");B2)) |
| D2 | =SUMMENPRODUKT((C2:C7>0)*(C2:C7<499)) |
| C3 | =ZAHLENWERT(WENN(ISTTEXT(B3);WECHSELN(B3;LINKS(B3;1);"");B3)) |
| C4 | =ZAHLENWERT(WENN(ISTTEXT(B4);WECHSELN(B4;LINKS(B4;1);"");B4)) |
| C5 | =ZAHLENWERT(WENN(ISTTEXT(B5);WECHSELN(B5;LINKS(B5;1);"");B5)) |
| C6 | =ZAHLENWERT(WENN(ISTTEXT(B6);WECHSELN(B6;LINKS(B6;1);"");B6)) |
| C7 | =ZAHLENWERT(WENN(ISTTEXT(B7);WECHSELN(B7;LINKS(B7;1);"");B7)) |
| Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365 |
| Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg |
Guter Hinweis, danke