Clever-Excel-Forum

Hallo @ all,

es gibt zig viele Beiträge zum Thema blinkende Zelle, aber keins spricht genau mein Anliegen an.

Ich möchte gern, dass Zelle B1 automatisch blinkt wenn Sie leer ist und aufhört wenn was drin steht. Hab schon etliche Codes ausprobiert, aber keiner macht das was ich möchte.
Zudem brauche ich noch die Info wo genau der Code dann eingegeben werden muss. (Modul und/oder DieseArbeitsmappe und/oder Tabelle1 ...) Das konnte ich bisher aus keinem Beitrag im www genau rauslesen oder ich hab´s einfach nicht geschnallt... Undecided

Diesen Code fand ich am logischsten. Wenn ich den richtig verstehe blinkt Zelle A1, wenn in dieser der wert 10 eingetragen wurde...? Und "ersteFarbe" bzw. "zweiteFarbe" ersetze ich durch z.b. green, red, blue...etc?? or What??

Code in Diese Arbeitsmappe einfügen:
Option Explicit
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Ende
End Sub

Private Sub Workbook_Open()
If ThisWorkbook.Worksheets("Tabelle1").Range("A1") = 10 Then ersteFarbe
End Sub

Code in ein Modul einfügen:
Option Explicit
Public ET As Variant

Sub ersteFarbe()
ThisWorkbook.Worksheets("Tabelle1").Range("A1").Interior.ColorIndex = 3
ET = Now + TimeValue("00:00:01")
Application.OnTime ET, "zweiteFarbe"
End Sub

Sub zweiteFarbe()
ThisWorkbook.Worksheets("Tabelle1").Range("A1").Interior.ColorIndex = 33
ET = Now + TimeValue("00:00:01")
Application.OnTime ET, "ersteFarbe"
End Sub

Sub Ende()
On Error Resume Next
Application.OnTime EarliestTime:=ET, Procedure:="ErsteFarbe", Schedule:=False
Application.OnTime EarliestTime:=ET, Procedure:="zweiteFarbe", Schedule:=False
ET = ""
End Sub

Vielen Dank für Eure Unterstützung!!
Stefan

Moin!
Ich habe da eine Spielerei in meinem Archiv.
Da funktioniert die Steuerung der Farbe über bedingte Formatierungen.
Hat den Vorteil, dass Hintergrundfarben nicht gelöscht werden.

Die Idee ist nicht von mir, ich habe nur etwas erweitert.

Gruß Ralf

Hallo,

hinterfragen tue ich das jetzt mal nicht.

Code:
In ein allgemeines Modul:

Option Explicit

Public ET As Variant

Sub ersteFarbe()

ThisWorkbook.Worksheets("Tabelle1").Range("B1").Interior.Color = vbBlue

ET = Now + TimeValue("00:00:01")

Application.OnTime ET, "zweiteFarbe"

End Sub

Sub zweiteFarbe()

ThisWorkbook.Worksheets("Tabelle1").Range("B1").Interior.Color = vbGreen

ET = Now + TimeValue("00:00:01")

Application.OnTime ET, "ersteFarbe"

End Sub

Sub Ende()

On Error Resume Next

Application.OnTime EarliestTime:=ET, Procedure:="ErsteFarbe", Schedule:=False

Application.OnTime EarliestTime:=ET, Procedure:="zweiteFarbe", Schedule:=False

ET = ""

End Sub

Ins Codemodul von "DieseArbeitsmappe"

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)

Ende

End Sub

Private Sub Workbook_Open()

If ThisWorkbook.Worksheets("Tabelle1").Range("B1") = "" Then ersteFarbe

End Sub

Ins Codemodul des Tabellenblattes, auf dem die Zelle blinken soll:

Private Sub Worksheet_Change(ByVal Target As Range)

If Range("B1") <> "" Then

    Ende

    Range("B1").Interior.Color = xlNone

Else

    ersteFarbe

End If

End Sub

Gruß Werner

Vielen Dank dafür. Nicht das was ich explizit gesucht hatte, ABER das baue ich in eine andere Tabelle ein. Das passt da super rein!! THX ;)

Mega großes THX! Genau so wollte ich das haben. Auch wenn Du nicht hinterfragst.....

Manche Mitarbeitern brauchen halt blinkende Zellen um zu schnallen das se da was eintragen müssen...

StefanB

RPP63

Werner.M

StefanB