Clever-Excel-Forum

(16.03.2021, 18:51)Ego schrieb: [ -> ]Hallo S...,

A) Warum willst du eine 0 durch "" ersetzen?
Wenn dich nur die Anzeige der 0 stört, kannst du über das Zahlenformat die Anzeige unterdrücken.

B) Änderungen
Im Folgenden nur den hinteren Teil deiner Formel

1. Deine Formel

Code:

=WENN(UND(DY48="in time";ISTLEER(CO48)=WAHR;W48<$EC$3);V48/L48;
WENN(UND(DY48="in time";ISTLEER(CR48)=WAHR;Z48<$EC$3);Y48/L48;
WENN(UND(DY48="in time";ISTLEER(CU48)=WAHR;AC48<$EC$3);AB48/L48;
WENN(UND(DY48="in time";ISTLEER(CX48)=WAHR;AF48<$EC$3);AE48/L48;
WENN(UND(DY48="in time";ISTLEER(DA48)=WAHR;AI48<$EC$3);AH48/L48;
WENN(UND(DY48="in time";ISTLEER(DD48)=WAHR;AL48<$EC$3);AK48/L48;
WENN(UND(DY48="in time";ISTLEER(DG48)=WAHR;AO48<$EC$3);AN48/L48;
WENN(UND(DY48="in time";ISTLEER(DJ48)=WAHR;AR48<$EC$3);AQ48/L48;
WENN(UND(DY48="in time";ISTLEER(DM48)=WAHR;AU48<$EC$3);AT48/L48;
WENN(UND(DY48="in time";ISTLEER(DP48)=WAHR;AX48<$EC$3);AW48/L48;""))))))))))

2. Ausklammern von DY48, Berücksichtigen von "early" und entfernen von "=WAHR"

Code:

=WENN(ODER(DY48="in time";DY48="early");
WENN(UND(ISTLEER(CO48);W48<$EC$3);V48/L48;
WENN(UND(ISTLEER(CR48);Z48<$EC$3);Y48/L48;
WENN(UND(ISTLEER(CU48);AC48<$EC$3);AB48/L48;
WENN(UND(ISTLEER(CX48);AF48<$EC$3);AE48/L48;
WENN(UND(ISTLEER(DA48);AI48<$EC$3);AH48/L48;
WENN(UND(ISTLEER(DD48);AL48<$EC$3);AK48/L48;
WENN(UND(ISTLEER(DG48);AO48<$EC$3);AN48/L48;
WENN(UND(ISTLEER(DJ48);AR48<$EC$3);AQ48/L48;
WENN(UND(ISTLEER(DM48);AU48<$EC$3);AT48/L48;
WENN(UND(ISTLEER(DP48);AX48<$EC$3);AW48/L48;""))))))))));"")

3. Listen anstelle von Einzelwerten

Code:

=WENN(ODER(DY48="in time";DY48="early");INDEX(V48:AW48;;VERGLEICH(1;(CO48:DP48="")*(W48:AX48<$EC$3)*(REST(SPALTE(V48:AW48);3)=1);0))/L48;"")

4. Fehlermeldung abfangen wenn keine Bedingung zutrifft (Vergleich findet keine 1)

Code:

=WENNFEHLER(WENN(ODER(DY48="in time";DY48="early");INDEX(V48:AW48;;VERGLEICH(1;(CO48:DP48="")*(W48:AX48<$EC$3)*(REST(SPALTE(V48:AW48);3)=1);0))/L48;"");"")

Super, vielen Dank :)
So verstehe auch ich das und kann daraus lernen.

PS: die Formel ist wirklich genial. Ich arbeite daran, dass ich das auch irgendwann kann :)

Hi,

das geht auch einfacher: