Clever-Excel-Forum

Hallo zusammen,

ich bin recht neu in XLS und wollte mich bei Euch erkundigen, ob mir jemand behilflich sein kann.

Ich habe eine Analyse die mir verschiedene Ereignisse anzeigt und dazu noch die Anzahl, wie häufig dieses auftritt. Das Format sieht wie folgt aus:

Szenario | Ergebnis | Häufigkeit des Ergebnisses
1 | 1,2 | 20
2 | 2,3 | 2
....

Es geht darum, dass ich gerne den Median, die Standardabweichung und die Varianz abbilden möchte. Leider ist mir aber nicht ganz klar, wie ich bei der Darstellung der Zahlen und Anzahl der Häufigkeit die Standard-Funktionen von XLS verwenden kann.

Weiß jemand, wie sich dieses Problem beheben lässt?

Viele Grüße

Moin

Median

Code:
=MEDIAN(WENN(SPALTE(1:1)<=Häufigkeiten;Klassen))

=AGGREGAT(17;6;Klassen/(SPALTE(1:1)<=Häufigkeiten);2)

=MEDIAN(WENN(SEQUENZ(;SUMME(Häufigkeiten))<=Häufigkeiten;Klassen))

=AGGREGAT(17;6;Klassen/(SEQUENZ(;SUMME(Häufigkeiten))<=Häufigkeiten);2)

Standardabweichung

Code:
=WURZEL(SUMME(((Klassen - SUMMENPRODUKT(Häufigkeiten*Klassen)/SUMME(Häufigkeiten))^2)*Häufigkeiten)/SUMME(Häufigkeiten))

Varianz

Code:
=Standardabweichung^2

=WURZEL(SUMME(((Klassen - SUMMENPRODUKT(Häufigkeiten*Klassen)/SUMME(Häufigkeiten))^2)*Häufigkeiten)/SUMME(Häufigkeiten))^2

Zugabe:
Mittelwert

Code:
=SUMMENPRODUKT(Häufigkeiten*Klassen)/SUMME(Häufigkeiten)

Modalwerte

Code:
=AGGREGAT(15;6;Klassen/(Häufigkeiten=MAX(Häufigkeiten));SEQUENZ(ZÄHLENWENN(Häufigkeiten;MAX(Häufigkeiten))))

Geometrisches Mittel

Code:
=PRODUKT(POTENZ(Klassen;Häufigkeiten))^(1/SUMME(Häufigkeiten))

froooast

shift-del