Clever-Excel-Forum

Normale Version: Anzahl von Werten in A mit Eigenschaften a in Spalte B
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Hallo zusammen,

ich habe eine Tabelle mit zwei Spalten. In der Spalte A sind Projekte aufgeführt. In der Spalte B sind den Projekten Eigenschaften zugeordnet. (siehe Anhang)

Wie ermittle ich die Anzahl der Projekte die nur eine Eigenschaft (bspw. "a") zugeordnet wurden?

und wie ermittle ich die Anzahl der Projekte die zwei Eigenschaften (bspw. "a" und "b") zugeordnet wurden?

Die Anzahl der Projekte habe ich wie folgt ermittelt: =SUMMENPRODUKT(1/ZÄHLENWENN(A2:A11;A2:A11))
Ergebnis ist 6 und richtig.

Mein Ansatz zur Lösung befriedigt mich nicht, da keine ganzen Zahlen ausgegeben werden. 
Lösungsansatz: =SUMMENPRODUKT((1/ZÄHLENWENN(A2:A11;A2:A11))*(B2:B11 = "a"))

Ergebnis ist 3,666 und somit falsch. (3 ist Korrekt)

Ich würde mich freuen wenn Ihr mir helfen könnt.  Blush
Besten Dank vorab
Hallo IronMike,

zum Beispiel so:

Arbeitsblatt mit dem Namen 'Tabelle1'
ABCDEF
1ProjekteEigenschaftEigenschaftAnzahl
2G.01aa4
3T.01ab2
4T.02bc1
5T.02b
6T.03c
7T.04a
8T.04abei zweiEignschaften
9T.04bEigenschaft1Eigenschaft2Anzahl
10T.05aac5
11T.05a

ZelleFormel
E2{=SUMME(N(WENN($B$2:$B$11=D2;VERGLEICH(WENN($B$2:$B$11=D2;$A$2:$A$11);WENN($B$2:$B$11=D2;$A$2:$A$11);0)=(ZEILE($A$2:$A$11)-1))))}
E3{=SUMME(N(WENN($B$2:$B$11=D3;VERGLEICH(WENN($B$2:$B$11=D3;$A$2:$A$11);WENN($B$2:$B$11=D3;$A$2:$A$11);0)=(ZEILE($A$2:$A$11)-1))))}
E4{=SUMME(N(WENN($B$2:$B$11=D4;VERGLEICH(WENN($B$2:$B$11=D4;$A$2:$A$11);WENN($B$2:$B$11=D4;$A$2:$A$11);0)=(ZEILE($A$2:$A$11)-1))))}
F10{=SUMME(N(WENN(($B$2:$B$11=D10)+($B$2:$B$11=E10);VERGLEICH(WENN(($B$2:$B$11=D10)+($B$2:$B$11=E10);$A$2:$A$11);WENN(($B$2:$B$11=D10)+($B$2:$B$11=E10);$A$2:$A$11);0)=(ZEILE($A$2:$A$11)-1))))}
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Das Prinzip der Formel stammt von hier:
https://www.computerwissen.de/office/exc...ehlen.html

Die -1 am Ende ist in meinem Beispiel notwendig, weil der eigentliche Datenbereich in Zeile 2 beginnt (Zeile 1 sind die Spaltenüberschriften)

Stichwort für Internet-Recherche:
Anzahl unterschiedlicher Werte zählen mit Bedingung

Gruß
Fred