Hallo,
wie kann man in diesem Beispiel die Anzahl der Minuten herausfiltern.
Es ist immer eine Zahl direkt gefolgt von "min", und vorher ist ein Leer-Zeichen.
Beispiel:
Spalte A
Von A nach B in 20min, und 10km zurück
von C nach D nur 150min bei 45°
Ergebnis in Spalte B
20
150
Vielen Dank
Oli
Moin Oli,
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B |
1 | Von A nach B in 20min, und 10km zurück | 20 |
2 | von C nach D nur 150min bei 45° | 150 |
3 | In 12min am Arbeitsplatz | 12 |
Zelle | Formel |
B1 | {=TEIL(A1;VERGLEICH(1;(ISTZAHL(WERT(TEIL(A1;ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)))*1);0);FINDEN("min";A1)-VERGLEICH(1;(ISTZAHL(WERT(TEIL(A1;ZEILE(INDIREKT("1:"&LÄNGE(A1)));1)))*1);0))*1} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Die VERGLEICH()-Formel stammt von hier:
https://www.herber.de/forum/archiv/848to...tteln.html
Hallo Günter,
danke für Deinen Vorschlag.
Ich bekomme da allerdings einen #NV Fehler.
Woran könnte das liegen?
Hi Oli,
ohne Datei kann ich dir nicht sagen, wo der Fehler liegt. Vermutlich fehlt eine der notwendigen Angaben.
Hallo,
die Datei ist anbei.
Vielen Dank fürs Schauen!
Du hast den Hinweis unter der Formel nicht beachtet.
Vielen Dank!
Habe es wirklich übersehen, es funktioniert
B1:
=1/VERWEIS(2;1/--TEIL(WECHSELN(WECHSELN(A1;"min";" ");" ";WIEDERHOLEN(" ";199));SPALTE(A:Z)*199-198;199))
Kürzer, ohne {} und nur 1 statt 6 A1. VERWEIS wird
hier als ältere Möglichkeit eines WENNFEHLER eingesetzt. Achtung: Nur in Excel möglich!
B1:
=MAX(WENNFEHLER(--TEIL(WECHSELN(WECHSELN(A1;"min";" ");" ";WIEDERHOLEN(" ";199));SPALTE(A:Z)*199-198;199);))
auch in Docs und anderen WENNFEHLER-Tabellenkalkulationen (mittlerweile wohl alle)