Hallo wer kann mir helfen?
Ich habe die Datei angefügt, ich bräuchte die passenden automatischen Formeln damit die Tage nach den Bedingungen berechnet werden und in der Übersicht gelistet werden.
Ich habe eine Formel eingebaut, die berechnet die Tage aber nicht richtig.
Ich hoffe ihr könnt mir helfen und anhand der Datei verstehen was ich meine.
Danke im Voraus
Hallo!
Ich versuche mal, dir zu helfen. Um dieses Problem wirklich vollautomatisch über eine Formel lösen zu können, brauchst du noch eine Hilfsspalte, in der du die Sonderfälle gerade/ungerade erfasst. Ich melde mich nochmal, wenn ich die Datei fertig habe.
Liebe Grüße
Alex
Hallo!
Ich bins nochmal. Habe jetzt die Datei angepasst. Da du auch noch letzte Tage drin hast, wurde die Formel etwas länger. Den letzten Tag musst du auch in der Spalte Sonderfälle mit einem L erfassen.
=WENN(E2="L";DATUM(JAHR(B2);MONAT(B2)+1;-REST(DATUM(JAHR(B2);MONAT(B2)+1;-1)-C2;7));WENN(E2="G";WENN(REST(MONAT(B2);2)=0;B2-REST(B2-2-C2;7)+7*D2-1;DATUM(JAHR(B2);MONAT(B2)+1;1)-REST(DATUM(JAHR(B2);MONAT(B2)+1;1)-2-C2;7)+7*D2-1);WENN(E2="U";WENN(REST(MONAT(B2);2)=1;B2-REST(B2-2-C2;7)+7*D2-1;DATUM(JAHR(B2);MONAT(B2)+1;1)-REST(DATUM(JAHR(B2);MONAT(B2)+1;1)-2-C2;7)+7*D2-1);B2-REST(B2-2-C2;7)+7*D2-1)))
Liebe Grüße
Alex
(19.10.2021, 13:16)Oldiefan schrieb: [ -> ]Hallo!
Ich bins nochmal. Habe jetzt die Datei angepasst. Da du auch noch letzte Tage drin hast, wurde die Formel etwas länger. Den letzten Tag musst du auch in der Spalte Sonderfälle mit einem L erfassen.
=WENN(E2="L";DATUM(JAHR(B2);MONAT(B2)+1;-REST(DATUM(JAHR(B2);MONAT(B2)+1;-1)-C2;7));WENN(E2="G";WENN(REST(MONAT(B2);2)=0;B2-REST(B2-2-C2;7)+7*D2-1;DATUM(JAHR(B2);MONAT(B2)+1;1)-REST(DATUM(JAHR(B2);MONAT(B2)+1;1)-2-C2;7)+7*D2-1);WENN(E2="U";WENN(REST(MONAT(B2);2)=1;B2-REST(B2-2-C2;7)+7*D2-1;DATUM(JAHR(B2);MONAT(B2)+1;1)-REST(DATUM(JAHR(B2);MONAT(B2)+1;1)-2-C2;7)+7*D2-1);B2-REST(B2-2-C2;7)+7*D2-1)))
Liebe Grüße
Alex
Hallo Alex, danke für deine Antwort und Hilfe, ich werde die Behelfsspalte einfügen und dann die Formeln anpassen. Ich habe gesehen, dass in der Übersicht noch keine Einträge ausgelesen werden. Kannst du das Bitte in die Tabelle eintragen und dann nochmal bereitstellen??
Hallo,
ist denn das Ausgangsdatum bei allen Einträgen gleich? Soll das Ausgangsdatum nur den Monat widerspeigeln, für den die Termine angezeigt werden sollen (also alle Termine, die im Oktober liegen)? Oder soll immer der nächste fällige Termin ab dem angegebenen Datum angezeigt werden?
Ich denke das ganze kann erheblich vereinfacht werden.
(19.10.2021, 14:16)Der Steuerfuzzi schrieb: [ -> ]Hallo,
ist denn das Ausgangsdatum bei allen Einträgen gleich? Soll das Ausgangsdatum nur den Monat widerspeigeln, für den die Termine angezeigt werden sollen (also alle Termine, die im Oktober liegen)? Oder soll immer der nächste fällige Termin ab dem angegebenen Datum angezeigt werden?
Ich denke das ganze kann erheblich vereinfacht werden.
Hallo Michael, ich habe eine Formel drin, die immer den ersten des Monats ausgibt, 01.10.21 dann 01.11.022, von da aus wird berechnet, wenn es die Möglichkeit einfacher zu arbeiten, bin ich auch einverstanden
Naja, vereinfachen ist relativ. Ich habe es mal etwas umgebaut und mit Dropdowns umgesetzt. Schau es Dir mal an.
Hallo,
ich habe mir die Funktion von @Oldiefan etwas genauer angeschaut und festgestellt, wenn man die in Excel2016 vorhandene Funktion MONATSENDE(Datum;Monate) verwendet, kann man die Formel um 1/4 verkürzen:
=WENN(E2="L";MONATSENDE(B2;0)-REST(MONATSENDE(B2;0)-1-C2;7);
WENN(E2="G";WENN(REST(MONAT(B2);2)=0;B2-REST(B2-2-C2;7)-1;MONATSENDE(B2;0)-REST(MONATSENDE(B2;0)-1-C2;7));
WENN(E2="U";WENN(REST(MONAT(B2);2)=1;B2-REST(B2-2-C2;7)-1;MONATSENDE(B2;0)-REST(MONATSENDE(B2;0)-1-C2;7));
B2-REST(B2-2-C2;7)-1))+7*D2)
Eine weitere wesentliche Verkürzung erzielt man allerdings mit einem Excel365 bei Verwendung der LET(..)-Funktion:
=LET(a;B2-REST(B2-2-C2;7)-1; e;MONATSENDE(B2;0)-REST(MONATSENDE(B2;0)-1-C2;7); u;REST(MONAT(B2);2);
WENN(E2="L";e; WENNS(E2="G";WENN(u;e;a);E2="U";WENN(u;a;e); WAHR; a)+7*D2))
Mit dieser Funktion kann man formellokale Variable erzeugen und verwenden, was in diesem Fall die Variablen a, e, u sind; ferner ist die WENNS(..)-Funktion enthalten, die eine Erleichterung bei sonst verschachtelten WENN-Funktionen bringt.
Vielen Dank an euch allen für die schnelle Hilfe, Ihr seid einfach Top.
Jetzt warte ich mal bis zum nächsten 1, also November, ob alles nicht läuft, aber ich denke es gibt keine Probleme.
Vielen Dank nochmal an alle.
