Hallo zusammen.
Ich habe eine Tabelle mit mehreren 1000 Zellen. Aus dieser habe ich den Mittelwert aus jeweils 16 Zahlen erstellt.
Der besseren Übersicht halber, möchte ich diesen Wert in einer 2. Tabelle untereinander auflisten. Wenn ich den Verweis in Tabelle 2 nur runterziehe, erweitert er den Bezug ja immer nur um 1 Zelle. Kann ich den Bezug so benennen, dass beim runterziehen immer um 16 erweitert wird?
Das würde mir viel Arbeit erleichtern.
Ist stand wäre wie folgt:
Tabelle 1:
Wert befindet sich in Zelle C3, C19, C35 usw.
Tabelle 2: Wert soll erscheinen in B1(C3),B2(C19),B3(C35) usw.
Würde mich freuen, wenn ihr mir helfen könntet.
Lieben Gruß
Markus
Hi Markus,
zeig uns mal bitte eine Beispieldatei, wie das bei dir aussieht. Bitte keine Bilder, sondern .xlsx. So geht's:
https://www.clever-excel-forum.de/thread-326.html
Außerdem solltest du uns mitteilen, mit welcher Excelversion du arbeitest. Die Versionsangabe 16 sagt mir nichts.
Moin!
Die Zahlenreihe 3, 19, 35, 51, …
erzeugst Du durch herunterziehen der Formel
=ZEILE(X1)*16-13
das Ganze jetzt in INDEX() gewickelt:
Tabelle2!B1:
=INDEX(Tabelle1!C:C;ZEILE(X1)*16-13)
Gruß Ralf
Hallo,
in B1:
=INDEX(Tabelle1!C:C;ZEILE()*16-13)
Zu spät, Cadmus!
Zur Erklärung an Markus:
Ich habe absichtlich ZEILE(X1) als Startwert genommen, damit die Formel auch funktioniert, wenn Du vielleicht doch eine Überschrift darüber haben willst.
Die Spalte ist irrelevant, ich hätte genauso gut mit ZEILE(RPP1) anfngen können, da es sich um eine Zählvariable handelt.
Da solche Anfragen häufiger kommen:
Die gewünschten Sprünge schafft man mittels:
=ZEILE(X1)*Abstand-(Abstand-Startwert)
| A | B | C |
1 | Startwert | 5 | 5 |
2 | Abstand | 3 | 8 |
3 | | | 11 |
4 | | | 14 |
5 | | | 17 |
6 | | | 20 |
7 | | | 23 |
8 | | | 26 |
Formeln der Tabelle |
Zelle | Formel | C1 | =ZEILE(X1)*B$2-(B$2-B$1) |
|
Hallo nochmal zusammen,
erstmal Danke für die Antworten. Aber anscheinend habe ich ein "hängerchen" oder Fußball von gestern hängt mir noch nach.
Meine Angaben zu dem Thema waren leider auch nicht ganz genau. Dafür erstmal ein großes SORRY.
Jetzt aber nochmal richtig (inklusive Dateien):
In der Datei "Lastgang CXXBI Januar" stehen in der Spalte D ab Zeile 23 meine Werte, welche ich gerne in die Datei "CxX Auswertung" ab Spalte D Zeile 2 einfügen möchte.
Wie bereits gesagt, der einfachhalt halber, möchte ich die Formel einfach runterziehen.
Die INDEX Funktion habe ich mal in einer Probe Datei probiert. Dies ging ohne Probleme. Aber sobald ich den Bezug ändere, kommen nur falsche Werte raus.
Liegt es daran, dass es 2 Dateien sind?
Schonmal Danke für eure Hilfe.
Lieben Gruß
Markus
Du hast kein Hängerchen, sondern einen ausgesprochenen Hänger!
Übrigens enthält Deine "Lastgang.xlsx" einen logischen Fehler!
Der erste Block ist 15 Zeilen, der zweite 16 Zeilen hoch!
Die Gruppe ab Zeile 104 enthält nur 15 Zeiträume, danach wieder 16!
Das ist grottenschlecht vorbereitet.
Übrigens wäre es sehr viel sinnvoller (und wie man sieht auch nicht so fehleranfällig), wenn man das MAX() gleich in eine INDEX() integriert:
Spalte D basiert auf Deinem Murks, Spalte E ist meine Logik:
| A | B | C | D | E |
1 | Datum | Zeit | CXX BI | CXX DR |
2 | 01.01.2021 | 00:00 | 03:45 | 20 | 20 |
3 | 04:00 | 07:45 | 22 | 22 |
4 | 08:00 | 11:45 | 21 | 21 |
5 | 12:00 | 15:45 | 20 | 20 |
6 | 16:00 | 19:45 | 20 | 20 |
7 | 20:00 | 23:45:00 | 20 | 20 |
8 | 02.01.2021 | 00:00 | 03:45 | 0 | 22 |
9 | 04:00 | 07:45 | 0 | 18 |
10 | 08:00 | 11:45 | 0 | 36 |
11 | 12:00 | 15:45 | 0 | 32 |
12 | 16:00 | 19:45 | 0 | 23 |
13 | 20:00 | 23:45:00 | 0 | 22 |
Formeln der Tabelle |
Zelle | Formel | D2 | =INDEX('[Lastgang CXXBI Januar.xlsx]Januar'!$D:$D;ZEILE(X2)*16-9) | E2 | =MAX(INDEX('[Lastgang CXXBI Januar.xlsx]Januar'!$C:$C;ZEILE(X1)*16-7):INDEX('[Lastgang CXXBI Januar.xlsx]Januar'!$C:$C;ZEILE(X1)*16+8)) |
|
Bedingte Formatierungen der Tabelle |
Zelle | Nr.: / Bedingung | Format | E2 | 1. / Farbskala | Abc |
|
Gruß Ralf