Code:
Private Sub CommandButton1_Click()
ThisWorkbook.Worksheets("DVDliste").Activate
ActiveSheet.Range("B1").AutoFilter
ActiveSheet.Range("B1").AutoFilter 2, TextBoxAZ.Value
End Sub
Ich habe wieder ein kleine Frage zu meinem Code. Mit dem Code kann ich über eine Textbox nach Werten suchen. Das funktioniert auch wunderbar. Allerdings würde ich jetzt gern bei einer leeren Liste eine MsgBox mit "kein Treffer in Spalte b" ausgeben! Welche Funktion ist dafür am besten geeigenet?
Gruß
Roy
du kannst mit einer Formel zb. Teilergebnis prüfen on unterhalb des Tabellenkopfes Nichtleere Zellen gefunden werden.
columns(2) ist die 2. Spalte des benutzten Blattbereiches
z.b. in vba : if worksheetfunction.SUBTOTAL(3, activesheet.usedrange.columns(2)) = 0 then msgbox "Nichts gefunden"
Hallo,
Code:
Private Sub CommandButton1_Click()
With ThisWorkbook.Worksheets("DVDliste")
.Range("B1").AutoFilter 2, TextBoxAZ.Value
If .AutoFilter.Range.SpecialCells(xlCellTypeVisible).Rows.Count = 1 Then
MsgBox "kein Treffer in Spalte b"
Else
MsgBox .AutoFilter.Range.SpecialCells(xlCellTypeVisible).Rows.Count - 1 & " Treffer"
End If
End With
End Sub
Gruß Uwe
Ich habe es mit dem Code versucht. Geht nicht, da er bei der If-Schleife eine Fehlermeldung ausgibt.
Dann hab ichs mal mit Änderungen versucht:
Code:
.CurrentRegion.SpecialCells(xlVisible)
Aber ging auch nicht.
Gruß
Hallo,
1. bitte ohne Activate, das ist unnötig und macht den Code nur langsam
2. solltest du auch vorher prüfen, ob was in der Textbox steht
3. wozu erst filtern um dann zu prüfen, ob es ein Ergebnis gibt? Besser vorher prüfen, dass der Filterbegriff vorhanden ist.
Code:
Private Sub CommandButton1_Click()
With ThisWorkbook.Worksheets("DVDliste")
If TextboxAZ <> "" Then
If WorksheetFunction.CountIf(.Columns("B"), TextboxAZ) > 0 Then
.Range("B1").AutoFilter 2, TextboxAZ.Value
Else
MsgBox TextboxAZ & " gibt es in Spalte B nicht."
End If
Else
MsgBox "Bitte einen Wert in die Textbox eingeben."
End If
End With
End Sub
Gruß Werner
Vielen Dank,
jetzt mit dem Code läufts super.
Auch für die Anmerkungen. Bzgl. des .activate wurde in den Schulungsunterlagen geschrieben, dass man diese Anweisung sicherheitshalber "immer" setzen sollte. Und gerade weil ich viele Worksheets in der Arbeitsmappe verwende, dachte ich, dass es sinnvoll sei.
Dank für die Hilfe!
Gruß
Roy
Hallo,
Zitat:Bzgl. des .activate wurde in den Schulungsunterlagen geschrieben, dass man diese Anweisung sicherheitshalber "immer" setzen sollte.
um welche Schulungsunterlage handelt es sich da?
Hallo Hans-Dieter,
schätze da wird wohl nix mehr kommen, weil der TE damit abgeschlossen hat und nicht mehr rein schaut.
Interessieren würde mich das aber auch. Vor allem, weil ich davon ausgehe, dass da jemand Geld dafür bekommt.
Gruß Werner
Hallo Werner,
habe es in einem anderen Beitrag des TE gefunden. Er hat ein Buch von Bernd Held...
Hallo Klaus-Dieter (und nicht Hans-Dieter),
ok, und da wird ernsthaft Activate empfohlen? Schon seltsam.
Gruß Werner