Hallo zusammen,
ich bin auf der Suche nach einer Excel-Formel für eine aktuelles Problem.
Ich habe eine große Tabelle mit doppelten Werten.
Ergebnis der gesuchten Formel soll sein, dass mir in einem zweiten Tabellenblatt alle Berufe anzeigt werden die z.B. Kennziffer "10" (Spalte A) zugeordnet sind.
Und das am besten untereinander und nicht in einer Zeile.
Eine vereinfachte Beispieltabelle habe ich angefügt.
Hat jemand eine Idee und kann mir weiterhelfen?
Vielen Dank vorab.
Hola,
Code:
=WENNFEHLER(INDEX(Tabelle1!B:B;AGGREGAT(15;6;ZEILE(Tabelle1!$B$2:$B$14)/(Tabelle1!$A$2:$A$14=$A$1);ZEILE(A1)));"")
Deine Versionsangabe passt allerdings nicht zur Dateieindung.
Gruß,
steve1da
Hallo Steve,
danke dir für die Formel, jedoch erziele ich damit nicht das gewünschte Ergbenis.
Ich hatte damit gerechnet, dass mit nach Einstaz der Formel in Spalte "C" die entsprechenden Berufe aufgelistet werden die z.B. Kennziffer "10" zugeordnet sind.
Leider erhalte ich kein Ergebnis.
Auf Grund der Formelwennfehler ist das Ergebnis eine leere Zelle.
Habe ich etwas falsch gemacht? :/
Hola,
welche Excel Version hast du denn nun wirklich im Einsatz?
Gruß,
steve1da
Ich gehe im Zweifel immer von einer aktuellen aus:
| A | B | C | D | E | F | G | H | I | J |
| 1 | Kennziffer | Beruf | | 10 | 20 | 30 | 40 | 50 | 60 | 70 |
| 2 | 10 | Arzt | | Arzt | Arzt | Arzt | Arzt | Arzt | Fahrer | Arzt |
| 3 | 10 | Schwester | | Schwester | Schwester | | | | | Schwester |
| 4 | 10 | Fahrer | | Fahrer | Fahrer | | | | | Fahrer |
| 5 | 20 | Arzt | | | | | | | | |
| 6 | 20 | Schwester | | | | | | | | |
| 7 | 20 | Fahrer | | | | | | | | |
| 8 | 30 | Arzt | | | | | | | | |
| 9 | 40 | Arzt | | | | | | | | |
| 10 | 50 | Arzt | | | | | | | | |
| 11 | 60 | Fahrer | | | | | | | | |
| 12 | 70 | Arzt | | | | | | | | |
| 13 | 70 | Schwester | | | | | | | | |
| 14 | 70 | Fahrer | | | | | | | | |
| Zelle | Formel |
| D1 | =MTRANS(EINDEUTIG(A2:A14)) |
| D2 | =FILTER($B2:$B14;$A2:$A14=D1) |
| E2 | =FILTER($B2:$B14;$A2:$A14=E1) |
| F2 | =FILTER($B2:$B14;$A2:$A14=F1) |
| G2 | =FILTER($B2:$B14;$A2:$A14=G1) |
| H2 | =FILTER($B2:$B14;$A2:$A14=H1) |
| I2 | =FILTER($B2:$B14;$A2:$A14=I1) |
| J2 | =FILTER($B2:$B14;$A2:$A14=J1) |
Edit: ich gehe davon aus dass in der anderen Tabelle in A1 nicht die gewünschte Nummer steht.
Hallo,
Version 2008 ist istalliert.
Dann in A1 die gesuchte Nummer.
Code:
=WENNFEHLER(INDEX(Tabelle1!B:B;KKLEINSTE(WENN(Tabelle1!$A$2:$A$14=$A$1;ZEILE(X$2:X$14));ZEILE(X1)));"")
Die Formel mit Strg-Shift-Enter abschließen und danach nach unten ziehen.
Jetzt klappt es.... vielen Dank ;)