Clever-Excel-Forum

Normale Version: MIN/MAX Suchen in mehreren Spalten
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Hallo Zusammen 

Ich suche eine Alternative für die Minwenns Funktion in Excel 2013. 

Ich habe eine Tabelle die als Beispiel wie folgt aussieht:
[attachment=40504]

[
Bild bitte so als Datei hochladen: Klick mich!
]

Nun möchte ich für Produkt A das Minimum und das Maximum der Fertigungskosten in einem Feld berechnen lassen und im aktuellen Excel funktioniert dies mit Minwenns auch sehr gut. (=MINWENNS(C3:C11;B3:B11;B1))

Ich habe folgende Funktionen probiert:

 =AGGREGAT(5;4;(INDEX(B3:D9;VERGLEICH(B1;B3:B9;0);VERGLEICH(C1;B3:D3))))
 =INDEX(B3:D9;KKLEINSTE(VERGLEICH(B1;B3:B9;0);1);VERGLEICH(C1;B3:D3;0))

Als Ergebniss bekomme ich jeweils die 100 als Fertigungskosten. Ich vermute, dass über die Index Funktion mir nur die erste Kombination aus A und Fertigungskosten angezeigt wird. Wie kann ich dies erweitern, sodass ich Minimum und Maximum bekomme? 

Vielen Dank für eure Hilfe :) 
Nuraya
Da warten wir mal auf die Datei.
Ich habe nun eine Tabelle angehängt =)
Hi,

z.B.:

=AGGREGAT(15;6;C4:C9/(B4:B9=B1);ZEILEN($1:1))
Vielen Dank für deine Antwort :) Es funktioniert!

Gibt es noch eine Möglichkeit wie ich im Array statt "C4:C9" eine Formel verwenden kann die mir das richtige Ergebniss liefert auch wenn ich die Tabelle in den Spalten um mehr Daten ergänze und meine gesuchte Kombination sich nicht nur im Produkt sondern auch zb. von Fertigungskosten zu Fertigungszeit ändert wenn diese in Spalte D stehen würden? 

 Danke für die schnelle Hilfe!
Gruss
Hi,

die Möglichkeit gibt es bestimmt. Zeig mal bitte ein Beispiel. 

VG Boris
Hi,

Ich habe in dem Beispiel jetzt in Spalte D und E jeweils weitere Parameter hinzugefügt In Zeile D1 steht die Formel wie von dir angegeben. 
Ich würde nun gerne in Feld B1 und C1 über das Dropdown-Menü unterschiedliche Kombinationen auswählen und dann für diese den Max und Min-Wert berechnen lassen. Ich habe es über einen Vergleich probiert, jedoch führe dies zu einer Fehlermeldung. 

[attachment=40509]

Danke für die Hilfe :)
Gruss
Hallo Nuraya,

mithilfe von INDEX und VERGLEICH kann man aus einer Matrix dynamisch einen bestimmten Zellbereich (z.B. eine bestimmte Spalte) auswählen.
Hier wird's erklärt:
https://www.youtube.com/watch?v=npu_adz_mOI

Ersetze also in der Formel von Boris den Ausdruck
  C4:C11
durch
  INDEX($C$4:$E$11;0;VERGLEICH($C$1;$C$3:$E$3;0))

Formel für den Max-Wert:
=AGGREGAT(14;6;INDEX($C$4:$E$11;0;VERGLEICH($C$1;$C$3:$E$3;0))/(B4:B11=B1);ZEILEN(B1:C1))

Und für den Min-Wert dann einfach den ersten Parameter der AGGREGAT-Funktion auf 15 ändern.

Gruß
Fred
Moin,

Fred hat ja bereits alles gesagt. Falls Du immer nur MIN und MAX haben möchtest, also nicht den 2., 3., 4. etc. kleinsten/größten Wert, dann ist am Ende ZEILE(N) natürlich nicht nötig. Da reicht dann eine 1:

=AGGREGAT(14;6;INDEX(C4:E11;0;VERGLEICH(C1;C3:E3;0))/(B4:B11=B1);1)
Vielen Dank für eure Hilfe, es funktioniert super!